1: # The LearningOnline Network
2: # TCP networking package
3: #
4: # Functions for use by content handlers:
5: #
6: # plaintext(short) : plain text explanation of short term
7: # fileembstyle(ext) : embed style in page for file extension
8: # filedescription(ext) : descriptor text for file extension
9: # allowed(short,url) : returns codes for allowed actions
10: # F: full access
11: # U,I,K: authentication modes (cxx only)
12: # '': forbidden
13: # 1: user needs to choose course
14: # 2: browse allowed
15: # definerole(rolename,sys,dom,cou) : define a custom role rolename
16: # set priviledges in format of lonTabs/roles.tab for
17: # system, domain and course level,
18: # assignrole(udom,uname,url,role,end,start) : give a role to a user for the
19: # level given by url. Optional start and end dates
20: # (leave empty string or zero for "no date")
21: # assigncustomrole (udom,uname,url,rdom,rnam,rolename,end,start) : give a
22: # custom role to a user for the level given by url.
23: # Specify name and domain of role author, and role name
24: # revokerole (udom,uname,url,role) : Revoke a role for url
25: # revokecustomrole (udom,uname,url,rdom,rnam,rolename) : Revoke a custom role
26: # appenv(hash) : adds hash to session environment
27: # delenv(varname) : deletes all environment entries starting with varname
28: # store(hash) : stores hash permanently for this url
29: # cstore(hash) : critical store
30: # restore : returns hash for this url
31: # eget(namesp,array) : returns hash with keys from array filled in from namesp
32: # get(namesp,array) : returns hash with keys from array filled in from namesp
33: # del(namesp,array) : deletes keys out of array from namesp
34: # put(namesp,hash) : stores hash in namesp
35: # cput(namesp,hash) : critical put
36: # dump(namesp) : dumps the complete namespace into a hash
37: # ssi(url,hash) : does a complete request cycle on url to localhost, posts
38: # hash
39: # coursedescription(id) : returns and caches course description for id
40: # repcopy(filename) : replicate file
41: # dirlist(url) : gets a directory listing
42: # directcondval(index) : reading condition value of single condition from
43: # state string
44: # condval(index) : value of condition index based on state
45: # EXT(name) : value of a variable
46: # refreshstate() : refresh the state information string
47: # symblist(map,hash) : Updates symbolic storage links
48: # symbread([filename]) : returns the data handle (filename optional)
49: # rndseed() : returns a random seed
50: # getfile(filename) : returns the contents of filename, or a -1 if it can't
51: # be found, replicates and subscribes to the file
52: # filelocation(dir,file) : returns a farily clean absolute reference to file
53: # from the directory dir
54: # hreflocation(dir,file) : same as filelocation, but for hrefs
55: # log(domain,user,home,msg) : write to permanent log for user
56: #
57: # 6/1/99,6/2,6/10,6/11,6/12,6/14,6/26,6/28,6/29,6/30,
58: # 7/1,7/2,7/9,7/10,7/12,7/14,7/15,7/19,
59: # 11/8,11/16,11/18,11/22,11/23,12/22,
60: # 01/06,01/13,02/24,02/28,02/29,
61: # 03/01,03/02,03/06,03/07,03/13,
62: # 04/05,05/29,05/31,06/01,
63: # 06/05,06/26 Gerd Kortemeyer
64: # 06/26 Ben Tyszka
65: # 06/30,07/15,07/17,07/18,07/20,07/21,07/22,07/25 Gerd Kortemeyer
66: # 08/14 Ben Tyszka
67: # 08/22,08/28,08/31,09/01,09/02,09/04,09/05,09/25,09/28,09/30 Gerd Kortemeyer
68: # 10/04 Gerd Kortemeyer
69: # 10/04 Guy Albertelli
70: # 10/06,10/09,10/10,10/11,10/14,10/20,10/23,10/25,10/26,10/27,10/28,10/29,
71: # 10/30,10/31,11/2 Gerd Kortemeyer
72:
73: package Apache::lonnet;
74:
75: use strict;
76: use Apache::File;
77: use LWP::UserAgent();
78: use HTTP::Headers;
79: use vars
80: qw(%perlvar %hostname %homecache %spareid %hostdom %libserv %pr %prp %fe %fd $readit);
81: use IO::Socket;
82: use GDBM_File;
83: use Apache::Constants qw(:common :http);
84:
85: # --------------------------------------------------------------------- Logging
86:
87: sub logthis {
88: my $message=shift;
89: my $execdir=$perlvar{'lonDaemons'};
90: my $now=time;
91: my $local=localtime($now);
92: my $fh=Apache::File->new(">>$execdir/logs/lonnet.log");
93: print $fh "$local ($$): $message\n";
94: return 1;
95: }
96:
97: sub logperm {
98: my $message=shift;
99: my $execdir=$perlvar{'lonDaemons'};
100: my $now=time;
101: my $local=localtime($now);
102: my $fh=Apache::File->new(">>$execdir/logs/lonnet.perm.log");
103: print $fh "$now:$message:$local\n";
104: return 1;
105: }
106:
107: # -------------------------------------------------- Non-critical communication
108: sub subreply {
109: my ($cmd,$server)=@_;
110: my $peerfile="$perlvar{'lonSockDir'}/$server";
111: my $client=IO::Socket::UNIX->new(Peer =>"$peerfile",
112: Type => SOCK_STREAM,
113: Timeout => 10)
114: or return "con_lost";
115: print $client "$cmd\n";
116: my $answer=<$client>;
117: if (!$answer) { $answer="con_lost"; }
118: chomp($answer);
119: return $answer;
120: }
121:
122: sub reply {
123: my ($cmd,$server)=@_;
124: my $answer=subreply($cmd,$server);
125: if ($answer eq 'con_lost') { $answer=subreply($cmd,$server); }
126: if (($answer=~/^error:/) || ($answer=~/^refused/) ||
127: ($answer=~/^rejected/)) {
128: &logthis("<font color=blue>WARNING:".
129: " $cmd to $server returned $answer</font>");
130: }
131: return $answer;
132: }
133:
134: # ----------------------------------------------------------- Send USR1 to lonc
135:
136: sub reconlonc {
137: my $peerfile=shift;
138: &logthis("Trying to reconnect for $peerfile");
139: my $loncfile="$perlvar{'lonDaemons'}/logs/lonc.pid";
140: if (my $fh=Apache::File->new("$loncfile")) {
141: my $loncpid=<$fh>;
142: chomp($loncpid);
143: if (kill 0 => $loncpid) {
144: &logthis("lonc at pid $loncpid responding, sending USR1");
145: kill USR1 => $loncpid;
146: sleep 1;
147: if (-e "$peerfile") { return; }
148: &logthis("$peerfile still not there, give it another try");
149: sleep 5;
150: if (-e "$peerfile") { return; }
151: &logthis(
152: "<font color=blue>WARNING: $peerfile still not there, giving up</font>");
153: } else {
154: &logthis(
155: "<font color=blue>WARNING:".
156: " lonc at pid $loncpid not responding, giving up</font>");
157: }
158: } else {
159: &logthis('<font color=blue>WARNING: lonc not running, giving up</font>');
160: }
161: }
162:
163: # ------------------------------------------------------ Critical communication
164:
165: sub critical {
166: my ($cmd,$server)=@_;
167: my $answer=reply($cmd,$server);
168: if ($answer eq 'con_lost') {
169: my $pingreply=reply('ping',$server);
170: &reconlonc("$perlvar{'lonSockDir'}/$server");
171: my $pongreply=reply('pong',$server);
172: &logthis("Ping/Pong for $server: $pingreply/$pongreply");
173: $answer=reply($cmd,$server);
174: if ($answer eq 'con_lost') {
175: my $now=time;
176: my $middlename=$cmd;
177: $middlename=substr($middlename,0,16);
178: $middlename=~s/\W//g;
179: my $dfilename=
180: "$perlvar{'lonSockDir'}/delayed/$now.$middlename.$server";
181: {
182: my $dfh;
183: if ($dfh=Apache::File->new(">$dfilename")) {
184: print $dfh "$cmd\n";
185: }
186: }
187: sleep 2;
188: my $wcmd='';
189: {
190: my $dfh;
191: if ($dfh=Apache::File->new("$dfilename")) {
192: $wcmd=<$dfh>;
193: }
194: }
195: chomp($wcmd);
196: if ($wcmd eq $cmd) {
197: &logthis("<font color=blue>WARNING: ".
198: "Connection buffer $dfilename: $cmd</font>");
199: &logperm("D:$server:$cmd");
200: return 'con_delayed';
201: } else {
202: &logthis("<font color=red>CRITICAL:"
203: ." Critical connection failed: $server $cmd</font>");
204: &logperm("F:$server:$cmd");
205: return 'con_failed';
206: }
207: }
208: }
209: return $answer;
210: }
211:
212: # ---------------------------------------------------------- Append Environment
213:
214: sub appenv {
215: my %newenv=@_;
216: map {
217: if (($newenv{$_}=~/^user\.role/) || ($newenv{$_}=~/^user\.priv/)) {
218: &logthis("<font color=blue>WARNING: ".
219: "Attempt to modify environment ".$_." to ".$newenv{$_});
220: delete($newenv{$_});
221: } else {
222: $ENV{$_}=$newenv{$_};
223: }
224: } keys %newenv;
225: my @oldenv;
226: {
227: my $fh;
228: unless ($fh=Apache::File->new("$ENV{'user.environment'}")) {
229: return 'error';
230: }
231: @oldenv=<$fh>;
232: }
233: for (my $i=0; $i<=$#oldenv; $i++) {
234: chomp($oldenv[$i]);
235: if ($oldenv[$i] ne '') {
236: my ($name,$value)=split(/=/,$oldenv[$i]);
237: unless (defined($newenv{$name})) {
238: $newenv{$name}=$value;
239: }
240: }
241: }
242: {
243: my $fh;
244: unless ($fh=Apache::File->new(">$ENV{'user.environment'}")) {
245: return 'error';
246: }
247: my $newname;
248: foreach $newname (keys %newenv) {
249: print $fh "$newname=$newenv{$newname}\n";
250: }
251: }
252: return 'ok';
253: }
254: # ----------------------------------------------------- Delete from Environment
255:
256: sub delenv {
257: my $delthis=shift;
258: my %newenv=();
259: if (($delthis=~/user\.role/) || ($delthis=~/user\.priv/)) {
260: &logthis("<font color=blue>WARNING: ".
261: "Attempt to delete from environment ".$delthis);
262: return 'error';
263: }
264: my @oldenv;
265: {
266: my $fh;
267: unless ($fh=Apache::File->new("$ENV{'user.environment'}")) {
268: return 'error';
269: }
270: @oldenv=<$fh>;
271: }
272: {
273: my $fh;
274: unless ($fh=Apache::File->new(">$ENV{'user.environment'}")) {
275: return 'error';
276: }
277: map {
278: unless ($_=~/^$delthis/) { print $fh $_; }
279: } @oldenv;
280: }
281: return 'ok';
282: }
283:
284: # ------------------------------ Find server with least workload from spare.tab
285:
286: sub spareserver {
287: my $tryserver;
288: my $spareserver='';
289: my $lowestserver=100;
290: foreach $tryserver (keys %spareid) {
291: my $answer=reply('load',$tryserver);
292: if (($answer =~ /\d/) && ($answer<$lowestserver)) {
293: $spareserver="http://$hostname{$tryserver}";
294: $lowestserver=$answer;
295: }
296: }
297: return $spareserver;
298: }
299:
300: # --------- Try to authenticate user from domain's lib servers (first this one)
301:
302: sub authenticate {
303: my ($uname,$upass,$udom)=@_;
304: $upass=escape($upass);
305: if (($perlvar{'lonRole'} eq 'library') &&
306: ($udom eq $perlvar{'lonDefDomain'})) {
307: my $answer=reply("encrypt:auth:$udom:$uname:$upass",$perlvar{'lonHostID'});
308: if ($answer =~ /authorized/) {
309: if ($answer eq 'authorized') {
310: &logthis("User $uname at $udom authorized by local server");
311: return $perlvar{'lonHostID'};
312: }
313: if ($answer eq 'non_authorized') {
314: &logthis("User $uname at $udom rejected by local server");
315: return 'no_host';
316: }
317: }
318: }
319:
320: my $tryserver;
321: foreach $tryserver (keys %libserv) {
322: if ($hostdom{$tryserver} eq $udom) {
323: my $answer=reply("encrypt:auth:$udom:$uname:$upass",$tryserver);
324: if ($answer =~ /authorized/) {
325: if ($answer eq 'authorized') {
326: &logthis("User $uname at $udom authorized by $tryserver");
327: return $tryserver;
328: }
329: if ($answer eq 'non_authorized') {
330: &logthis("User $uname at $udom rejected by $tryserver");
331: return 'no_host';
332: }
333: }
334: }
335: }
336: &logthis("User $uname at $udom could not be authenticated");
337: return 'no_host';
338: }
339:
340: # ---------------------- Find the homebase for a user from domain's lib servers
341:
342: sub homeserver {
343: my ($uname,$udom)=@_;
344:
345: my $index="$uname:$udom";
346: if ($homecache{$index}) { return "$homecache{$index}"; }
347:
348: my $tryserver;
349: foreach $tryserver (keys %libserv) {
350: if ($hostdom{$tryserver} eq $udom) {
351: my $answer=reply("home:$udom:$uname",$tryserver);
352: if ($answer eq 'found') {
353: $homecache{$index}=$tryserver;
354: return $tryserver;
355: }
356: }
357: }
358: return 'no_host';
359: }
360:
361: # ----------------------------- Subscribe to a resource, return URL if possible
362:
363: sub subscribe {
364: my $fname=shift;
365: my $author=$fname;
366: $author=~s/\/home\/httpd\/html\/res\/([^\/]*)\/([^\/]*).*/$1\/$2/;
367: my ($udom,$uname)=split(/\//,$author);
368: my $home=homeserver($uname,$udom);
369: if (($home eq 'no_host') || ($home eq $perlvar{'lonHostID'})) {
370: return 'not_found';
371: }
372: my $answer=reply("sub:$fname",$home);
373: return $answer;
374: }
375:
376: # -------------------------------------------------------------- Replicate file
377:
378: sub repcopy {
379: my $filename=shift;
380: $filename=~s/\/+/\//g;
381: my $transname="$filename.in.transfer";
382: if ((-e $filename) || (-e $transname)) { return OK; }
383: my $remoteurl=subscribe($filename);
384: if ($remoteurl eq 'con_lost') {
385: &logthis("Subscribe returned con_lost: $filename");
386: return HTTP_SERVICE_UNAVAILABLE;
387: } elsif ($remoteurl eq 'not_found') {
388: &logthis("Subscribe returned not_found: $filename");
389: return HTTP_NOT_FOUND;
390: } elsif ($remoteurl eq 'rejected') {
391: &logthis("Subscribe returned rejected: $filename");
392: return FORBIDDEN;
393: } elsif ($remoteurl eq 'directory') {
394: return OK;
395: } else {
396: my @parts=split(/\//,$filename);
397: my $path="/$parts[1]/$parts[2]/$parts[3]/$parts[4]";
398: if ($path ne "$perlvar{'lonDocRoot'}/res") {
399: &logthis("Malconfiguration for replication: $filename");
400: return HTTP_BAD_REQUEST;
401: }
402: my $count;
403: for ($count=5;$count<$#parts;$count++) {
404: $path.="/$parts[$count]";
405: if ((-e $path)!=1) {
406: mkdir($path,0777);
407: }
408: }
409: my $ua=new LWP::UserAgent;
410: my $request=new HTTP::Request('GET',"$remoteurl");
411: my $response=$ua->request($request,$transname);
412: if ($response->is_error()) {
413: unlink($transname);
414: my $message=$response->status_line;
415: &logthis("<font color=blue>WARNING:"
416: ." LWP get: $message: $filename</font>");
417: return HTTP_SERVICE_UNAVAILABLE;
418: } else {
419: if ($remoteurl!~/\.meta$/) {
420: my $mrequest=new HTTP::Request('GET',$remoteurl.'.meta');
421: my $mresponse=$ua->request($mrequest,$filename.'.meta');
422: if ($mresponse->is_error()) {
423: unlink($filename.'.meta');
424: &logthis(
425: "<font color=yellow>INFO: No metadata: $filename</font>");
426: }
427: }
428: rename($transname,$filename);
429: return OK;
430: }
431: }
432: }
433:
434: # --------------------------------------------------------- Server Side Include
435:
436: sub ssi {
437:
438: my ($fn,%form)=@_;
439:
440: my $ua=new LWP::UserAgent;
441:
442: my $request;
443:
444: if (%form) {
445: $request=new HTTP::Request('POST',"http://".$ENV{'HTTP_HOST'}.$fn);
446: $request->content(join '&', map { "$_=$form{$_}" } keys %form);
447: } else {
448: $request=new HTTP::Request('GET',"http://".$ENV{'HTTP_HOST'}.$fn);
449: }
450:
451: $request->header(Cookie => $ENV{'HTTP_COOKIE'});
452: my $response=$ua->request($request);
453:
454: return $response->content;
455: }
456:
457: # ------------------------------------------------------------------------- Log
458:
459: sub log {
460: my ($dom,$nam,$hom,$what)=@_;
461: return critical("log:$dom:$nam:$what",$hom);
462: }
463:
464: # ----------------------------------------------------------------------- Store
465:
466: sub store {
467: my %storehash=@_;
468: my $symb;
469: unless ($symb=escape(&symbread())) { return ''; }
470: my $namespace;
471: unless ($namespace=$ENV{'request.course.id'}) { return ''; }
472: my $namevalue='';
473: map {
474: $namevalue.=escape($_).'='.escape($storehash{$_}).'&';
475: } keys %storehash;
476: $namevalue=~s/\&$//;
477: return reply(
478: "store:$ENV{'user.domain'}:$ENV{'user.name'}:$namespace:$symb:$namevalue",
479: "$ENV{'user.home'}");
480: }
481:
482: # -------------------------------------------------------------- Critical Store
483:
484: sub cstore {
485: my %storehash=@_;
486: my $symb;
487: unless ($symb=escape(&symbread())) { return ''; }
488: my $namespace;
489: unless ($namespace=$ENV{'request.course.id'}) { return ''; }
490: my $namevalue='';
491: map {
492: $namevalue.=escape($_).'='.escape($storehash{$_}).'&';
493: } keys %storehash;
494: $namevalue=~s/\&$//;
495: return critical(
496: "store:$ENV{'user.domain'}:$ENV{'user.name'}:$namespace:$symb:$namevalue",
497: "$ENV{'user.home'}");
498: }
499:
500: # --------------------------------------------------------------------- Restore
501:
502: sub restore {
503: my $symb;
504: unless ($symb=escape(&symbread())) { return ''; }
505: my $namespace;
506: unless ($namespace=$ENV{'request.course.id'}) { return ''; }
507: my $answer=reply(
508: "restore:$ENV{'user.domain'}:$ENV{'user.name'}:$namespace:$symb",
509: "$ENV{'user.home'}");
510: my %returnhash=();
511: map {
512: my ($name,$value)=split(/\=/,$_);
513: $returnhash{&unescape($name)}=&unescape($value);
514: } split(/\&/,$answer);
515: map {
516: $returnhash{$_}=$returnhash{$returnhash{'version'}.':'.$_};
517: } split(/\:/,$returnhash{$returnhash{'version'}.':keys'});
518: return %returnhash;
519: }
520:
521: # ---------------------------------------------------------- Course Description
522:
523: sub coursedescription {
524: my $courseid=shift;
525: $courseid=~s/^\///;
526: $courseid=~s/\_/\//g;
527: my ($cdomain,$cnum)=split(/\//,$courseid);
528: my $chome=homeserver($cnum,$cdomain);
529: if ($chome ne 'no_host') {
530: my $rep=reply("dump:$cdomain:$cnum:environment",$chome);
531: if ($rep ne 'con_lost') {
532: my $normalid=$courseid;
533: $normalid=~s/\//\_/g;
534: my %envhash=();
535: my %returnhash=('home' => $chome,
536: 'domain' => $cdomain,
537: 'num' => $cnum);
538: map {
539: my ($name,$value)=split(/\=/,$_);
540: $name=&unescape($name);
541: $value=&unescape($value);
542: $returnhash{$name}=$value;
543: $envhash{'course.'.$normalid.'.'.$name}=$value;
544: } split(/\&/,$rep);
545: $returnhash{'url'}='/res/'.declutter($returnhash{'url'});
546: $returnhash{'fn'}=$perlvar{'lonDaemons'}.'/tmp/'.
547: $ENV{'user.name'}.'_'.$cdomain.'_'.$cnum;
548: $envhash{'course.'.$normalid.'.last_cache'}=time;
549: &appenv(%envhash);
550: return %returnhash;
551: }
552: }
553: return ();
554: }
555:
556: # -------------------------------------------------------- Get user priviledges
557:
558: sub rolesinit {
559: my ($domain,$username,$authhost)=@_;
560: my $rolesdump=reply("dump:$domain:$username:roles",$authhost);
561: if (($rolesdump eq 'con_lost') || ($rolesdump eq '')) { return ''; }
562: my %allroles=();
563: my %thesepriv=();
564: my $now=time;
565: my $userroles="user.login.time=$now\n";
566: my $thesestr;
567:
568: if ($rolesdump ne '') {
569: map {
570: if ($_!~/^rolesdef\&/) {
571: my ($area,$role)=split(/=/,$_);
572: $area=~s/\_\w\w$//;
573: my ($trole,$tend,$tstart)=split(/_/,$role);
574: $userroles.='user.role.'.$trole.'.'.$area.'='.
575: $tstart.'.'.$tend."\n";
576: if ($tend!=0) {
577: if ($tend<$now) {
578: $trole='';
579: }
580: }
581: if ($tstart!=0) {
582: if ($tstart>$now) {
583: $trole='';
584: }
585: }
586: if (($area ne '') && ($trole ne '')) {
587: my $spec=$trole.'.'.$area;
588: my ($tdummy,$tdomain,$trest)=split(/\//,$area);
589: if ($trole =~ /^cr\//) {
590: my ($rdummy,$rdomain,$rauthor,$rrole)=split(/\//,$trole);
591: my $homsvr=homeserver($rauthor,$rdomain);
592: if ($hostname{$homsvr} ne '') {
593: my $roledef=
594: reply("get:$rdomain:$rauthor:roles:rolesdef_$rrole",
595: $homsvr);
596: if (($roledef ne 'con_lost') && ($roledef ne '')) {
597: my ($syspriv,$dompriv,$coursepriv)=
598: split(/\_/,unescape($roledef));
599: $allroles{'cm./'}.=':'.$syspriv;
600: $allroles{$spec.'./'}.=':'.$syspriv;
601: if ($tdomain ne '') {
602: $allroles{'cm./'.$tdomain.'/'}.=':'.$dompriv;
603: $allroles{$spec.'./'.$tdomain.'/'}.=':'.$dompriv;
604: if ($trest ne '') {
605: $allroles{'cm.'.$area}.=':'.$coursepriv;
606: $allroles{$spec.'.'.$area}.=':'.$coursepriv;
607: }
608: }
609: }
610: }
611: } else {
612: $allroles{'cm./'}.=':'.$pr{$trole.':s'};
613: $allroles{$spec.'./'}.=':'.$pr{$trole.':s'};
614: if ($tdomain ne '') {
615: $allroles{'cm./'.$tdomain.'/'}.=':'.$pr{$trole.':d'};
616: $allroles{$spec.'./'.$tdomain.'/'}.=':'.$pr{$trole.':d'};
617: if ($trest ne '') {
618: $allroles{'cm.'.$area}.=':'.$pr{$trole.':c'};
619: $allroles{$spec.'.'.$area}.=':'.$pr{$trole.':c'};
620: }
621: }
622: }
623: }
624: }
625: } split(/&/,$rolesdump);
626: map {
627: %thesepriv=();
628: map {
629: if ($_ ne '') {
630: my ($priviledge,$restrictions)=split(/&/,$_);
631: if ($restrictions eq '') {
632: $thesepriv{$priviledge}='F';
633: } else {
634: if ($thesepriv{$priviledge} ne 'F') {
635: $thesepriv{$priviledge}.=$restrictions;
636: }
637: }
638: }
639: } split(/:/,$allroles{$_});
640: $thesestr='';
641: map { $thesestr.=':'.$_.'&'.$thesepriv{$_}; } keys %thesepriv;
642: $userroles.='user.priv.'.$_.'='.$thesestr."\n";
643: } keys %allroles;
644: }
645: return $userroles;
646: }
647:
648: # --------------------------------------------------------------- get interface
649:
650: sub get {
651: my ($namespace,@storearr)=@_;
652: my $items='';
653: map {
654: $items.=escape($_).'&';
655: } @storearr;
656: $items=~s/\&$//;
657: my $rep=reply("get:$ENV{'user.domain'}:$ENV{'user.name'}:$namespace:$items",
658: $ENV{'user.home'});
659: my @pairs=split(/\&/,$rep);
660: my %returnhash=();
661: my $i=0;
662: map {
663: $returnhash{$_}=unescape($pairs[$i]);
664: $i++;
665: } @storearr;
666: return %returnhash;
667: }
668:
669: # --------------------------------------------------------------- del interface
670:
671: sub del {
672: my ($namespace,@storearr)=@_;
673: my $items='';
674: map {
675: $items.=escape($_).'&';
676: } @storearr;
677: $items=~s/\&$//;
678: return reply("del:$ENV{'user.domain'}:$ENV{'user.name'}:$namespace:$items",
679: $ENV{'user.home'});
680: }
681:
682: # -------------------------------------------------------------- dump interface
683:
684: sub dump {
685: my $namespace=shift;
686: my $rep=reply("dump:$ENV{'user.domain'}:$ENV{'user.name'}:$namespace",
687: $ENV{'user.home'});
688: my @pairs=split(/\&/,$rep);
689: my %returnhash=();
690: map {
691: my ($key,$value)=split(/=/,$_);
692: $returnhash{unescape($key)}=unescape($value);
693: } @pairs;
694: return %returnhash;
695: }
696:
697: # --------------------------------------------------------------- put interface
698:
699: sub put {
700: my ($namespace,%storehash)=@_;
701: my $items='';
702: map {
703: $items.=escape($_).'='.escape($storehash{$_}).'&';
704: } keys %storehash;
705: $items=~s/\&$//;
706: return reply("put:$ENV{'user.domain'}:$ENV{'user.name'}:$namespace:$items",
707: $ENV{'user.home'});
708: }
709:
710: # ------------------------------------------------------ critical put interface
711:
712: sub cput {
713: my ($namespace,%storehash)=@_;
714: my $items='';
715: map {
716: $items.=escape($_).'='.escape($storehash{$_}).'&';
717: } keys %storehash;
718: $items=~s/\&$//;
719: return critical
720: ("put:$ENV{'user.domain'}:$ENV{'user.name'}:$namespace:$items",
721: $ENV{'user.home'});
722: }
723:
724: # -------------------------------------------------------------- eget interface
725:
726: sub eget {
727: my ($namespace,@storearr)=@_;
728: my $items='';
729: map {
730: $items.=escape($_).'&';
731: } @storearr;
732: $items=~s/\&$//;
733: my $rep=reply("eget:$ENV{'user.domain'}:$ENV{'user.name'}:$namespace:$items",
734: $ENV{'user.home'});
735: my @pairs=split(/\&/,$rep);
736: my %returnhash=();
737: my $i=0;
738: map {
739: $returnhash{$_}=unescape($pairs[$i]);
740: $i++;
741: } @storearr;
742: return %returnhash;
743: }
744:
745: # ------------------------------------------------- Check for a user priviledge
746:
747: sub allowed {
748: my ($priv,$uri)=@_;
749: $uri=&declutter($uri);
750:
751: # Free bre access to adm and meta resources
752:
753: if ((($uri=~/^adm\//) || ($uri=~/\.meta$/)) && ($priv eq 'bre')) {
754: return 'F';
755: }
756:
757: my $thisallowed='';
758: my $statecond=0;
759: my $courseprivid='';
760:
761: # Course
762:
763: if ($ENV{'user.priv.'.$ENV{'request.role'}.'./'}=~/$priv\&([^\:]*)/) {
764: $thisallowed.=$1;
765: }
766:
767: # Domain
768:
769: if ($ENV{'user.priv.'.$ENV{'request.role'}.'./'.(split(/\//,$uri))[0].'/'}
770: =~/$priv\&([^\:]*)/) {
771: $thisallowed.=$1;
772: }
773:
774: # Course: uri itself is a course
775:
776: if ($ENV{'user.priv.'.$ENV{'request.role'}.'./'.$uri}
777: =~/$priv\&([^\:]*)/) {
778: $thisallowed.=$1;
779: }
780:
781: # Full access at system, domain or course-wide level? Exit.
782:
783: if ($thisallowed=~/F/) {
784: return 'F';
785: }
786:
787: # If this is generating or modifying users, exit with special codes
788:
789: if (':csu:cdc:ccc:cin:cta:cep:ccr:cst:cad:cli:cau:cdg:'=~/\:$priv\:/) {
790: return $thisallowed;
791: }
792: #
793: # Gathered so far: system, domain and course wide priviledges
794: #
795: # Course: See if uri or referer is an individual resource that is part of
796: # the course
797:
798: if ($ENV{'request.course.id'}) {
799: $courseprivid=$ENV{'request.course.id'};
800: if ($ENV{'request.course.sec'}) {
801: $courseprivid.='/'.$ENV{'request.course.sec'};
802: }
803: $courseprivid=~s/\_/\//;
804: my $checkreferer=1;
805: my @uriparts=split(/\//,$uri);
806: my $filename=$uriparts[$#uriparts];
807: my $pathname=$uri;
808: $pathname=~s/\/$filename$//;
809: if ($ENV{'acc.res.'.$ENV{'request.course.id'}.'.'.$pathname}=~
810: /\&$filename\:([\d\|]+)\&/) {
811: $statecond=$1;
812: if ($ENV{'user.priv.'.$ENV{'request.role'}.'./'.$courseprivid}
813: =~/$priv\&([^\:]*)/) {
814: $thisallowed.=$1;
815: $checkreferer=0;
816: }
817: }
818:
819: if (($ENV{'HTTP_REFERER'}) && ($checkreferer)) {
820: my $refuri=$ENV{'HTTP_REFERER'};
821: $refuri=~s/^http\:\/\/$ENV{'request.host'}//i;
822: $refuri=&declutter($refuri);
823: my @uriparts=split(/\//,$refuri);
824: my $filename=$uriparts[$#uriparts];
825: my $pathname=$refuri;
826: $pathname=~s/\/$filename$//;
827: my @filenameparts=split(/\./,$uri);
828: if (&fileembstyle($filenameparts[$#filenameparts]) ne 'ssi') {
829: if ($ENV{'acc.res.'.$ENV{'request.course.id'}.'.'.$pathname}=~
830: /\&$filename\:([\d\|]+)\&/) {
831: my $refstatecond=$1;
832: if ($ENV{'user.priv.'.$ENV{'request.role'}.'./'.$courseprivid}
833: =~/$priv\&([^\:]*)/) {
834: $thisallowed.=$1;
835: $uri=$refuri;
836: $statecond=$refstatecond;
837: }
838: }
839: }
840: }
841: }
842:
843: #
844: # Gathered now: all priviledges that could apply, and condition number
845: #
846: #
847: # Full or no access?
848: #
849:
850: if ($thisallowed=~/F/) {
851: return 'F';
852: }
853:
854: unless ($thisallowed) {
855: return '';
856: }
857:
858: # Restrictions exist, deal with them
859: #
860: # C:according to course preferences
861: # R:according to resource settings
862: # L:unless locked
863: # X:according to user session state
864: #
865:
866: # Possibly locked functionality, check all courses
867: # Locks might take effect only after 10 minutes cache expiration for other
868: # courses, and 2 minutes for current course
869:
870: my $envkey;
871: if ($thisallowed=~/L/) {
872: foreach $envkey (keys %ENV) {
873: if ($envkey=~/^user\.role\.(st|ta)\.([^\.]*)/) {
874: my $courseid=$2;
875: my $roleid=$1.'.'.$2;
876: my $expiretime=600;
877: if ($ENV{'request.role'} eq $roleid) {
878: $expiretime=120;
879: }
880: my ($cdom,$cnum,$csec)=split(/\//,$courseid);
881: my $prefix='course.'.$cdom.'_'.$cnum.'.';
882: if ((time-$ENV{$prefix.'last_cache'})>$expiretime) {
883: &coursedescription($courseid);
884: }
885: if (($ENV{$prefix.'res.'.$uri.'.lock.sections'}=~/\,$csec\,/)
886: || ($ENV{$prefix.'res.'.$uri.'.lock.sections'} eq 'all')) {
887: if ($ENV{$prefix.'res.'.$uri.'.lock.expire'}>time) {
888: &log($ENV{'user.domain'},$ENV{'user.name'},
889: $ENV{'user.host'},
890: 'Locked by res: '.$priv.' for '.$uri.' due to '.
891: $cdom.'/'.$cnum.'/'.$csec.' expire '.
892: $ENV{$prefix.'priv.'.$priv.'.lock.expire'});
893: return '';
894: }
895: }
896: if (($ENV{$prefix.'priv.'.$priv.'.lock.sections'}=~/\,$csec\,/)
897: || ($ENV{$prefix.'priv.'.$priv.'.lock.sections'} eq 'all')) {
898: if ($ENV{'priv.'.$priv.'.lock.expire'}>time) {
899: &log($ENV{'user.domain'},$ENV{'user.name'},
900: $ENV{'user.host'},
901: 'Locked by priv: '.$priv.' for '.$uri.' due to '.
902: $cdom.'/'.$cnum.'/'.$csec.' expire '.
903: $ENV{$prefix.'priv.'.$priv.'.lock.expire'});
904: return '';
905: }
906: }
907: }
908: }
909: }
910:
911: #
912: # Rest of the restrictions depend on selected course
913: #
914:
915: unless ($ENV{'request.course.id'}) {
916: return '1';
917: }
918:
919: #
920: # Now user is definitely in a course
921: #
922:
923:
924: # Course preferences
925:
926: if ($thisallowed=~/C/) {
927: my $rolecode=(split(/\./,$ENV{'request.role'}))[0];
928: if ($ENV{'course.'.$ENV{'request.course.id'}.'.'.$priv.'.roles.denied'}
929: =~/\,$rolecode\,/) {
930: &log($ENV{'user.domain'},$ENV{'user.name'},$ENV{'user.host'},
931: 'Denied by role: '.$priv.' for '.$uri.' as '.$rolecode.' in '.
932: $ENV{'request.course.id'});
933: return '';
934: }
935: }
936:
937: # Resource preferences
938:
939: if ($thisallowed=~/R/) {
940: my $rolecode=(split(/\./,$ENV{'request.role'}))[0];
941: my $filename=$perlvar{'lonDocRoot'}.'/res/'.$uri.'.meta';
942: if (-e $filename) {
943: my @content;
944: {
945: my $fh=Apache::File->new($filename);
946: @content=<$fh>;
947: }
948: if (join('',@content)=~
949: /\<roledeny[^\>]*\>[^\<]*$rolecode[^\<]*\<\/roledeny\>/) {
950: &log($ENV{'user.domain'},$ENV{'user.name'},$ENV{'user.host'},
951: 'Denied by role: '.$priv.' for '.$uri.' as '.$rolecode);
952: return '';
953:
954: }
955: }
956: }
957:
958: # Restricted by state?
959:
960: if ($thisallowed=~/X/) {
961: if (&condval($statecond)) {
962: return '2';
963: } else {
964: return '';
965: }
966: }
967:
968: return 'F';
969: }
970:
971: # ---------------------------------------------------------- Refresh State Info
972:
973: sub refreshstate {
974: }
975:
976: # ----------------------------------------------------------------- Define Role
977:
978: sub definerole {
979: if (allowed('mcr','/')) {
980: my ($rolename,$sysrole,$domrole,$courole)=@_;
981: map {
982: my ($crole,$cqual)=split(/\&/,$_);
983: if ($pr{'cr:s'}!~/$crole/) { return "refused:s:$crole"; }
984: if ($pr{'cr:s'}=~/$crole\&/) {
985: if ($pr{'cr:s'}!~/$crole\&\w*$cqual/) {
986: return "refused:s:$crole&$cqual";
987: }
988: }
989: } split('/',$sysrole);
990: map {
991: my ($crole,$cqual)=split(/\&/,$_);
992: if ($pr{'cr:d'}!~/$crole/) { return "refused:d:$crole"; }
993: if ($pr{'cr:d'}=~/$crole\&/) {
994: if ($pr{'cr:d'}!~/$crole\&\w*$cqual/) {
995: return "refused:d:$crole&$cqual";
996: }
997: }
998: } split('/',$domrole);
999: map {
1000: my ($crole,$cqual)=split(/\&/,$_);
1001: if ($pr{'cr:c'}!~/$crole/) { return "refused:c:$crole"; }
1002: if ($pr{'cr:c'}=~/$crole\&/) {
1003: if ($pr{'cr:c'}!~/$crole\&\w*$cqual/) {
1004: return "refused:c:$crole&$cqual";
1005: }
1006: }
1007: } split('/',$courole);
1008: my $command="encrypt:rolesput:$ENV{'user.domain'}:$ENV{'user.name'}:".
1009: "$ENV{'user.domain'}:$ENV{'user.name'}:".
1010: "rolesdef_$rolename=".
1011: escape($sysrole.'_'.$domrole.'_'.$courole);
1012: return reply($command,$ENV{'user.home'});
1013: } else {
1014: return 'refused';
1015: }
1016: }
1017:
1018: # ------------------------------------------------------------------ Plain Text
1019:
1020: sub plaintext {
1021: my $short=shift;
1022: return $prp{$short};
1023: }
1024:
1025: # ------------------------------------------------------------------ Plain Text
1026:
1027: sub fileembstyle {
1028: my $ending=shift;
1029: return $fe{$ending};
1030: }
1031:
1032: # ------------------------------------------------------------ Description Text
1033:
1034: sub filedecription {
1035: my $ending=shift;
1036: return $fd{$ending};
1037: }
1038:
1039: # ----------------------------------------------------------------- Assign Role
1040:
1041: sub assignrole {
1042: my ($udom,$uname,$url,$role,$end,$start)=@_;
1043: my $mrole;
1044: $url=declutter($url);
1045: if ($role =~ /^cr\//) {
1046: unless ($url=~/\.course$/) { return 'invalid'; }
1047: unless (allowed('ccr',$url)) { return 'refused'; }
1048: $mrole='cr';
1049: } else {
1050: unless (($url=~/\.course$/) || ($url=~/\/$/)) { return 'invalid'; }
1051: unless (allowed('c'+$role)) { return 'refused'; }
1052: $mrole=$role;
1053: }
1054: my $command="encrypt:rolesput:$ENV{'user.domain'}:$ENV{'user.name'}:".
1055: "$udom:$uname:$url".'_'."$mrole=$role";
1056: if ($end) { $command.='_$end'; }
1057: if ($start) {
1058: if ($end) {
1059: $command.='_$start';
1060: } else {
1061: $command.='_0_$start';
1062: }
1063: }
1064: return &reply($command,&homeserver($uname,$udom));
1065: }
1066:
1067: # ---------------------------------------------------------- Assign Custom Role
1068:
1069: sub assigncustomrole {
1070: my ($udom,$uname,$url,$rdom,$rnam,$rolename,$end,$start)=@_;
1071: return &assignrole($udom,$uname,$url,'cr/'.$rdom.'/'.$rnam.'/'.$rolename,
1072: $end,$start);
1073: }
1074:
1075: # ----------------------------------------------------------------- Revoke Role
1076:
1077: sub revokerole {
1078: my ($udom,$uname,$url,$role)=@_;
1079: my $now=time;
1080: return &assignrole($udom,$uname,$url,$role,$now);
1081: }
1082:
1083: # ---------------------------------------------------------- Revoke Custom Role
1084:
1085: sub revokecustomrole {
1086: my ($udom,$uname,$url,$rdom,$rnam,$rolename)=@_;
1087: my $now=time;
1088: return &assigncustomrole($udom,$uname,$url,$rdom,$rnam,$rolename,$now);
1089: }
1090:
1091: # ------------------------------------------------------------ Directory lister
1092:
1093: sub dirlist {
1094: my $uri=shift;
1095: $uri=~s/^\///;
1096: $uri=~s/\/$//;
1097: my ($res,$udom,$uname,@rest)=split(/\//,$uri);
1098: if ($udom) {
1099: if ($uname) {
1100: my $listing=reply('ls:'.$perlvar{'lonDocRoot'}.'/'.$uri,
1101: homeserver($uname,$udom));
1102: return split(/:/,$listing);
1103: } else {
1104: my $tryserver;
1105: my %allusers=();
1106: foreach $tryserver (keys %libserv) {
1107: if ($hostdom{$tryserver} eq $udom) {
1108: my $listing=reply('ls:'.$perlvar{'lonDocRoot'}.'/res/'.$udom,
1109: $tryserver);
1110: if (($listing ne 'no_such_dir') && ($listing ne 'empty')
1111: && ($listing ne 'con_lost')) {
1112: map {
1113: my ($entry,@stat)=split(/&/,$_);
1114: $allusers{$entry}=1;
1115: } split(/:/,$listing);
1116: }
1117: }
1118: }
1119: my $alluserstr='';
1120: map {
1121: $alluserstr.=$_.'&user:';
1122: } sort keys %allusers;
1123: $alluserstr=~s/:$//;
1124: return split(/:/,$alluserstr);
1125: }
1126: } else {
1127: my $tryserver;
1128: my %alldom=();
1129: foreach $tryserver (keys %libserv) {
1130: $alldom{$hostdom{$tryserver}}=1;
1131: }
1132: my $alldomstr='';
1133: map {
1134: $alldomstr.=$perlvar{'lonDocRoot'}.'/res/'.$_.'&domain:';
1135: } sort keys %alldom;
1136: $alldomstr=~s/:$//;
1137: return split(/:/,$alldomstr);
1138: }
1139: }
1140:
1141: # -------------------------------------------------------- Value of a Condition
1142:
1143: sub directcondval {
1144: my $number=shift;
1145: if ($ENV{'user.state.'.$ENV{'request.course.id'}}) {
1146: return substr($ENV{'user.state.'.$ENV{'request.course.id'}},$number,1);
1147: } else {
1148: return 2;
1149: }
1150: }
1151:
1152: sub condval {
1153: my $condidx=shift;
1154: my $result=0;
1155: my $allpathcond='';
1156: map {
1157: if (defined($ENV{'acc.cond.'.$ENV{'request.course.id'}.'.'.$_})) {
1158: $allpathcond.=
1159: '('.$ENV{'acc.cond.'.$ENV{'request.course.id'}.'.'.$_}.')|';
1160: }
1161: } split(/\|/,$condidx);
1162: $allpathcond=~s/\|$//;
1163: if ($ENV{'request.course.id'}) {
1164: if ($allpathcond) {
1165: my $operand='|';
1166: my @stack;
1167: map {
1168: if ($_ eq '(') {
1169: push @stack,($operand,$result)
1170: } elsif ($_ eq ')') {
1171: my $before=pop @stack;
1172: if (pop @stack eq '&') {
1173: $result=$result>$before?$before:$result;
1174: } else {
1175: $result=$result>$before?$result:$before;
1176: }
1177: } elsif (($_ eq '&') || ($_ eq '|')) {
1178: $operand=$_;
1179: } else {
1180: my $new=directcondval($_);
1181: if ($operand eq '&') {
1182: $result=$result>$new?$new:$result;
1183: } else {
1184: $result=$result>$new?$result:$new;
1185: }
1186: }
1187: } ($allpathcond=~/(\d+|\(|\)|\&|\|)/g);
1188: }
1189: }
1190: return $result;
1191: }
1192:
1193: # --------------------------------------------------------- Value of a Variable
1194:
1195: sub EXT {
1196: my $varname=shift;
1197: my ($realm,$space,$qualifier,@therest)=split(/\./,$varname);
1198: my $rest;
1199: if ($therest[0]) {
1200: $rest=join('.',@therest);
1201: } else {
1202: $rest='';
1203: }
1204: my $qualifierrest=$qualifier;
1205: if ($rest) { $qualifierrest.='.'.$rest; }
1206: my $spacequalifierrest=$space;
1207: if ($qualifierrest) { $spacequalifierrest.='.'.$qualifierrest; }
1208: if ($realm eq 'user') {
1209: # --------------------------------------------------------------- user.resource
1210: if ($space eq 'resource') {
1211: my %restored=&restore;
1212: return $restored{$qualifierrest};
1213: # ----------------------------------------------------------------- user.access
1214: } elsif ($space eq 'access') {
1215: return &allowed($qualifier,$rest);
1216: # ------------------------------------------ user.preferences, user.environment
1217: } elsif (($space eq 'preferences') || ($space eq 'environment')) {
1218: return $ENV{join('.',('environment',$qualifierrest))};
1219: # ----------------------------------------------------------------- user.course
1220: } elsif ($space eq 'course') {
1221: return $ENV{join('.',('request.course',$qualifier))};
1222: # ------------------------------------------------------------------- user.role
1223: } elsif ($space eq 'role') {
1224: my ($role,$where)=split(/\./,$ENV{'request.role'});
1225: if ($qualifier eq 'value') {
1226: return $role;
1227: } elsif ($qualifier eq 'extent') {
1228: return $where;
1229: }
1230: # ----------------------------------------------------------------- user.domain
1231: } elsif ($space eq 'domain') {
1232: return $ENV{'user.domain'};
1233: # ------------------------------------------------------------------- user.name
1234: } elsif ($space eq 'name') {
1235: return $ENV{'user.name'};
1236: # ---------------------------------------------------- Any other user namespace
1237: } else {
1238: my $item=($rest)?$qualifier.'.'.$rest:$qualifier;
1239: my %reply=&get($space,$item);
1240: return $reply{$item};
1241: }
1242: } elsif ($realm eq 'request') {
1243: # ------------------------------------------------------------- request.browser
1244: if ($space eq 'browser') {
1245: return $ENV{'browser.'.$qualifier};
1246: # ------------------------------------------------------------ request.filename
1247: } else {
1248: return $ENV{'request.'.$spacequalifierrest};
1249: }
1250: } elsif ($realm eq 'course') {
1251: # ---------------------------------------------------------- course.description
1252: my $section='';
1253: if ($ENV{'request.course.sec'}) {
1254: $section='_'.$ENV{'request.course.sec'};
1255: }
1256: return $ENV{'course.'.$ENV{'request.course.id'}.$section.'.'.
1257: $spacequalifierrest};
1258: } elsif ($realm eq 'resource') {
1259: # ----------------------------------------------------------- resource metadata
1260: my $uri=&declutter($ENV{'request.filename'});
1261: my $filename=$perlvar{'lonDocRoot'}.'/res/'.$ENV.'.meta';
1262: if (-e $filename) {
1263: my @content;
1264: {
1265: my $fh=Apache::File->new($filename);
1266: @content=<$fh>;
1267: }
1268: if (join('',@content)=~
1269: /\<$space[^\>]*\>([^\<]*)\<\/$space\>/) {
1270: return $1;
1271: } else {
1272: return '';
1273: }
1274: }
1275: } elsif ($realm eq 'userdata') {
1276: my $uhome=&homeserver($qualifier,$space);
1277: # ----------------------------------------------- userdata.domain.name.resource
1278: # ---------------------------------------------------- Any other user namespace
1279: } elsif ($realm eq 'environment') {
1280: # ----------------------------------------------------------------- environment
1281: return $ENV{$spacequalifierrest};
1282: } elsif ($realm eq 'system') {
1283: # ----------------------------------------------------------------- system.time
1284: if ($space eq 'time') {
1285: return time;
1286: }
1287: }
1288: return '';
1289: }
1290:
1291: # ------------------------------------------------- Update symbolic store links
1292:
1293: sub symblist {
1294: my ($mapname,%newhash)=@_;
1295: $mapname=declutter($mapname);
1296: my %hash;
1297: if (($ENV{'request.course.fn'}) && (%newhash)) {
1298: if (tie(%hash,'GDBM_File',$ENV{'request.course.fn'}.'_symb.db',
1299: &GDBM_WRCREAT,0640)) {
1300: map {
1301: $hash{declutter($_)}=$mapname.'___'.$newhash{$_};
1302: } keys %newhash;
1303: if (untie(%hash)) {
1304: return 'ok';
1305: }
1306: }
1307: }
1308: return 'error';
1309: }
1310:
1311: # ------------------------------------------------------ Return symb list entry
1312:
1313: sub symbread {
1314: my $thisfn=shift;
1315: unless ($thisfn) {
1316: $thisfn=$ENV{'request.filename'};
1317: }
1318: $thisfn=declutter($thisfn);
1319: my %hash;
1320: my %bighash;
1321: my $syval='';
1322: if (($ENV{'request.course.fn'}) && ($thisfn)) {
1323: if (tie(%hash,'GDBM_File',$ENV{'request.course.fn'}.'_symb.db',
1324: &GDBM_READER,0640)) {
1325: $syval=$hash{$thisfn};
1326: untie(%hash);
1327: }
1328: # ---------------------------------------------------------- There was an entry
1329: if ($syval) {
1330: unless ($syval=~/\_\d+$/) {
1331: unless ($ENV{'form.request.prefix'}=~/\.(\d+)\_$/) {
1332: &appenv('request.ambiguous' => $thisfn);
1333: return '';
1334: }
1335: $syval.=$1;
1336: }
1337: } else {
1338: # ------------------------------------------------------- Was not in symb table
1339: if (tie(%bighash,'GDBM_File',$ENV{'request.course.fn'}.'.db',
1340: &GDBM_READER,0640)) {
1341: # ---------------------------------------------- Get ID(s) for current resource
1342: my $ids=$bighash{'ids_/res/'.$thisfn};
1343: if ($ids) {
1344: # ------------------------------------------------------------------- Has ID(s)
1345: my @possibilities=split(/\,/,$ids);
1346: if ($#possibilities==0) {
1347: # ----------------------------------------------- There is only one possibility
1348: my ($mapid,$resid)=split(/\./,$ids);
1349: $syval=declutter($bighash{'map_id_'.$mapid}).'___'.$resid;
1350: } else {
1351: # ------------------------------------------ There is more than one possibility
1352: my $realpossible=0;
1353: map {
1354: my $file=$bighash{'src_'.$_};
1355: if (&allowed('bre',$file)) {
1356: my ($mapid,$resid)=split(/\./,$_);
1357: if ($bighash{'map_type_'.$mapid} ne 'page') {
1358: $realpossible++;
1359: $syval=declutter($bighash{'map_id_'.$mapid}).
1360: '___'.$resid;
1361: }
1362: }
1363: } @possibilities;
1364: if ($realpossible!=1) { $syval=''; }
1365: }
1366: }
1367: untie(%bighash)
1368: }
1369: }
1370: if ($syval) { return $syval.'___'.$thisfn; }
1371: }
1372: &appenv('request.ambiguous' => $thisfn);
1373: return '';
1374: }
1375:
1376: # ---------------------------------------------------------- Return random seed
1377:
1378: sub numval {
1379: my $txt=shift;
1380: $txt=~tr/A-J/0-9/;
1381: $txt=~tr/a-j/0-9/;
1382: $txt=~tr/K-T/0-9/;
1383: $txt=~tr/k-t/0-9/;
1384: $txt=~tr/U-Z/0-5/;
1385: $txt=~tr/u-z/0-5/;
1386: $txt=~s/\D//g;
1387: return int($txt);
1388: }
1389:
1390: sub rndseed {
1391: my $symb;
1392: unless ($symb=&symbread()) { return time; }
1393: my $symbchck=unpack("%32C*",$symb);
1394: my $symbseed=numval($symb)%$symbchck;
1395: my $namechck=unpack("%32C*",$ENV{'user.name'});
1396: my $nameseed=numval($ENV{'user.name'})%$namechck;
1397: return int( $symbseed
1398: .$nameseed
1399: .unpack("%32C*",$ENV{'user.domain'})
1400: .unpack("%32C*",$ENV{'request.course.id'})
1401: .$namechck
1402: .$symbchck);
1403: }
1404:
1405: # ------------------------------------------------------------ Serves up a file
1406: # returns either the contents of the file or a -1
1407: sub getfile {
1408: my $file=shift;
1409: &repcopy($file);
1410: if (! -e $file ) { return -1; };
1411: my $fh=Apache::File->new($file);
1412: my $a='';
1413: while (<$fh>) { $a .=$_; }
1414: return $a
1415: }
1416:
1417: sub filelocation {
1418: my ($dir,$file) = @_;
1419: my $location;
1420: $file=~ s/^\s*(\S+)\s*$/$1/; ## strip off leading and trailing spaces
1421: if ($file=~m:^/~:) { # is a contruction space reference
1422: $location = $file;
1423: $location =~ s:/~(.*?)/(.*):/home/$1/public_html/$2:;
1424: } else {
1425: $file=~s/^$perlvar{'lonDocRoot'}//;
1426: $file=~s:^/*res::;
1427: if ( !( $file =~ m:^/:) ) {
1428: $location = $dir. '/'.$file;
1429: } else {
1430: $location = '/home/httpd/html/res'.$file;
1431: }
1432: }
1433: $location=~s://+:/:g; # remove duplicate /
1434: while ($location=~m:/\.\./:) {$location=~ s:/[^/]+/\.\./:/:g;} #remove dir/..
1435: return $location;
1436: }
1437:
1438: sub hreflocation {
1439: my ($dir,$file)=@_;
1440: unless (($_=~/^http:\/\//i) || ($_=~/^\//)) {
1441: my $finalpath=filelocation($dir,$file);
1442: $finalpath=~s/^\/home\/httpd\/html//;
1443: return $finalpath;
1444: } else {
1445: return $file;
1446: }
1447: }
1448:
1449: # ------------------------------------------------------------- Declutters URLs
1450:
1451: sub declutter {
1452: my $thisfn=shift;
1453: $thisfn=~s/^$perlvar{'lonDocRoot'}//;
1454: $thisfn=~s/^\///;
1455: $thisfn=~s/^res\///;
1456: return $thisfn;
1457: }
1458:
1459: # -------------------------------------------------------- Escape Special Chars
1460:
1461: sub escape {
1462: my $str=shift;
1463: $str =~ s/(\W)/"%".unpack('H2',$1)/eg;
1464: return $str;
1465: }
1466:
1467: # ----------------------------------------------------- Un-Escape Special Chars
1468:
1469: sub unescape {
1470: my $str=shift;
1471: $str =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
1472: return $str;
1473: }
1474:
1475: # ================================================================ Main Program
1476:
1477: sub BEGIN {
1478: if ($readit ne 'done') {
1479: # ------------------------------------------------------------ Read access.conf
1480: {
1481: my $config=Apache::File->new("/etc/httpd/conf/access.conf");
1482:
1483: while (my $configline=<$config>) {
1484: if ($configline =~ /PerlSetVar/) {
1485: my ($dummy,$varname,$varvalue)=split(/\s+/,$configline);
1486: chomp($varvalue);
1487: $perlvar{$varname}=$varvalue;
1488: }
1489: }
1490: }
1491:
1492: # ------------------------------------------------------------- Read hosts file
1493: {
1494: my $config=Apache::File->new("$perlvar{'lonTabDir'}/hosts.tab");
1495:
1496: while (my $configline=<$config>) {
1497: my ($id,$domain,$role,$name,$ip)=split(/:/,$configline);
1498: $hostname{$id}=$name;
1499: $hostdom{$id}=$domain;
1500: if ($role eq 'library') { $libserv{$id}=$name; }
1501: }
1502: }
1503:
1504: # ------------------------------------------------------ Read spare server file
1505: {
1506: my $config=Apache::File->new("$perlvar{'lonTabDir'}/spare.tab");
1507:
1508: while (my $configline=<$config>) {
1509: chomp($configline);
1510: if (($configline) && ($configline ne $perlvar{'lonHostID'})) {
1511: $spareid{$configline}=1;
1512: }
1513: }
1514: }
1515: # ------------------------------------------------------------ Read permissions
1516: {
1517: my $config=Apache::File->new("$perlvar{'lonTabDir'}/roles.tab");
1518:
1519: while (my $configline=<$config>) {
1520: chomp($configline);
1521: my ($role,$perm)=split(/ /,$configline);
1522: if ($perm ne '') { $pr{$role}=$perm; }
1523: }
1524: }
1525:
1526: # -------------------------------------------- Read plain texts for permissions
1527: {
1528: my $config=Apache::File->new("$perlvar{'lonTabDir'}/rolesplain.tab");
1529:
1530: while (my $configline=<$config>) {
1531: chomp($configline);
1532: my ($short,$plain)=split(/:/,$configline);
1533: if ($plain ne '') { $prp{$short}=$plain; }
1534: }
1535: }
1536:
1537: # ------------------------------------------------------------- Read file types
1538: {
1539: my $config=Apache::File->new("$perlvar{'lonTabDir'}/filetypes.tab");
1540:
1541: while (my $configline=<$config>) {
1542: chomp($configline);
1543: my ($ending,$emb,@descr)=split(/\s+/,$configline);
1544: if ($descr[0] ne '') {
1545: $fe{$ending}=$emb;
1546: $fd{$ending}=join(' ',@descr);
1547: }
1548: }
1549: }
1550:
1551:
1552: $readit='done';
1553: &logthis('<font color=yellow>INFO: Read configuration</font>');
1554: }
1555: }
1556: 1;
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to lonnet.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / lonnet / perl