File:
[LON-CAPA] /
loncom /
loncnew
Revision
1.17:
download - view:
text,
annotated -
select for diffs
Sun Aug 3 00:44:31 2003 UTC (21 years ago) by
foxr
Branches:
MAIN
CVS tags:
HEAD
1. Correct handling of connection failure: Assume it means the host is
unreachable and fail all of the queued transactions. Note that the
inflight transactions should fail on their own time due either to timeout
or send/receive failures.
2. Correct handling of logs for forced death signals. Pull the signal
from the event watcher.
#!/usr/bin/perl
# The LearningOnline Network with CAPA
# lonc maintains the connections to remote computers
#
# $Id: loncnew,v 1.17 2003/08/03 00:44:31 foxr Exp $
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
## LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#
#
# new lonc handles n request out bver m connections to londs.
# This module is based on the Event class.
# Development iterations:
# - Setup basic event loop. (done)
# - Add timer dispatch. (done)
# - Add ability to accept lonc UNIX domain sockets. (done)
# - Add ability to create/negotiate lond connections (done).
# - Add general logic for dispatching requests and timeouts. (done).
# - Add support for the lonc/lond requests. (done).
# - Add logging/status monitoring.
# - Add Signal handling - HUP restarts. USR1 status report.
# - Add Configuration file I/O (done).
# - Add management/status request interface.
# - Add deferred request capability. (done)
# - Detect transmission timeouts.
#
# Change log:
# $Log: loncnew,v $
# Revision 1.17 2003/08/03 00:44:31 foxr
# 1. Correct handling of connection failure: Assume it means the host is
# unreachable and fail all of the queued transactions. Note that the
# inflight transactions should fail on their own time due either to timeout
# or send/receive failures.
# 2. Correct handling of logs for forced death signals. Pull the signal
# from the event watcher.
#
# Revision 1.16 2003/07/29 02:33:05 foxr
# Add SIGINT processing to child processes to toggle annoying trace mode
# on/off.. will try to use this to isolate the compute boud process issue.
#
# Revision 1.15 2003/07/15 02:07:05 foxr
# Added code for lonc/lond transaction timeouts. Who knows if it works right.
# The intent is for a timeout to fail any transaction in progress and kill
# off the sockt that timed out.
#
# Revision 1.14 2003/07/03 02:10:18 foxr
# Get all of the signals to work correctly.
#
# Revision 1.13 2003/07/02 01:31:55 foxr
# Added kill -HUP logic (restart).
#
# Revision 1.11 2003/06/25 01:54:44 foxr
# Fix more problems with transaction failure.
#
# Revision 1.10 2003/06/24 02:46:04 foxr
# Put a limit on the number of times we'll retry a connection.
# Start getting the signal stuff put in as well...note that need to get signals
# going or else 6the client will permanently give up on dead servers.
#
# Revision 1.9 2003/06/13 02:38:43 foxr
# Add logging in 'expected format'
#
# Revision 1.8 2003/06/11 02:04:35 foxr
# Support delayed transactions... this is done uniformly by encapsulating
# transactions in an object ... a LondTransaction that is implemented by
# LondTransaction.pm
#
# Revision 1.7 2003/06/03 01:59:39 foxr
# complete coding to support deferred transactions.
#
#
use lib "/home/httpd/lib/perl/";
use lib "/home/foxr/newloncapa/types";
use Event qw(:DEFAULT );
use POSIX qw(:signal_h);
use POSIX;
use IO::Socket;
use IO::Socket::INET;
use IO::Socket::UNIX;
use IO::File;
use IO::Handle;
use Socket;
use Crypt::IDEA;
use LONCAPA::Queue;
use LONCAPA::Stack;
use LONCAPA::LondConnection;
use LONCAPA::LondTransaction;
use LONCAPA::Configuration;
use LONCAPA::HashIterator;
#
# Disable all signals we might receive from outside for now.
#
#$SIG{QUIT} = IGNORE;
#$SIG{HUP} = IGNORE;
#$SIG{USR1} = IGNORE;
#$SIG{INT} = IGNORE;
#$SIG{CHLD} = IGNORE;
#$SIG{__DIE__} = IGNORE;
# Read the httpd configuration file to get perl variables
# normally set in apache modules:
my $perlvarref = LONCAPA::Configuration::read_conf('loncapa.conf');
my %perlvar = %{$perlvarref};
#
# parent and shared variables.
my %ChildHash; # by pid -> host.
my $MaxConnectionCount = 10; # Will get from config later.
my $ClientConnection = 0; # Uniquifier for client events.
my $DebugLevel = 0;
my $NextDebugLevel= 10; # So Sigint can toggle this.
my $IdleTimeout= 3600; # Wait an hour before pruning connections.
#
# The variables below are only used by the child processes.
#
my $RemoteHost; # Name of host child is talking to.
my $UnixSocketDir= "/home/httpd/sockets";
my $IdleConnections = Stack->new(); # Set of idle connections
my %ActiveConnections; # Connections to the remote lond.
my %ActiveTransactions; # LondTransactions in flight.
my %ActiveClients; # Serial numbers of active clients by socket.
my $WorkQueue = Queue->new(); # Queue of pending transactions.
my $ConnectionCount = 0;
my $IdleSeconds = 0; # Number of seconds idle.
my $Status = ""; # Current status string.
my $RecentLogEntry = "";
my $ConnectionRetries=5; # Number of connection retries allowed.
my $ConnectionRetriesLeft=5; # Number of connection retries remaining.
#
# The hash below gives the HTML format for log messages
# given a severity.
#
my %LogFormats;
$LogFormats{"CRITICAL"} = "<font color=red>CRITICAL: %s</font>";
$LogFormats{"SUCCESS"} = "<font color=green>SUCCESS: %s</font>";
$LogFormats{"INFO"} = "<font color=yellow>INFO: %s</font>";
$LogFormats{"WARNING"} = "<font color=blue>WARNING: %s</font>";
$LogFormats{"DEFAULT"} = " %s ";
=pod
=head2 LogPerm
Makes an entry into the permanent log file.
=cut
sub LogPerm {
my $message=shift;
my $execdir=$perlvar{'lonDaemons'};
my $now=time;
my $local=localtime($now);
my $fh=IO::File->new(">>$execdir/logs/lonnet.perm.log");
print $fh "$now:$message:$local\n";
}
=pod
=head2 Log
Logs a message to the log file.
Parameters:
=item severity
One of CRITICAL, WARNING, INFO, SUCCESS used to select the
format string used to format the message. if the severity is
not a defined severity the Default format string is used.
=item message
The base message. In addtion to the format string, the message
will be appended to a string containing the name of our remote
host and the time will be formatted into the message.
=cut
sub Log {
my $severity = shift;
my $message = shift;
if(!$LogFormats{$severity}) {
$severity = "DEFAULT";
}
my $format = $LogFormats{$severity};
# Put the window dressing in in front of the message format:
my $now = time;
my $local = localtime($now);
my $finalformat = "$local ($$) [$RemoteHost] [$Status] ";
my $finalformat = $finalformat.$format."\n";
# open the file and put the result.
my $execdir = $perlvar{'lonDaemons'};
my $fh = IO::File->new(">>$execdir/logs/lonc.log");
my $msg = sprintf($finalformat, $message);
$RecentLogEntry = $msg;
print $fh $msg;
}
=pod
=head2 GetPeerName
Returns the name of the host that a socket object is connected to.
=cut
sub GetPeername {
my $connection = shift;
my $AdrFamily = shift;
my $peer = $connection->peername();
my $peerport;
my $peerip;
if($AdrFamily == AF_INET) {
($peerport, $peerip) = sockaddr_in($peer);
my $peername = gethostbyaddr($iaddr, $AdrFamily);
return $peername;
} elsif ($AdrFamily == AF_UNIX) {
my $peerfile;
($peerfile) = sockaddr_un($peer);
return $peerfile;
}
}
#----------------------------- Timer management ------------------------
=pod
=head2 Debug
Invoked to issue a debug message.
=cut
sub Debug {
my $level = shift;
my $message = shift;
if ($level <= $DebugLevel) {
Log("INFO", "-Debug- $message host = $RemotHost");
}
}
sub SocketDump {
my $level = shift;
my $socket= shift;
if($level <= $DebugLevel) {
$socket->Dump();
}
}
=pod
=head2 ShowStatus
Place some text as our pid status.
and as what we return in a SIGUSR1
=cut
sub ShowStatus {
my $state = shift;
my $now = time;
my $local = localtime($now);
$Status = $local.": ".$state;
$0='lonc: '.$state.' '.$local;
}
=pod
=head 2 SocketTimeout
Called when an action on the socket times out. The socket is
destroyed and any active transaction is failed.
=cut
sub SocketTimeout {
my $Socket = shift;
KillSocket($Socket);
}
=pod
=head2 Tick
Invoked each timer tick.
=cut
sub Tick {
my $client;
ShowStatus(GetServerHost()." Connection count: ".$ConnectionCount);
# Is it time to prune connection count:
if($IdleConnections->Count() &&
($WorkQueue->Count() == 0)) { # Idle connections and nothing to do?
$IdleSeconds++;
if($IdleSeconds > $IdleTimeout) { # Prune a connection...
$Socket = $IdleConnections->pop();
KillSocket($Socket);
}
} else {
$IdleSeconds = 0; # Reset idle count if not idle.
}
#
# For each inflight transaction, tick down its timeout counter.
#
foreach $item (keys %ActiveTransactions) {
my $Socket = $ActiveTransactions{$item}->getServer();
$Socket->Tick();
}
# Do we have work in the queue, but no connections to service them?
# If so, try to make some new connections to get things going again.
#
my $Requests = $WorkQueue->Count();
if (($ConnectionCount == 0) && ($Requests > 0)) {
if ($ConnectionRetriesLeft > 0) {
my $Connections = ($Requests <= $MaxConnectionCount) ?
$Requests : $MaxConnectionCount;
Debug(1,"Work but no connections, start ".$Connections." of them");
for ($i =0; $i < $Connections; $i++) {
MakeLondConnection();
}
} else {
Debug(1,"Work in queue, but gave up on connections..flushing\n");
EmptyQueue(); # Connections can't be established.
}
}
}
=pod
=head2 SetupTimer
Sets up a 1 per sec recurring timer event. The event handler is used to:
=item
Trigger timeouts on communications along active sockets.
=item
Trigger disconnections of idle sockets.
=cut
sub SetupTimer {
Debug(6, "SetupTimer");
Event->timer(interval => 1, debug => 1, cb => \&Tick );
}
=pod
=head2 ServerToIdle
This function is called when a connection to the server is
ready for more work.
If there is work in the Work queue the top element is dequeued
and the connection will start to work on it. If the work queue is
empty, the connection is pushed on the idle connection stack where
it will either get another work unit, or alternatively, if it sits there
long enough, it will be shut down and released.
=cut
sub ServerToIdle {
my $Socket = shift; # Get the socket.
delete($ActiveTransactions{$Socket}); # Server has no transaction
&Debug(6, "Server to idle");
# If there's work to do, start the transaction:
$reqdata = $WorkQueue->dequeue(); # This is a LondTransaction
unless($reqdata eq undef) {
Debug(9, "Queue gave request data: ".$reqdata->getRequest());
&StartRequest($Socket, $reqdata);
} else {
# There's no work waiting, so push the server to idle list.
&Debug(8, "No new work requests, server connection going idle");
$IdleConnections->push($Socket);
}
}
=pod
=head2 ClientWritable
Event callback for when a client socket is writable.
This callback is established when a transaction reponse is
avaiable from lond. The response is forwarded to the unix socket
as it becomes writable in this sub.
Parameters:
=item Event
The event that has been triggered. Event->w->data is
the data and Event->w->fd is the socket to write.
=cut
sub ClientWritable {
my $Event = shift;
my $Watcher = $Event->w;
my $Data = $Watcher->data;
my $Socket = $Watcher->fd;
# Try to send the data:
&Debug(6, "ClientWritable writing".$Data);
&Debug(9, "Socket is: ".$Socket);
if($Socket->connected) {
my $result = $Socket->send($Data, 0);
# $result undefined: the write failed.
# otherwise $result is the number of bytes written.
# Remove that preceding string from the data.
# If the resulting data is empty, destroy the watcher
# and set up a read event handler to accept the next
# request.
&Debug(9,"Send result is ".$result." Defined: ".defined($result));
if(defined($result)) {
&Debug(9, "send result was defined");
if($result == length($Data)) { # Entire string sent.
&Debug(9, "ClientWritable data all written");
$Watcher->cancel();
#
# Set up to read next request from socket:
my $descr = sprintf("Connection to lonc client %d",
$ActiveClients{$Socket});
Event->io(cb => \&ClientRequest,
poll => 'r',
desc => $descr,
data => "",
fd => $Socket);
} else { # Partial string sent.
$Watcher->data(substr($Data, $result));
if($result == 0) { # client hung up on us!!
Log("INFO", "lonc pipe client hung up on us!");
$Watcher->cancel;
$Socket->shutdown(2);
$Socket->close();
}
}
} else { # Error of some sort...
# Some errnos are possible:
my $errno = $!;
if($errno == POSIX::EWOULDBLOCK ||
$errno == POSIX::EAGAIN ||
$errno == POSIX::EINTR) {
# No action taken?
} else { # Unanticipated errno.
&Debug(5,"ClientWritable error or peer shutdown".$RemoteHost);
$Watcher->cancel; # Stop the watcher.
$Socket->shutdown(2); # Kill connection
$Socket->close(); # Close the socket.
}
}
} else {
$Watcher->cancel(); # A delayed request...just cancel.
}
}
=pod
=head2 CompleteTransaction
Called when the reply data has been received for a lond
transaction. The reply data must now be sent to the
ultimate client on the other end of the Unix socket. This is
done by setting up a writable event for the socket with the
data the reply data.
Parameters:
=item Socket
Socket on which the lond transaction occured. This is a
LondConnection. The data received is in the TransactionReply member.
=item Transaction
The transaction that is being completed.
=cut
sub CompleteTransaction {
&Debug(6,"Complete transaction");
my $Socket = shift;
my $Transaction = shift;
if (!$Transaction->isDeferred()) { # Normal transaction
my $data = $Socket->GetReply(); # Data to send.
StartClientReply($Transaction, $data);
} else { # Delete deferred transaction file.
Log("SUCCESS", "A delayed transaction was completed");
LogPerm("S:$Client:".$Transaction->getRequest());
unlink $Transaction->getFile();
}
}
=pod
=head1 StartClientReply
Initiates a reply to a client where the reply data is a parameter.
=head2 parameters:
=item Transaction
The transaction for which we are responding to the client.
=item data
The data to send to apached client.
=cut
sub StartClientReply {
my $Transaction = shift;
my $data = shift;
my $Client = $Transaction->getClient();
&Debug(8," Reply was: ".$data);
my $Serial = $ActiveClients{$Client};
my $desc = sprintf("Connection to lonc client %d",
$Serial);
Event->io(fd => $Client,
poll => "w",
desc => $desc,
cb => \&ClientWritable,
data => $data);
}
=pod
=head2 FailTransaction
Finishes a transaction with failure because the associated lond socket
disconnected. There are two possibilities:
- The transaction is deferred: in which case we just quietly
delete the transaction since there is no client connection.
- The transaction is 'live' in which case we initiate the sending
of "con_lost" to the client.
Deleting the transaction means killing it from the
%ActiveTransactions hash.
Parameters:
=item client
The LondTransaction we are failing.
=cut
sub FailTransaction {
my $transaction = shift;
Log("WARNING", "Failing transaction ".$transaction->getRequest());
Debug(1, "Failing transaction: ".$transaction->getRequest());
if (!$transaction->isDeferred()) { # If the transaction is deferred we'll get to it.
my $client = $transaction->getClient();
Debug(1," Replying con_lost to ".$transaction->getRequest());
StartClientReply($transaction, "con_lost\n");
}
}
=pod
=head1 EmptyQueue
Fails all items in the work queue with con_lost.
Note that each item in the work queue is a transaction.
=cut
sub EmptyQueue {
while($WorkQueue->Count()) {
my $request = $WorkQueue->dequeue(); # This is a transaction
FailTransaction($request);
}
}
=pod
=head2 CloseAllLondConnections
Close all connections open on lond prior to exit e.g.
=cut
sub CloseAllLondConnections {
foreach $Socket (keys %ActiveConnections) {
KillSocket($Socket);
}
}
=cut
=pod
=head2 KillSocket
Destroys a socket. This function can be called either when a socket
has died of 'natural' causes or because a socket needs to be pruned due to
idleness. If the socket has died naturally, if there are no longer any
live connections a new connection is created (in case there are transactions
in the queue). If the socket has been pruned, it is never re-created.
Parameters:
=item Socket
The socket to kill off.
=item Restart
nonzero if we are allowed to create a new connection.
=cut
sub KillSocket {
my $Socket = shift;
Log("WARNING", "Shutting down a socket");
$Socket->Shutdown();
# If the socket came from the active connection set,
# delete its transaction... note that FailTransaction should
# already have been called!!!
# otherwise it came from the idle set.
#
if(exists($ActiveTransactions{$Socket})) {
delete ($ActiveTransactions{$Socket});
}
if(exists($ActiveConnections{$Socket})) {
delete($ActiveConnections{$Socket});
}
$ConnectionCount--;
# If the connection count has gone to zero and there is work in the
# work queue, the work all gets failed with con_lost.
#
if($ConnectionCount == 0) {
EmptyQueue;
}
}
=pod
=head2 LondReadable
This function is called whenever a lond connection
is readable. The action is state dependent:
=head3 State=Initialized
We''re waiting for the challenge, this is a no-op until the
state changes.
=head3 State=Challenged
The challenge has arrived we need to transition to Writable.
The connection must echo the challenge back.
=head3 State=ChallengeReplied
The challenge has been replied to. The we are receiveing the
'ok' from the partner.
=head3 State=RequestingKey
The ok has been received and we need to send the request for
an encryption key. Transition to writable for that.
=head3 State=ReceivingKey
The the key has been requested, now we are reading the new key.
=head3 State=Idle
The encryption key has been negotiated or we have finished
reading data from the a transaction. If the callback data has
a client as well as the socket iformation, then we are
doing a transaction and the data received is relayed to the client
before the socket is put on the idle list.
=head3 State=SendingRequest
I do not think this state can be received here, but if it is,
the appropriate thing to do is to transition to writable, and send
the request.
=head3 State=ReceivingReply
We finished sending the request to the server and now transition
to readable to receive the reply.
The parameter to this function are:
The event. Implicit in this is the watcher and its data. The data
contains at least the lond connection object and, if a
transaction is in progress, the socket attached to the local client.
=cut
sub LondReadable {
my $Event = shift;
my $Watcher = $Event->w;
my $Socket = $Watcher->data;
my $client = undef;
&Debug(6,"LondReadable called state = ".$State);
my $State = $Socket->GetState(); # All action depends on the state.
SocketDump(6, $Socket);
my $status = $Socket->Readable();
&Debug(2, "Socket->Readable returned: $status");
if($status != 0) {
# bad return from socket read. Currently this means that
# The socket has become disconnected. We fail the transaction.
Log("WARNING",
"Lond connection lost.");
if(exists($ActiveTransactions{$Socket})) {
FailTransaction($ActiveTransactions{$Socket});
}
$Watcher->cancel();
KillSocket($Socket);
return;
}
SocketDump(6,$Socket);
$State = $Socket->GetState(); # Update in case of transition.
&Debug(6, "After read, state is ".$State);
if($State eq "Initialized") {
} elsif ($State eq "ChallengeReceived") {
# The challenge must be echoed back; The state machine
# in the connection takes care of setting that up. Just
# need to transition to writable:
$Watcher->cb(\&LondWritable);
$Watcher->poll("w");
} elsif ($State eq "ChallengeReplied") {
} elsif ($State eq "RequestingKey") {
# The ok was received. Now we need to request the key
# That requires us to be writable:
$Watcher->cb(\&LondWritable);
$Watcher->poll("w");
} elsif ($State eq "ReceivingKey") {
} elsif ($State eq "Idle") {
# If necessary, complete a transaction and then go into the
# idle queue.
$Watcher->cancel();
if(exists($ActiveTransactions{$Socket})) {
Debug(8,"Completing transaction!!");
CompleteTransaction($Socket,
$ActiveTransactions{$Socket});
} else {
Log("SUCCESS", "Connection ".$ConnectionCount." to "
.$RemoteHost." now ready for action");
}
ServerToIdle($Socket); # Next work unit or idle.
} elsif ($State eq "SendingRequest") {
# We need to be writable for this and probably don't belong
# here inthe first place.
Deubg(6, "SendingRequest state encountered in readable");
$Watcher->poll("w");
$Watcher->cb(\&LondWritable);
} elsif ($State eq "ReceivingReply") {
} else {
# Invalid state.
Debug(4, "Invalid state in LondReadable");
}
}
=pod
=head2 LondWritable
This function is called whenever a lond connection
becomes writable while there is a writeable monitoring
event. The action taken is very state dependent:
=head3 State = Connected
The connection is in the process of sending the 'init' hailing to the
lond on the remote end. The connection object''s Writable member is
called. On error, ConnectionError is called to destroy the connection
and remove it from the ActiveConnections hash
=head3 Initialized
'init' has been sent, writability monitoring is removed and
readability monitoring is started with LondReadable as the callback.
=head3 ChallengeReceived
The connection has received the who are you challenge from the remote
system, and is in the process of sending the challenge
response. Writable is called.
=head3 ChallengeReplied
The connection has replied to the initial challenge The we switch to
monitoring readability looking for the server to reply with 'ok'.
=head3 RequestingKey
The connection is in the process of requesting its encryption key.
Writable is called.
=head3 ReceivingKey
The connection has sent the request for a key. Switch to readability
monitoring to accept the key
=head3 SendingRequest
The connection is in the process of sending a request to the server.
This request is part of a client transaction. All the states until
now represent the client setup protocol. Writable is called.
=head3 ReceivingReply
The connection has sent a request. Now it must receive a reply.
Readability monitoring is requested.
This function is an event handler and therefore receives as
a parameter the event that has fired. The data for the watcher
of this event is a reference to a list of one or two elements,
depending on state. The first (and possibly only) element is the
socket. The second (present only if a request is in progress)
is the socket on which to return a reply to the caller.
=cut
sub LondWritable {
my $Event = shift;
my $Watcher = $Event->w;
my $Socket = $Watcher->data;
my $State = $Socket->GetState();
Debug(6,"LondWritable State = ".$State."\n");
# Figure out what to do depending on the state of the socket:
SocketDump(6,$Socket);
if ($State eq "Connected") {
if ($Socket->Writable() != 0) {
# The write resulted in an error.
# We'll treat this as if the socket got disconnected:
Log("WARNING", "Connection to ".$RemoteHost.
" has been disconnected");
$Watcher->cancel();
KillSocket($Socket);
return;
}
# "init" is being sent...
} elsif ($State eq "Initialized") {
# Now that init was sent, we switch
# to watching for readability:
$Watcher->cb(\&LondReadable);
$Watcher->poll("r");
} elsif ($State eq "ChallengeReceived") {
# We received the challenge, now we
# are echoing it back. This is a no-op,
# we're waiting for the state to change
if($Socket->Writable() != 0) {
$Watcher->cancel();
KillSocket($Socket);
return;
}
} elsif ($State eq "ChallengeReplied") {
# The echo was sent back, so we switch
# to watching readability.
$Watcher->cb(\&LondReadable);
$Watcher->poll("r");
} elsif ($State eq "RequestingKey") {
# At this time we're requesting the key.
# again, this is essentially a no-op.
# we'll write the next chunk until the
# state changes.
if($Socket->Writable() != 0) {
# Write resulted in an error.
$Watcher->cancel();
KillSocket($Socket);
return;
}
} elsif ($State eq "ReceivingKey") {
# Now we need to wait for the key
# to come back from the peer:
$Watcher->cb(\&LondReadable);
$Watcher->poll("r");
} elsif ($State eq "SendingRequest") {
# At this time we are sending a request to the
# peer... write the next chunk:
if($Socket->Writable() != 0) {
if(exists($ActiveTransactions{$Socket})) {
Debug(3, "Lond connection lost, failing transactions");
FailTransaction($ActiveTransactions{$Socket});
}
$Watcher->cancel();
KillSocket($Socket);
return;
}
} elsif ($State eq "ReceivingReply") {
# The send has completed. Wait for the
# data to come in for a reply.
Debug(8,"Writable sent request/receiving reply");
$Watcher->cb(\&LondReadable);
$Watcher->poll("r");
} else {
# Control only passes here on an error:
# the socket state does not match any
# of the known states... so an error
# must be logged.
&Debug(4, "Invalid socket state ".$State."\n");
}
}
=pod
=cut
sub QueueDelayed {
Debug(3,"QueueDelayed called");
my $path = "$perlvar{'lonSockDir'}/delayed";
Debug(4, "Delayed path: ".$path);
opendir(DIRHANDLE, $path);
@alldelayed = grep /\.$RemoteHost$/, readdir DIRHANDLE;
Debug(4, "Got ".$alldelayed." delayed files");
closedir(DIRHANDLE);
my $dfname;
my $reqfile;
foreach $dfname (sort @alldelayed) {
$reqfile = "$path/$dfname";
Debug(4, "queueing ".$reqfile);
my $Handle = IO::File->new($reqfile);
my $cmd = <$Handle>;
chomp $cmd; # There may or may not be a newline...
$cmd = $cmd."\n"; # now for sure there's exactly one newline.
my $Transaction = LondTransaction->new($cmd);
$Transaction->SetDeferred($reqfile);
QueueTransaction($Transaction);
}
}
=pod
=head2 MakeLondConnection
Create a new lond connection object, and start it towards its initial
idleness. Once idle, it becomes elligible to receive transactions
from the work queue. If the work queue is not empty when the
connection is completed and becomes idle, it will dequeue an entry and
start off on it.
=cut
sub MakeLondConnection {
Debug(4,"MakeLondConnection to ".GetServerHost()." on port "
.GetServerPort());
my $Connection = LondConnection->new(&GetServerHost(),
&GetServerPort());
if($Connection == undef) { # Needs to be more robust later.
Log("CRITICAL","Failed to make a connection with lond.");
$ConnectionRetriesLeft--;
return 0; # Failure.
} else {
$ConnectionRetriesLeft = $ConnectionRetries; # success resets the count
# The connection needs to have writability
# monitored in order to send the init sequence
# that starts the whole authentication/key
# exchange underway.
#
my $Socket = $Connection->GetSocket();
if($Socket == undef) {
die "did not get a socket from the connection";
} else {
&Debug(9,"MakeLondConnection got socket: ".$Socket);
}
$event = Event->io(fd => $Socket,
poll => 'w',
cb => \&LondWritable,
data => $Connection,
desc => 'Connection to lond server');
$ActiveConnections{$Connection} = $event;
$ConnectionCount++;
Debug(4, "Connection count = ".$ConnectionCount);
if($ConnectionCount == 1) { # First Connection:
QueueDelayed;
}
Log("SUCESS", "Created connection ".$ConnectionCount
." to host ".GetServerHost());
return 1; # Return success.
}
}
=pod
=head2 StartRequest
Starts a lond request going on a specified lond connection.
parameters are:
=item $Lond
Connection to the lond that will send the transaction and receive the
reply.
=item $Client
Connection to the client that is making this request We got the
request from this socket, and when the request has been relayed to
lond and we get a reply back from lond it will get sent to this
socket.
=item $Request
The text of the request to send.
=cut
sub StartRequest {
my $Lond = shift;
my $Request = shift; # This is a LondTransaction.
Debug(6, "StartRequest: ".$Request->getRequest());
my $Socket = $Lond->GetSocket();
$Request->Activate($Lond);
$ActiveTransactions{$Lond} = $Request;
$Lond->InitiateTransaction($Request->getRequest());
$event = Event->io(fd => $Socket,
poll => "w",
cb => \&LondWritable,
data => $Lond,
desc => "lond transaction connection");
$ActiveConnections{$Lond} = $event;
Debug(8," Start Request made watcher data with ".$event->data."\n");
}
=pod
=head2 QueueTransaction
If there is an idle lond connection, it is put to work doing this
transaction. Otherwise, the transaction is placed in the work queue.
If placed in the work queue and the maximum number of connections has
not yet been created, a new connection will be started. Our goal is
to eventually have a sufficient number of connections that the work
queue will typically be empty. parameters are:
=item Socket
open on the lonc client.
=item Request
data to send to the lond.
=cut
sub QueueTransaction {
my $requestData = shift; # This is a LondTransaction.
my $cmd = $requestData->getRequest();
Debug(6,"QueueTransaction: ".$cmd);
my $LondSocket = $IdleConnections->pop();
if(!defined $LondSocket) { # Need to queue request.
Debug(8,"Must queue...");
$WorkQueue->enqueue($requestData);
if($ConnectionCount < $MaxConnectionCount) {
Debug(4,"Starting additional lond connection");
if(MakeLondConnection() == 0) {
EmptyQueue(); # Fail transactions, can't make connection.
}
}
} else { # Can start the request:
Debug(8,"Can start...");
StartRequest($LondSocket, $requestData);
}
}
#-------------------------- Lonc UNIX socket handling ---------------------
=pod
=head2 ClientRequest
Callback that is called when data can be read from the UNIX domain
socket connecting us with an apache server process.
=cut
sub ClientRequest {
Debug(6, "ClientRequest");
my $event = shift;
my $watcher = $event->w;
my $socket = $watcher->fd;
my $data = $watcher->data;
my $thisread;
Debug(9, " Watcher named: ".$watcher->desc);
my $rv = $socket->recv($thisread, POSIX::BUFSIZ, 0);
Debug(8, "rcv: data length = ".length($thisread)
." read =".$thisread);
unless (defined $rv && length($thisread)) {
# Likely eof on socket.
Debug(5,"Client Socket closed on lonc for ".$RemoteHost);
close($socket);
$watcher->cancel();
delete($ActiveClients{$socket});
return;
}
Debug(8,"Data: ".$data." this read: ".$thisread);
$data = $data.$thisread; # Append new data.
$watcher->data($data);
if($data =~ /(.*\n)/) { # Request entirely read.
if($data eq "close_connection_exit\n") {
Log("CRITICAL",
"Request Close Connection ... exiting");
CloseAllLondConnections();
exit;
}
Debug(8, "Complete transaction received: ".$data);
my $Transaction = LondTransaction->new($data);
$Transaction->SetClient($socket);
QueueTransaction($Transaction);
$watcher->cancel(); # Done looking for input data.
}
}
=pod
=head2 NewClient
Callback that is called when a connection is received on the unix
socket for a new client of lonc. The callback is parameterized by the
event.. which is a-priori assumed to be an io event, and therefore has
an fd member that is the Listener socket. We Accept the connection
and register a new event on the readability of that socket:
=cut
sub NewClient {
Debug(6, "NewClient");
my $event = shift; # Get the event parameters.
my $watcher = $event->w;
my $socket = $watcher->fd; # Get the event' socket.
my $connection = $socket->accept(); # Accept the client connection.
Debug(8,"Connection request accepted from "
.GetPeername($connection, AF_UNIX));
my $description = sprintf("Connection to lonc client %d",
$ClientConnection);
Debug(9, "Creating event named: ".$description);
Event->io(cb => \&ClientRequest,
poll => 'r',
desc => $description,
data => "",
fd => $connection);
$ActiveClients{$connection} = $ClientConnection;
$ClientConnection++;
}
=pod
=head2 GetLoncSocketPath
Returns the name of the UNIX socket on which to listen for client
connections.
=cut
sub GetLoncSocketPath {
return $UnixSocketDir."/".GetServerHost();
}
=pod
=head2 GetServerHost
Returns the host whose lond we talk with.
=cut
sub GetServerHost {
return $RemoteHost; # Setup by the fork.
}
=pod
=head2 GetServerPort
Returns the lond port number.
=cut
sub GetServerPort {
return $perlvar{londPort};
}
=pod
=head2 SetupLoncListener
Setup a lonc listener event. The event is called when the socket
becomes readable.. that corresponds to the receipt of a new
connection. The event handler established will accept the connection
(creating a communcations channel), that int turn will establish
another event handler to subess requests.
=cut
sub SetupLoncListener {
my $socket;
my $SocketName = GetLoncSocketPath();
unlink($SocketName);
unless ($socket =IO::Socket::UNIX->new(Local => $SocketName,
Listen => 10,
Type => SOCK_STREAM)) {
die "Failed to create a lonc listner socket";
}
Event->io(cb => \&NewClient,
poll => 'r',
desc => 'Lonc listener Unix Socket',
fd => $socket);
}
=pod
=head2 ChildStatus
Child USR1 signal handler to report the most recent status
into the status file.
=cut
sub ChildStatus {
my $event = shift;
my $watcher = $event->w;
Debug(2, "Reporting child status because : ".$watcher->data);
my $docdir = $perlvar{'lonDocRoot'};
my $fh = IO::File->new(">>$docdir/lon-status/loncstatus.txt");
print $fh $$."\t".$RemoteHost."\t".$Status."\t".
$RecentLogEntry."\n";
}
=pod
=head2 SignalledToDeath
Called in response to a signal that causes a chid process to die.
=cut
sub SignalledToDeath {
my $event = shift;
my $watcher= $event->w;
Debug(2,"Signalled to death! via ".$watcher->data);
my ($signal) = $watcher->data;
chomp($signal);
Log("CRITICAL", "Abnormal exit. Child $$ for $RemoteHost "
."died through "."\"$signal\"");
LogPerm("F:lonc: $$ on $RemoteHost signalled to death: "
."\"$signal\"");
exit 0;
}
=head2 ToggleDebug
This sub toggles trace debugging on and off.
=cut
sub ToggleDebug {
my $Current = $DebugLevel;
$DebugLevel = $NextDebugLevel;
$NextDebugLevel = $Current;
Log("SUCCESS", "New debugging level for $RemoteHost now $DebugLevel");
}
=head2 ChildProcess
This sub implements a child process for a single lonc daemon.
=cut
sub ChildProcess {
#
# Signals must be handled by the Event framework...
#
Event->signal(signal => "QUIT",
cb => \&SignalledToDeath,
data => "QUIT");
Event->signal(signal => "HUP",
cb => \&ChildStatus,
data => "HUP");
Event->signal(signal => "USR1",
cb => \&ChildStatus,
data => "USR1");
Event->signal(signal => "INT",
cb => \&ToggleDebug,
data => "INT");
SetupTimer();
SetupLoncListener();
$Event::Debuglevel = $DebugLevel;
Debug(9, "Making initial lond connection for ".$RemoteHost);
# Setup the initial server connection:
# &MakeLondConnection(); // let first work requirest do it.
Debug(9,"Entering event loop");
my $ret = Event::loop(); # Start the main event loop.
die "Main event loop exited!!!";
}
# Create a new child for host passed in:
sub CreateChild {
my $sigset = POSIX::SigSet->new(SIGINT);
sigprocmask(SIG_BLOCK, $sigset);
my $host = shift;
$RemoteHost = $host;
Log("CRITICAL", "Forking server for ".$host);
$pid = fork;
if($pid) { # Parent
$RemoteHost = "Parent";
$ChildHash{$pid} = $RemoteHost;
sigprocmask(SIG_UNBLOCK, $sigset);
} else { # child.
ShowStatus("Connected to ".$RemoteHost);
$SIG{INT} = DEFAULT;
sigprocmask(SIG_UNBLOCK, $sigset);
ChildProcess; # Does not return.
}
}
#
# Parent process logic pass 1:
# For each entry in the hosts table, we will
# fork off an instance of ChildProcess to service the transactions
# to that host. Each pid will be entered in a global hash
# with the value of the key, the host.
# The parent will then enter a loop to wait for process exits.
# Each exit gets logged and the child gets restarted.
#
#
# Fork and start in new session so hang-up isn't going to
# happen without intent.
#
ShowStatus("Forming new session");
my $childpid = fork;
if ($childpid != 0) {
sleep 4; # Give child a chacne to break to
exit 0; # a new sesion.
}
#
# Write my pid into the pid file so I can be located
#
ShowStatus("Parent writing pid file:");
$execdir = $perlvar{'lonDaemons'};
open (PIDSAVE, ">$execdir/logs/lonc.pid");
print PIDSAVE "$$\n";
close(PIDSAVE);
if (POSIX::setsid() < 0) {
print "Could not create new session\n";
exit -1;
}
ShowStatus("Forking node servers");
Log("CRITICAL", "--------------- Starting children ---------------");
my $HostIterator = LondConnection::GetHostIterator;
while (! $HostIterator->end()) {
$hostentryref = $HostIterator->get();
CreateChild($hostentryref->[0]);
$HostIterator->next();
}
$RemoteHost = "Parent Server";
# Maintain the population:
ShowStatus("Parent keeping the flock");
#
# Set up parent signals:
#
$SIG{INT} = \&Terminate;
$SIG{TERM} = \&Terminate;
$SIG{HUP} = \&Restart;
$SIG{USR1} = \&CheckKids;
while(1) {
$deadchild = wait();
if(exists $ChildHash{$deadchild}) { # need to restart.
$deadhost = $ChildHash{$deadchild};
delete($ChildHash{$deadchild});
Log("WARNING","Lost child pid= ".$deadchild.
"Connected to host ".$deadhost);
Log("INFO", "Restarting child procesing ".$deadhost);
CreateChild($deadhost);
}
}
=pod
=head1 CheckKids
Since kids do not die as easily in this implementation
as the previous one, there is no need to restart the
dead ones (all dead kids get restarted when they die!!)
The only thing this function does is to pass USR1 to the
kids so that they report their status.
=cut
sub CheckKids {
Debug(2, "Checking status of children");
my $docdir = $perlvar{'lonDocRoot'};
my $fh = IO::File->new(">$docdir/lon-status/loncstatus.txt");
my $now=time;
my $local=localtime($now);
print $fh "LONC status $local - parent $$ \n\n";
foreach $pid (keys %ChildHash) {
Debug(2, "Sending USR1 -> $pid");
kill 'USR1' => $pid; # Tell Child to report status.
sleep 1; # Wait so file doesn't intermix.
}
}
=pod
=head1 Restart
Signal handler for HUP... all children are killed and
we self restart. This is an el-cheapo way to re read
the config file.
=cut
sub Restart {
KillThemAll; # First kill all the children.
Log("CRITICAL", "Restarting");
my $execdir = $perlvar{'lonDaemons'};
unlink("$execdir/logs/lonc.pid");
exec("$execdir/lonc");
}
=pod
=head1 KillThemAll
Signal handler that kills all children by sending them a
SIGHUP. Responds to sigint and sigterm.
=cut
sub KillThemAll {
Debug(2, "Kill them all!!");
local($SIG{CHLD}) = 'IGNORE'; # Our children >will< die.
foreach $pid (keys %ChildHash) {
my $serving = $ChildHash{$pid};
Debug(2, "Killing lonc for $serving pid = $pid");
ShowStatus("Killing lonc for $serving pid = $pid");
Log("CRITICAL", "Killing lonc for $serving pid = $pid");
kill 'QUIT' => $pid;
delete($ChildHash{$pid});
}
my $execdir = $perlvar{'lonDaemons'};
unlink("$execdir/logs/lonc.pid");
}
=pod
=head1 Terminate
Terminate the system.
=cut
sub Terminate {
KillThemAll;
Log("CRITICAL","Master process exiting");
exit 0;
}
=pod
=head1 Theory
The event class is used to build this as a single process with an
event driven model. The following events are handled:
=item UNIX Socket connection Received
=item Request data arrives on UNIX data transfer socket.
=item lond connection becomes writable.
=item timer fires at 1 second intervals.
All sockets are run in non-blocking mode. Timeouts managed by the timer
handler prevents hung connections.
Key data structures:
=item RequestQueue
A queue of requests received from UNIX sockets that are
waiting for a chance to be forwarded on a lond connection socket.
=item ActiveConnections
A hash of lond connections that have transactions in process that are
available to be timed out.
=item ActiveTransactions
A hash indexed by lond connections that contain the client reply
socket for each connection that has an active transaction on it.
=item IdleConnections
A hash of lond connections that have no work to do. These connections
can be closed if they are idle for a long enough time.
=cut
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>