1: # The LearningOnline Network with CAPA
2: # Construction Space Directory Lister
3: #
4: # $Id: lonpubdir.pm,v 1.59 2004/01/29 00:44:43 www Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: package Apache::lonpubdir;
31:
32: use strict;
33: use Apache::File;
34: use File::Copy;
35: use Apache::Constants qw(:common :http :methods);
36: use Apache::loncacc;
37: use Apache::loncommon();
38: use Apache::lonhtmlcommon();
39: use Apache::lonlocal;
40: use Apache::lonmsg;
41:
42: sub handler {
43:
44: my $r=shift;
45:
46: my $fn;
47:
48:
49:
50: $fn = getEffectiveUrl($r);
51:
52: # Validate access to the construction space and get username@domain.
53:
54: my $uname;
55: my $udom;
56:
57: ($uname,$udom)=
58: &Apache::loncacc::constructaccess(
59: $fn,$r->dir_config('lonDefDomain'));
60: unless (($uname) && ($udom)) {
61: $r->log_reason($uname.' at '.$udom.
62: ' trying to list directory '.$ENV{'form.filename'}.
63: ' ('.$fn.') - not authorized',
64: $r->filename);
65: return HTTP_NOT_ACCEPTABLE;
66: }
67:
68: # Remove trailing / from directory name.
69:
70: $fn=~s/\/$//;
71:
72: unless ($fn) {
73: $r->log_reason($ENV{'user.name'}.' at '.$ENV{'user.domain'}.
74: ' trying to list empty directory', $r->filename);
75: return HTTP_NOT_FOUND;
76: }
77:
78: # ----------------------------------------------------------- Start page output
79:
80: my $thisdisfn=$fn;
81: $thisdisfn=~s/^\/home\/$uname\/public_html//; # subdirectory part of
82: # construction space.
83: my $docroot=$r->dir_config('lonDocRoot'); # Apache londocument root.
84:
85: my $resdir=$docroot.'/res/'.$udom.'/'.$uname.$thisdisfn; # Resource directory
86: my $targetdir=$udom.'/'.$uname.$thisdisfn; # Publiction target directory.
87: my $linkdir='/priv/'.$uname.$thisdisfn; # Full URL name of constr space.
88:
89: my %bombs=&Apache::lonmsg::all_url_author_res_msg($uname,$udom);
90:
91: &startpage($r, $uname, $udom, $thisdisfn); # Put out the start of page.
92:
93: # Start off the directory table.
94:
95: $r->print('<table border="0" cellspacing="2" cellpadding="2">'.
96: '<tr><th> </th><th>'.&mt('Actions').'</th><th>'.&mt('Name').'</th><th>'.
97: &mt('Title').'</th>'.
98: '<th>'.&mt('Status').'</th><th>'.&mt('Last Modified').
99: '</th></tr>');
100:
101: my $filename;
102: my $dirptr=16384; # Mask indicating a directory in stat.cmode.
103:
104: opendir(DIR,$fn);
105: my @files=sort {uc($a) cmp uc($b)} (readdir(DIR));
106: foreach my $filename (@files) {
107: my ($cdev,$cino,$cmode,$cnlink,
108: $cuid,$cgid,$crdev,$csize,
109: $catime,$cmtime,$cctime,
110: $cblksize,$cblocks)=stat($fn.'/'.$filename);
111:
112: my $extension='';
113: if ($filename=~/\.(\w+)$/) { $extension=$1; }
114: if ($cmode&$dirptr) {
115: putdirectory($r, $thisdisfn, $linkdir, $filename, $cmtime,$targetdir,\%bombs);
116: } elsif (&Apache::loncommon::fileembstyle($extension) ne 'hdn') {
117: putresource($r, $uname, $filename, $thisdisfn, $resdir,
118: $targetdir, $linkdir, $cmtime,\%bombs);
119: } else {
120: # "hidden" extension and not a directory, so hide it away.
121: }
122: }
123: closedir(DIR);
124:
125: $r->print('</table></body></html>');
126: return OK;
127: }
128: #
129: # Gets the effective URL of the request and returns it:
130: # $effn = getEffectiveUrl($r);
131: # $r - The Apache Request object.
132: sub getEffectiveUrl {
133: my $r = shift;
134: my $fn;
135:
136: if ($ENV{'form.filename'}) { # If a form filename is defined.
137: $fn=$ENV{'form.filename'};
138: #
139: # Replace the ~username of the URL with /home/username/public_html
140: # so that we don't have to worry about ~ expansion internally.
141: #
142: $fn=~s/^http\:\/\/[^\/]+\///;
143: $fn=~s/^\///;
144: $fn=~s/\~(\w+)/\/home\/$1\/public_html/;
145:
146: # Remove trailing / strings (?)
147:
148: $fn=~s/\/[^\/]+$//;
149: } else {
150: # If no form is defined, use request filename.
151: $fn = $r->filename();
152: my $lonDocRoot=$r->dir_config('lonDocRoot');
153: if ( $fn =~ /$lonDocRoot/ ) {
154: #internal authentication, needs fixup.
155: $fn = $r->uri(); # non users do not get the full path request
156: # through SCRIPT_FILENAME
157: $fn=~s|^/~(\w+)|/home/$1/public_html|;
158: }
159: }
160: $fn=~s/\/+/\//g;
161: return $fn;
162: }
163: #
164: # Output the header of the page. This includes:
165: # - The HTML header
166: # - The H1/H3 stuff which includes the directory.
167: #
168: # startpage($r, $uame, $udom, $thisdisfn);
169: # $r - The apache request object.
170: # $uname - User name.
171: # $udom - Domain name the user is logged in under.
172: # $thisdisfn - Displayable version of the filename.
173:
174: sub startpage {
175: my ($r, $uname, $udom, $thisdisfn) = @_;
176:
177: &Apache::loncommon::content_type($r,'text/html');
178: $r->send_http_header;
179:
180: $r->print('<html><head><title>LON-CAPA Construction Space</title></head>');
181:
182: $r->print(&Apache::loncommon::bodytag(undef,undef,undef,1));
183: my $pubdirscript=(<<ENDPUBDIRSCRIPT);
184: <script>
185: // Store directory location for menu bar to find
186:
187: parent.lastknownpriv='/~$uname/$thisdisfn/';
188:
189: // Confirmation dialogues
190:
191: function pubdir(theform) {
192: if (confirm('Publish complete directory?')) {
193: theform.submit();
194: }
195: }
196: function pubrecdir(theform) {
197: if (confirm('Publish directory and all subdirectories?')) {
198: theform.pubrec.value='1';
199: theform.submit();
200: }
201: }
202: </script>
203: ENDPUBDIRSCRIPT
204:
205: $r->print('<h2>'.&mt('Construction Space Directory').'</h2>'.
206: '<script type="text/javascript">top.document.title = \''.
207: $thisdisfn.'/ - LON-CAPA Construction Space\';</script>'.
208: $pubdirscript.
209: '<form method="post" action="/adm/publish" target="_parent">'.
210: '<table><tr><td><input type="hidden" name="filename" value="/~'.
211: $uname.$thisdisfn.'/" />'.
212: '<input type="button" onClick="pubdir(this.form);" value="'.
213: &mt('Publish Directory').'" />'.
214: '<input type="hidden" name="pubrec" value="" />'.
215: '<input type="button" onClick="pubrecdir(this.form);" value="'.
216: &mt('Publish Directory and Sub Directories').'" /></td><td>'.
217: '<input type="button" onClick="window.location='."'/~".
218: $uname.$thisdisfn."/default.meta'".'" value="'.
219: &mt('Edit Directory Catalog Information').'" /></td></tr><tr><td><input type="checkbox" name="forcerepub" /> '.&mt('Force publication of unmodified files').'.</td><td> </td></tr></table></form>');
220:
221: if (($uname ne $ENV{'user.name'}) || ($udom ne $ENV{'user.domain'})) {
222: $r->print('<h3>'.&mt('Co-Author').': '.$uname.' at '.$udom.
223: '</h3>');
224: }
225: my $formaction='/priv/'.$uname.'/'.$thisdisfn.'/';
226: $formaction=~s/\/+/\//g;
227: $r->print('<form name="dirs" method="post" action="'.$formaction
228: .'" target="_top">'.
229: &Apache::lonhtmlcommon::crumbs($uname.'/'.$thisdisfn.'/','_top','/priv').
230: &Apache::lonhtmlcommon::select_recent('construct','recent',
231: 'this.form.action=this.form.recent.value;this.form.submit()').
232: '</form>');
233: &Apache::lonhtmlcommon::store_recent('construct',$formaction,$formaction);
234: }
235:
236: #
237: # Get the title string or "[untitled]" if the file has no title metadata:
238: # Without the latter substitution, it's impossible to examine metadata for
239: # untitled resources. Resources may be legitimately untitled, to prevent
240: # searches from locating them.
241: #
242: # $str = getTitleString($fullname);
243: # $fullname - Fully qualified filename to check.
244: #
245: sub getTitleString {
246: my $fullname = shift;
247: my $title = &Apache::lonnet::metadata($fullname, 'title');
248:
249: unless ($title) {
250: $title = "[".&mt('untitled')."]";
251: }
252: return $title;
253: }
254:
255: sub getCopyRightString {
256: my $fullname = shift;
257: return &Apache::lonnet::metadata($fullname, 'copyright');
258: }
259: #
260: # Put out a directory table row:
261: # putdirectory(r, base, here, dirname, modtime)
262: # r - Apache request object.
263: # reqfile - File in request.
264: # here - Where we are in directory tree.
265: # dirname - Name of directory special file.
266: # modtime - Encoded modification time.
267: #
268: sub putdirectory {
269: my ($r, $reqfile, $here, $dirname, $modtime, $resdir, $bombs) = @_;
270:
271: # construct the display filename: the directory name unless ..:
272:
273: my $disfilename = $dirname;
274: if ($dirname eq '..') {
275: $disfilename = '<i>'.&mt('Parent Directory').'</i>';
276: }
277: unless (( ($dirname eq '..') && ($reqfile eq '')) ||
278: ($dirname eq '.')) {
279: my $kaputt=0;
280: foreach (keys %{$bombs}) {
281: if ($_=~m:^\Q$resdir\E/\Q$disfilename\E/:) { $kaputt=1; last; }
282: }
283: %Apache::lonpublisher::metadatafields=();
284: %Apache::lonpublisher::metadatakeys=();
285: my $construct=$here;
286: $construct=~s:^/priv/(\w+)$:/home/$1/public_html:;
287: &Apache::lonpublisher::metaeval(&Apache::lonnet::getfile(
288: $construct.'/'.$dirname.'/default.meta'
289: ));
290: $r->print('<tr bgcolor="#CCCCFF">'.
291: '<td><img src="'.
292: $Apache::lonnet::perlvar{'lonIconsURL'}.'/folder_closed.gif" /></td>'.
293: '<td>'.&mt('Go to ...').'</td>'.
294: '<td><font face="arial"><a href="'.$here.'/'.$dirname.'/" target="_top">'.
295: $disfilename.'</a></font></td>'.
296: '<td colspan="2">'.($kaputt?&Apache::lonhtmlcommon::authorbombs($resdir.'/'.$disfilename.'/'):'').$Apache::lonpublisher::metadatafields{'title'}.' <i>'.
297: $Apache::lonpublisher::metadatafields{'subject'}.'</i> '.
298: $Apache::lonpublisher::metadatafields{'keywords'}.'</td>'.
299: '<td>'.&Apache::lonlocal::locallocaltime($modtime).'</td>'.
300: "</tr>\n");
301: }
302: return OK;
303: }
304: #
305: # Put a table row for a file resource.
306: #
307: sub putresource {
308: my ($r, $uname, $filename, $thisdisfn,
309: $resdir, $targetdir, $linkdir,
310: $cmtime,$bombs) = @_;
311:
312: my $status=&mt('Unpublished');
313: my $bgcolor='#FFAA99';
314: my $title=' ';
315: if (-e $resdir.'/'.$filename) {
316: my ($rdev,$rino,$rmode,$rnlink,
317: $ruid,$rgid,$rrdev,$rsize,
318: $ratime,$rmtime,$rctime,
319: $rblksize,$rblocks)=stat($resdir.'/'.$filename);
320: if ($rmtime>=$cmtime) {
321: $status=&mt('Published').'<br />'.
322: &mt(&getCopyRightString($targetdir.'/'.$filename));
323: $bgcolor='#CCFF88';
324: if (&Apache::lonnet::metadata($targetdir.'/'.$filename,'obsolete')) {
325: $status=&mt('Obsolete');
326: $bgcolor='#AAAAAA';
327: }
328: $title='<a href="/res/'.$targetdir.'/'.$filename.
329: '.meta" target=cat>'.
330: &getTitleString($targetdir.'/'.$filename).'</a>';
331: } else {
332: $status=&mt('Modified').'<br />'.
333: &mt(&getCopyRightString($targetdir.'/'.$filename));
334: $bgcolor='#FFFF77';
335: $title='<a href="/res/'.$targetdir.'/'.$filename.'.meta" target=cat>'.
336: &getTitleString($targetdir.'/'.$filename).'</a>';
337: if (&Apache::loncommon::fileembstyle(($filename=~/\.(\w+)$/)) eq 'ssi') {
338: $status.='<br /><a href="/adm/diff?filename=/~'.$uname.
339: $thisdisfn.'/'.$filename.
340: '&versiontwo=priv" target=cat>'.&mt('Diffs').'</a>';
341: }
342: }
343: $title.='<br /><a href="/~'.$uname.$thisdisfn.'/'.$filename.'.meta">'.
344: ($$bombs{$targetdir.'/'.$filename}?'<img src="/adm/lonMisc/bomb.gif" border="0" />':'Edit Metadata').'</a>';
345: $status.='<br><a href="/adm/retrieve?filename=/~'.$uname.
346: $thisdisfn.'/'.$filename.'" target=cat>'.&mt('Retrieve').'</a>';
347: }
348: my $editlink='';
349: my $editlink2='';
350: if ($filename=~/\.(xml|html|htm|xhtml|xhtm|sty)$/) {
351: $editlink=' <br />(<a href="'.$linkdir.'/'.$filename.'?forceedit=1" target="_top">'.&mt('Edit').'</a>)';
352: }
353: if ($filename=~/\.(problem|exam|quiz|assess|survey|form|library)$/) {
354: $editlink=' (<a href="'.$linkdir.'/'.$filename.'?forceedit=1" target="_top">'.&mt('EditXML').'</a>)';
355: $editlink2=' <br />(<a href="'.$linkdir.'/'.$filename.'?forceColoredit=1" target="_top">'.&mt('Edit').'</a>)';
356: }
357: if ($filename=~/\.(zip|tar|bz2|gz|tar.gz|tar.bz2|tgz)$/) {
358: $editlink=' (<a target="_parent" href="/adm/cfile?decompress=/~'.
359: $uname.$thisdisfn.'/'.$filename.'">'.&mt('Decompress').'</a>)';
360: }
361: $r->print('<tr bgcolor="'.$bgcolor.'">'.
362: '<td>'.($filename=~/[\#\~]$/?' ':
363: '<img src="'.&Apache::loncommon::icon($filename).'" /></td>').
364: '<td><a target="_parent" href="/adm/publish?filename=/~'.
365: $uname.$thisdisfn.'/'.$filename.'">'.&mt('Publish').'</a>'.
366: '</td>'.
367: '<td><font face="arial">'.
368: '<a href="'.$linkdir.'/'.$filename.'" target="_top">'.
369: $filename.'</a></font>'.$editlink2.$editlink.
370: '</td>'.
371: '<td>'.$title.'</td>'.
372: '<td>'.$status.'</td>'.
373: '<td>'.&Apache::lonlocal::locallocaltime($cmtime).'</td>'.
374: "</tr>\n");
375: return OK;
376: }
377: #
378: # Categorize files in the directory.
379: # For each file in a list of files in a file directory,
380: # the file categorized as one of:
381: # - directory
382: # - sequence
383: # - problem
384: # - Other resource.
385: #
386: # For each file the modification date is determined as well.
387: # Returned is a list of sublists:
388: # (directories, sequences, problems, other)
389: # each of the sublists contains entries of the following form (sorted by
390: # filename):
391: # (filename, typecode, lastmodtime)
392: #
393: # $list = CategorizeFiles($location, $files)
394: # $location - Directory in which the files live (relative to our
395: # execution.
396: # $files - list of files.
397: #
398: sub CategorizeFiles {
399: my $location = shift;
400: my $files = shift;
401: }
402:
403: 1;
404: __END__
405:
406: =head1 NAME
407:
408: Apache::lonpubdir - Construction space directory lister
409:
410: =head1 SYNOPSIS
411:
412: Invoked (for various locations) by /etc/httpd/conf/srm.conf:
413:
414: <LocationMatch "^/\~.*/$">
415: PerlAccessHandler Apache::loncacc
416: SetHandler perl-script
417: PerlHandler Apache::lonpubdir
418: ErrorDocument 403 /adm/login
419: ErrorDocument 404 /adm/notfound.html
420: ErrorDocument 406 /adm/unauthorized.html
421: ErrorDocument 500 /adm/errorhandler
422: </LocationMatch>
423:
424: <Location /adm/pubdir>
425: PerlAccessHandler Apache::lonacc
426: SetHandler perl-script
427: PerlHandler Apache::lonpubdir
428: ErrorDocument 403 /adm/login
429: ErrorDocument 404 /adm/notfound.html
430: ErrorDocument 406 /adm/unauthorized.html
431: ErrorDocument 500 /adm/errorhandler
432: </Location>
433:
434: =head1 INTRODUCTION
435:
436: This module publishes a directory of files.
437:
438: This is part of the LearningOnline Network with CAPA project
439: described at http://www.lon-capa.org.
440:
441: =head1 HANDLER SUBROUTINE
442:
443: This routine is called by Apache and mod_perl.
444:
445: =over 4
446:
447: =item *
448:
449: read in information
450:
451: =item *
452:
453: start page output
454:
455: =item *
456:
457: run through list of files and attempt to publish unhidden files
458:
459: =back
460:
461: =cut
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>