1: # The LearningOnline Network with CAPA
2: # Dynamic plot
3: #
4: # $Id: lonplot.pm,v 1.116 2007/02/21 20:47:49 albertel Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonplot;
30:
31: use strict;
32: use warnings FATAL=>'all';
33: no warnings 'uninitialized';
34: use Apache::File;
35: use Apache::response;
36: use Apache::lonxml;
37: use Apache::edit;
38: use Apache::lonnet;
39: use lib '/home/httpd/lib/perl/';
40: use LONCAPA;
41:
42:
43: use vars qw/$weboutputformat $versionstring/;
44:
45:
46:
47: BEGIN {
48: &Apache::lonxml::register('Apache::lonplot',('gnuplot'));
49: #
50: # Determine the version of GNUPLOT
51: $weboutputformat = 'gif';
52: $versionstring = `gnuplot --version 2>/dev/null`;
53: if ($versionstring =~ /^gnuplot 4/) {
54: $weboutputformat = 'png';
55: }
56:
57: }
58:
59:
60: ##
61: ## Description of data structures:
62: ##
63: ## %plot %key %axis
64: ## --------------------------
65: ## height title color
66: ## width box xmin
67: ## bgcolor pos xmax
68: ## fgcolor ymin
69: ## transparent ymax
70: ## grid
71: ## border
72: ## font
73: ## align
74: ##
75: ## @labels: $labels[$i] = \%label
76: ## %label: text, xpos, ypos, justify
77: ##
78: ## @curves: $curves[$i] = \%curve
79: ## %curve: name, linestyle, ( function | data )
80: ##
81: ## $curves[$i]->{'data'} = [ [x1,x2,x3,x4],
82: ## [y1,y2,y3,y4] ]
83: ##
84:
85: ###################################################################
86: ## ##
87: ## Tests used in checking the validitity of input ##
88: ## ##
89: ###################################################################
90:
91: my $max_str_len = 50; # if a label, title, xlabel, or ylabel text
92: # is longer than this, it will be truncated.
93:
94: my %linestyles =
95: (
96: lines => 2, # Maybe this will be used in the future
97: linespoints => 2, # to check on whether or not they have
98: dots => 2, # supplied enough <data></data> fields
99: points => 2, # to use the given line style. But for
100: steps => 2, # now there are more important things
101: fsteps => 2, # for me to deal with.
102: histeps => 2,
103: errorbars => 3,
104: xerrorbars => [3,4],
105: yerrorbars => [3,4],
106: xyerrorbars => [4,6],
107: boxes => 3,
108: filledcurves => 2,
109: vector => 4
110: );
111:
112: my $int_test = sub {$_[0]=~s/\s+//g;$_[0]=~/^\d+$/};
113: my $real_test =
114: sub {$_[0]=~s/\s+//g;$_[0]=~/^[+-]?\d*\.?\d*([eE][+-]\d+)?$/};
115: my $pos_real_test =
116: sub {$_[0]=~s/\s+//g;$_[0]=~/^[+]?\d*\.?\d*([eE][+-]\d+)?$/};
117: my $color_test = sub {$_[0]=~s/\s+//g;$_[0]=~/^x[\da-fA-F]{6}$/};
118: my $onoff_test = sub {$_[0]=~/^(on|off)$/};
119: my $key_pos_test = sub {$_[0]=~/^(top|bottom|right|left|outside|below| )+$/};
120: my $sml_test = sub {$_[0]=~/^(small|medium|large)$/};
121: my $linestyle_test = sub {exists($linestyles{$_[0]})};
122: my $words_test = sub {$_[0]=~s/\s+/ /g;$_[0]=~/^([\w~!\@\#\$\%^&\*\(\)-=_\+\[\]\{\}:\;\'<>,\.\/\?\\]+ ?)+$/};
123:
124: ###################################################################
125: ## ##
126: ## Attribute metadata ##
127: ## ##
128: ###################################################################
129: my @gnuplot_edit_order =
130: qw/alttag bgcolor fgcolor height width font transparent grid samples
131: border align texwidth texfont plotcolor plottype gridtype lmargin rmargin
132: tmargin bmargin major_ticscale minor_ticscale boxwidth gridlayer fillstyle
133: pattern solid/;
134:
135: my $margin_choices = ['default',0..20];
136:
137: my %gnuplot_defaults =
138: (
139: alttag => {
140: default => 'dynamically generated plot',
141: test => $words_test,
142: description => 'brief description of the plot',
143: edit_type => 'entry',
144: size => '40'
145: },
146: height => {
147: default => 300,
148: test => $int_test,
149: description => 'height of image (pixels)',
150: edit_type => 'entry',
151: size => '10'
152: },
153: width => {
154: default => 400,
155: test => $int_test,
156: description => 'width of image (pixels)',
157: edit_type => 'entry',
158: size => '10'
159: },
160: bgcolor => {
161: default => 'xffffff',
162: test => $color_test,
163: description => 'background color of image (xffffff)',
164: edit_type => 'entry',
165: size => '10'
166: },
167: fgcolor => {
168: default => 'x000000',
169: test => $color_test,
170: description => 'foreground color of image (x000000)',
171: edit_type => 'entry',
172: size => '10'
173: },
174: transparent => {
175: default => 'off',
176: test => $onoff_test,
177: description => 'Transparent image',
178: edit_type => 'onoff'
179: },
180: grid => {
181: default => 'on',
182: test => $onoff_test,
183: description => 'Display grid',
184: edit_type => 'onoff'
185: },
186: gridlayer => {
187: default => 'off',
188: test => $onoff_test,
189: description => 'Display grid front layer over filled boxes or filled curves',
190: edit_type => 'onoff'
191: },
192: box_border => {
193: default => 'noborder',
194: test => sub {$_[0]=~/^(noborder|border)$/},
195: description => 'Draw border for boxes',
196: edit_type => 'choice',
197: choices => ['border','noborder']
198: },
199: border => {
200: default => 'on',
201: test => $onoff_test,
202: description => 'Draw border around plot',
203: edit_type => 'onoff'
204: },
205: font => {
206: default => 'medium',
207: test => $sml_test,
208: description => 'Size of font to use',
209: edit_type => 'choice',
210: choices => ['small','medium','large']
211: },
212: samples => {
213: default => '100',
214: test => $int_test,
215: description => 'Number of samples for non-data plots',
216: edit_type => 'choice',
217: choices => ['100','200','500','1000','2000','5000']
218: },
219: align => {
220: default => 'middle',
221: test => sub {$_[0]=~/^(left|right|middle|center)$/},
222: description => 'alignment for image in html',
223: edit_type => 'choice',
224: choices => ['left','right','middle']
225: },
226: texwidth => {
227: default => '93',
228: test => $int_test,
229: description => 'Width of plot when printed (mm)',
230: edit_type => 'entry',
231: size => '5'
232: },
233: texfont => {
234: default => '22',
235: test => $int_test,
236: description => 'Font size to use in TeX output (pts):',
237: edit_type => 'choice',
238: choices => [qw/8 10 12 14 16 18 20 22 24 26 28 30 32 34 36/],
239: },
240: plotcolor => {
241: default => 'monochrome',
242: test => sub {$_[0]=~/^(monochrome|color|colour)$/},
243: description => 'Color setting for printing:',
244: edit_type => 'choice',
245: choices => [qw/monochrome color colour/],
246: },
247: pattern => {
248: default => '',
249: test => $int_test,
250: description => 'pattern value for boxes:',
251: edit_type => 'choice',
252: choices => [0,1,2,3,4,5,6]
253: },
254: solid => {
255: default => 0,
256: test => $real_test,
257: description => 'The density of fill style for boxes',
258: edit_type => 'entry',
259: size => '5'
260: },
261: fillstyle => {
262: default => 'empty',
263: test => sub {$_[0]=~/^(empty|solid|pattern)$/},
264: description => 'Filled style for boxes:',
265: edit_type => 'choice',
266: choices => ['empty','solid','pattern']
267: },
268: plottype => {
269: default => 'Cartesian',
270: test => sub {$_[0]=~/^(Polar|Cartesian)$/},
271: description => 'Plot type:',
272: edit_type => 'choice',
273: choices => ['Cartesian','Polar']
274: },
275: gridtype => {
276: default => 'Cartesian',
277: test => sub {$_[0]=~/^(Polar|Cartesian)$/},
278: description => 'Grid type:',
279: edit_type => 'choice',
280: choices => ['Cartesian','Polar']
281: },
282: lmargin => {
283: default => 'default',
284: test => sub {$_[0]=~/^(default|\d+)$/},
285: description => 'Left margin width (pts):',
286: edit_type => 'choice',
287: choices => $margin_choices,
288: },
289: rmargin => {
290: default => 'default',
291: test => sub {$_[0]=~/^(default|\d+)$/},
292: description => 'Right margin width (pts):',
293: edit_type => 'choice',
294: choices => $margin_choices,
295: },
296: tmargin => {
297: default => 'default',
298: test => sub {$_[0]=~/^(default|\d+)$/},
299: description => 'Top margin width (pts):',
300: edit_type => 'choice',
301: choices => $margin_choices,
302: },
303: bmargin => {
304: default => 'default',
305: test => sub {$_[0]=~/^(default|\d+)$/},
306: description => 'Bottom margin width (pts):',
307: edit_type => 'choice',
308: choices => $margin_choices,
309: },
310: boxwidth => {
311: default => '',
312: test => $real_test,
313: description => 'width of boxes default auto',
314: edit_type => 'entry',
315: size => '5'
316: },
317: major_ticscale => {
318: default => '1',
319: test => $real_test,
320: description => 'Size of major tic marks (plot coordinates)',
321: edit_type => 'entry',
322: size => '5'
323: },
324: minor_ticscale => {
325: default => '0.5',
326: test => $real_test,
327: description => 'Size of minor tic mark (plot coordinates)',
328: edit_type => 'entry',
329: size => '5'
330: },
331: );
332:
333: my %key_defaults =
334: (
335: title => {
336: default => '',
337: test => $words_test,
338: description => 'Title of key',
339: edit_type => 'entry',
340: size => '40'
341: },
342: box => {
343: default => 'off',
344: test => $onoff_test,
345: description => 'Draw a box around the key?',
346: edit_type => 'onoff'
347: },
348: pos => {
349: default => 'top right',
350: test => $key_pos_test,
351: description => 'position of the key on the plot',
352: edit_type => 'choice',
353: choices => ['top left','top right','bottom left','bottom right',
354: 'outside','below']
355: }
356: );
357:
358: my %label_defaults =
359: (
360: xpos => {
361: default => 0,
362: test => $real_test,
363: description => 'x position of label (graph coordinates)',
364: edit_type => 'entry',
365: size => '10'
366: },
367: ypos => {
368: default => 0,
369: test => $real_test,
370: description => 'y position of label (graph coordinates)',
371: edit_type => 'entry',
372: size => '10'
373: },
374: justify => {
375: default => 'left',
376: test => sub {$_[0]=~/^(left|right|center)$/},
377: description => 'justification of the label text on the plot',
378: edit_type => 'choice',
379: choices => ['left','right','center']
380: }
381: );
382:
383: my @tic_edit_order = ('location','mirror','start','increment','end',
384: 'minorfreq');
385: my %tic_defaults =
386: (
387: location => {
388: default => 'border',
389: test => sub {$_[0]=~/^(border|axis)$/},
390: description => 'Location of major tic marks',
391: edit_type => 'choice',
392: choices => ['border','axis']
393: },
394: mirror => {
395: default => 'on',
396: test => $onoff_test,
397: description => 'mirror tics on opposite axis?',
398: edit_type => 'onoff'
399: },
400: start => {
401: default => '-10.0',
402: test => $real_test,
403: description => 'Start major tics at',
404: edit_type => 'entry',
405: size => '10'
406: },
407: increment => {
408: default => '1.0',
409: test => $real_test,
410: description => 'Place a major tic every',
411: edit_type => 'entry',
412: size => '10'
413: },
414: end => {
415: default => ' 10.0',
416: test => $real_test,
417: description => 'Stop major tics at ',
418: edit_type => 'entry',
419: size => '10'
420: },
421: minorfreq => {
422: default => '0',
423: test => $int_test,
424: description => 'Number of minor tics per major tic mark',
425: edit_type => 'entry',
426: size => '10'
427: },
428: );
429:
430: my @axis_edit_order = ('color','xmin','xmax','ymin','ymax');
431: my %axis_defaults =
432: (
433: color => {
434: default => 'x000000',
435: test => $color_test,
436: description => 'color of grid lines (x000000)',
437: edit_type => 'entry',
438: size => '10'
439: },
440: xmin => {
441: default => '-10.0',
442: test => $real_test,
443: description => 'minimum x-value shown in plot',
444: edit_type => 'entry',
445: size => '10'
446: },
447: xmax => {
448: default => ' 10.0',
449: test => $real_test,
450: description => 'maximum x-value shown in plot',
451: edit_type => 'entry',
452: size => '10'
453: },
454: ymin => {
455: default => '-10.0',
456: test => $real_test,
457: description => 'minimum y-value shown in plot',
458: edit_type => 'entry',
459: size => '10'
460: },
461: ymax => {
462: default => ' 10.0',
463: test => $real_test,
464: description => 'maximum y-value shown in plot',
465: edit_type => 'entry',
466: size => '10'
467: }
468: );
469:
470: my @curve_edit_order = ('color','name','linestyle','pointtype','pointsize','limit');
471:
472: my %curve_defaults =
473: (
474: color => {
475: default => 'x000000',
476: test => $color_test,
477: description => 'color of curve (x000000)',
478: edit_type => 'entry',
479: size => '10'
480: },
481: name => {
482: default => '',
483: test => $words_test,
484: description => 'name of curve to appear in key',
485: edit_type => 'entry',
486: size => '20'
487: },
488: linestyle => {
489: default => 'lines',
490: test => $linestyle_test,
491: description => 'Line style',
492: edit_type => 'choice',
493: choices => [keys(%linestyles)]
494: },
495: # gnuplots term=gif driver does not handle linewidth :(
496: # linewidth => {
497: # default => 1,
498: # test => $int_test,
499: # description => 'Line width (may not apply to all line styles)',
500: # edit_type => 'choice',
501: # choices => [1,2,3,4,5,6,7,8,9,10]
502: # },
503: pointsize => {
504: default => 1,
505: test => $pos_real_test,
506: description => 'point size (may not apply to all line styles)',
507: edit_type => 'entry',
508: size => '5'
509: },
510: pointtype => {
511: default => 1,
512: test => $int_test,
513: description => 'point type (may not apply to all line styles)',
514: edit_type => 'choice',
515: choices => [0,1,2,3,4,5,6]
516: },
517: limit => {
518: default => 'closed',
519: test => sub {$_[0]=~/^(closed|x1|x2|y1|y2)$/},
520: description => 'point to fill -- for filledcurves',
521: edit_type => 'choice',
522: choices => ['closed','x1','x2','y1','y2']
523: },
524: );
525:
526: ###################################################################
527: ## ##
528: ## parsing and edit rendering ##
529: ## ##
530: ###################################################################
531:
532: undef %Apache::lonplot::plot;
533: my (%key,%axis,$title,$xlabel,$ylabel,@labels,@curves,%xtics,%ytics);
534:
535: sub start_gnuplot {
536: undef(%Apache::lonplot::plot); undef(%key); undef(%axis);
537: undef($title); undef($xlabel); undef($ylabel);
538: undef(@labels); undef(@curves);
539: undef(%xtics); undef(%ytics);
540: #
541: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
542: my $result='';
543: &Apache::lonxml::register('Apache::lonplot',
544: ('title','xlabel','ylabel','key','axis','label','curve',
545: 'xtics','ytics'));
546: push (@Apache::lonxml::namespace,'lonplot');
547: if ($target eq 'web' || $target eq 'tex') {
548: &get_attributes(\%Apache::lonplot::plot,\%gnuplot_defaults,$parstack,$safeeval,
549: $tagstack->[-1]);
550: } elsif ($target eq 'edit') {
551: $result .= &Apache::edit::tag_start($target,$token,'GnuPlot');
552: $result .= &edit_attributes($target,$token,\%gnuplot_defaults,
553: \@gnuplot_edit_order)
554: .&Apache::edit::end_row()
555: .&Apache::edit::start_spanning_row();
556: } elsif ($target eq 'modified') {
557: my $constructtag=&Apache::edit::get_new_args
558: ($token,$parstack,$safeeval,keys(%gnuplot_defaults));
559: if ($constructtag) {
560: $result = &Apache::edit::rebuild_tag($token);
561: }
562: }
563: return $result;
564: }
565:
566: sub end_gnuplot {
567: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
568: pop @Apache::lonxml::namespace;
569: &Apache::lonxml::deregister('Apache::lonplot',
570: ('title','xlabel','ylabel','key','axis','label','curve'));
571: my $result = '';
572: my $randnumber;
573: # need to call rand everytime start_script would evaluate, as the
574: # safe space rand number generator and the global rand generator
575: # are not separate
576: if ($target eq 'web' || $target eq 'tex' || $target eq 'grade' ||
577: $target eq 'answer') {
578: $randnumber=int(rand(1000));
579: }
580: if ($target eq 'web' || $target eq 'tex') {
581: &check_inputs(); # Make sure we have all the data we need
582: ##
583: ## Determine filename
584: my $tmpdir = '/home/httpd/perl/tmp/';
585: my $filename = $env{'user.name'}.'_'.$env{'user.domain'}.
586: '_'.time.'_'.$$.$randnumber.'_plot';
587: ## Write the plot description to the file
588: &write_gnuplot_file($tmpdir,$filename,$target);
589: $filename = &escape($filename);
590: ## return image tag for the plot
591: if ($target eq 'web') {
592: $result .= <<"ENDIMAGE";
593: <img src = "/cgi-bin/plot.$weboutputformat?file=$filename.data"
594: width = "$Apache::lonplot::plot{'width'}"
595: height = "$Apache::lonplot::plot{'height'}"
596: align = "$Apache::lonplot::plot{'align'}"
597: alt = "$Apache::lonplot::plot{'alttag'}" />
598: ENDIMAGE
599: } elsif ($target eq 'tex') {
600: &Apache::lonxml::debug(" gnuplot wid = $Apache::lonplot::plot{'width'}");
601: &Apache::lonxml::debug(" gnuplot ht = $Apache::lonplot::plot{'height'}");
602: #might be inside the safe space, register the URL for later
603: &Apache::lonxml::register_ssi("/cgi-bin/plot.gif?file=$filename.data&output=eps");
604: $result = "%DYNAMICIMAGE:$Apache::lonplot::plot{'width'}:$Apache::lonplot::plot{'height'}:$Apache::lonplot::plot{'texwidth'}\n";
605: $result .= '\graphicspath{{/home/httpd/perl/tmp/}}'."\n";
606: $result .= '\includegraphics[width='.$Apache::lonplot::plot{'texwidth'}.' mm]{'.&unescape($filename).'.eps}';
607: }
608: } elsif ($target eq 'edit') {
609: $result.=&Apache::edit::tag_end($target,$token);
610: }
611: return $result;
612: }
613:
614:
615: ##--------------------------------------------------------------- xtics
616: sub start_xtics {
617: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
618: my $result='';
619: if ($target eq 'web' || $target eq 'tex') {
620: &get_attributes(\%xtics,\%tic_defaults,$parstack,$safeeval,
621: $tagstack->[-1]);
622: } elsif ($target eq 'edit') {
623: $result .= &Apache::edit::tag_start($target,$token,'xtics');
624: $result .= &edit_attributes($target,$token,\%tic_defaults,
625: \@tic_edit_order);
626: } elsif ($target eq 'modified') {
627: my $constructtag=&Apache::edit::get_new_args
628: ($token,$parstack,$safeeval,keys(%tic_defaults));
629: if ($constructtag) {
630: $result = &Apache::edit::rebuild_tag($token);
631: }
632: }
633: return $result;
634: }
635:
636: sub end_xtics {
637: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
638: my $result = '';
639: if ($target eq 'web' || $target eq 'tex') {
640: } elsif ($target eq 'edit') {
641: $result.=&Apache::edit::tag_end($target,$token);
642: }
643: return $result;
644: }
645:
646: ##--------------------------------------------------------------- ytics
647: sub start_ytics {
648: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
649: my $result='';
650: if ($target eq 'web' || $target eq 'tex') {
651: &get_attributes(\%ytics,\%tic_defaults,$parstack,$safeeval,
652: $tagstack->[-1]);
653: } elsif ($target eq 'edit') {
654: $result .= &Apache::edit::tag_start($target,$token,'ytics');
655: $result .= &edit_attributes($target,$token,\%tic_defaults,
656: \@tic_edit_order);
657: } elsif ($target eq 'modified') {
658: my $constructtag=&Apache::edit::get_new_args
659: ($token,$parstack,$safeeval,keys(%tic_defaults));
660: if ($constructtag) {
661: $result = &Apache::edit::rebuild_tag($token);
662: }
663: }
664: return $result;
665: }
666:
667: sub end_ytics {
668: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
669: my $result = '';
670: if ($target eq 'web' || $target eq 'tex') {
671: } elsif ($target eq 'edit') {
672: $result.=&Apache::edit::tag_end($target,$token);
673: }
674: return $result;
675: }
676:
677:
678: ##----------------------------------------------------------------- key
679: sub start_key {
680: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
681: my $result='';
682: if ($target eq 'web' || $target eq 'tex') {
683: &get_attributes(\%key,\%key_defaults,$parstack,$safeeval,
684: $tagstack->[-1]);
685: } elsif ($target eq 'edit') {
686: $result .= &Apache::edit::tag_start($target,$token,'Plot Key');
687: $result .= &edit_attributes($target,$token,\%key_defaults);
688: } elsif ($target eq 'modified') {
689: my $constructtag=&Apache::edit::get_new_args
690: ($token,$parstack,$safeeval,keys(%key_defaults));
691: if ($constructtag) {
692: $result = &Apache::edit::rebuild_tag($token);
693: }
694: }
695: return $result;
696: }
697:
698: sub end_key {
699: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
700: my $result = '';
701: if ($target eq 'web' || $target eq 'tex') {
702: } elsif ($target eq 'edit') {
703: $result.=&Apache::edit::tag_end($target,$token);
704: }
705: return $result;
706: }
707:
708: ##------------------------------------------------------------------- title
709: sub start_title {
710: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
711: my $result='';
712: if ($target eq 'web' || $target eq 'tex') {
713: $title = &Apache::lonxml::get_all_text("/title",$parser,$style);
714: $title=&Apache::run::evaluate($title,$safeeval,$$parstack[-1]);
715: $title =~ s/\n/ /g;
716: if (length($title) > $max_str_len) {
717: $title = substr($title,0,$max_str_len);
718: }
719: } elsif ($target eq 'edit') {
720: $result.=&Apache::edit::tag_start($target,$token,'Plot Title');
721: my $text=&Apache::lonxml::get_all_text("/title",$parser,$style);
722: $result.=&Apache::edit::editline('',$text,'',60);
723: } elsif ($target eq 'modified') {
724: $result.=&Apache::edit::rebuild_tag($token);
725: $result.=&Apache::edit::modifiedfield("/title",$parser);
726: }
727: return $result;
728: }
729:
730: sub end_title {
731: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
732: my $result = '';
733: if ($target eq 'web' || $target eq 'tex') {
734: } elsif ($target eq 'edit') {
735: $result.=&Apache::edit::tag_end($target,$token);
736: }
737: return $result;
738: }
739: ##------------------------------------------------------------------- xlabel
740: sub start_xlabel {
741: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
742: my $result='';
743: if ($target eq 'web' || $target eq 'tex') {
744: $xlabel = &Apache::lonxml::get_all_text("/xlabel",$parser,$style);
745: $xlabel=&Apache::run::evaluate($xlabel,$safeeval,$$parstack[-1]);
746: $xlabel =~ s/\n/ /g;
747: if (length($xlabel) > $max_str_len) {
748: $xlabel = substr($xlabel,0,$max_str_len);
749: }
750: } elsif ($target eq 'edit') {
751: $result.=&Apache::edit::tag_start($target,$token,'Plot Xlabel');
752: my $text=&Apache::lonxml::get_all_text("/xlabel",$parser,$style);
753: $result.=&Apache::edit::editline('',$text,'',60);
754: } elsif ($target eq 'modified') {
755: $result.=&Apache::edit::rebuild_tag($token);
756: $result.=&Apache::edit::modifiedfield("/xlabel",$parser);
757: }
758: return $result;
759: }
760:
761: sub end_xlabel {
762: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
763: my $result = '';
764: if ($target eq 'web' || $target eq 'tex') {
765: } elsif ($target eq 'edit') {
766: $result.=&Apache::edit::tag_end($target,$token);
767: }
768: return $result;
769: }
770:
771: ##------------------------------------------------------------------- ylabel
772: sub start_ylabel {
773: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
774: my $result='';
775: if ($target eq 'web' || $target eq 'tex') {
776: $ylabel = &Apache::lonxml::get_all_text("/ylabel",$parser,$style);
777: $ylabel = &Apache::run::evaluate($ylabel,$safeeval,$$parstack[-1]);
778: $ylabel =~ s/\n/ /g;
779: if (length($ylabel) > $max_str_len) {
780: $ylabel = substr($ylabel,0,$max_str_len);
781: }
782: } elsif ($target eq 'edit') {
783: $result .= &Apache::edit::tag_start($target,$token,'Plot Ylabel');
784: my $text = &Apache::lonxml::get_all_text("/ylabel",$parser,$style);
785: $result .= &Apache::edit::editline('',$text,'',60);
786: } elsif ($target eq 'modified') {
787: $result.=&Apache::edit::rebuild_tag($token);
788: $result.=&Apache::edit::modifiedfield("/ylabel",$parser);
789: }
790: return $result;
791: }
792:
793: sub end_ylabel {
794: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
795: my $result = '';
796: if ($target eq 'web' || $target eq 'tex') {
797: } elsif ($target eq 'edit') {
798: $result.=&Apache::edit::tag_end($target,$token);
799: }
800: return $result;
801: }
802:
803: ##------------------------------------------------------------------- label
804: sub start_label {
805: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
806: my $result='';
807: if ($target eq 'web' || $target eq 'tex') {
808: my %label;
809: &get_attributes(\%label,\%label_defaults,$parstack,$safeeval,
810: $tagstack->[-1]);
811: my $text = &Apache::lonxml::get_all_text("/label",$parser,$style);
812: $text = &Apache::run::evaluate($text,$safeeval,$$parstack[-1]);
813: $text =~ s/\n/ /g;
814: $text = substr($text,0,$max_str_len) if (length($text) > $max_str_len);
815: $label{'text'} = $text;
816: push(@labels,\%label);
817: } elsif ($target eq 'edit') {
818: $result .= &Apache::edit::tag_start($target,$token,'Plot Label');
819: $result .= &edit_attributes($target,$token,\%label_defaults);
820: my $text = &Apache::lonxml::get_all_text("/label",$parser,$style);
821: $result .= &Apache::edit::end_row().
822: &Apache::edit::start_spanning_row().
823: &Apache::edit::editline('',$text,'',60);
824: } elsif ($target eq 'modified') {
825: &Apache::edit::get_new_args
826: ($token,$parstack,$safeeval,keys(%label_defaults));
827: $result.=&Apache::edit::rebuild_tag($token);
828: $result.=&Apache::edit::modifiedfield("/label",$parser);
829: }
830: return $result;
831: }
832:
833: sub end_label {
834: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
835: my $result = '';
836: if ($target eq 'web' || $target eq 'tex') {
837: } elsif ($target eq 'edit') {
838: $result.=&Apache::edit::tag_end($target,$token);
839: }
840: return $result;
841: }
842:
843: ##------------------------------------------------------------------- curve
844: sub start_curve {
845: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
846: my $result='';
847: &Apache::lonxml::register('Apache::lonplot',('function','data'));
848: push (@Apache::lonxml::namespace,'curve');
849: if ($target eq 'web' || $target eq 'tex') {
850: my %curve;
851: &get_attributes(\%curve,\%curve_defaults,$parstack,$safeeval,
852: $tagstack->[-1]);
853: push (@curves,\%curve);
854: } elsif ($target eq 'edit') {
855: $result .= &Apache::edit::tag_start($target,$token,'Curve');
856: $result .= &edit_attributes($target,$token,\%curve_defaults,
857: \@curve_edit_order)
858: .&Apache::edit::end_row()
859: .&Apache::edit::start_spanning_row();
860:
861: } elsif ($target eq 'modified') {
862: my $constructtag=&Apache::edit::get_new_args
863: ($token,$parstack,$safeeval,keys(%curve_defaults));
864: if ($constructtag) {
865: $result = &Apache::edit::rebuild_tag($token);
866: $result.= &Apache::edit::handle_insert();
867: }
868: }
869: return $result;
870: }
871:
872: sub end_curve {
873: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
874: my $result = '';
875: pop @Apache::lonxml::namespace;
876: &Apache::lonxml::deregister('Apache::lonplot',('function','data'));
877: if ($target eq 'web' || $target eq 'tex') {
878: } elsif ($target eq 'edit') {
879: $result.=&Apache::edit::tag_end($target,$token);
880: }
881: return $result;
882: }
883:
884: ##------------------------------------------------------------ curve function
885: sub start_function {
886: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
887: my $result='';
888: if ($target eq 'web' || $target eq 'tex') {
889: if (exists($curves[-1]->{'data'})) {
890: &Apache::lonxml::warning
891: ('Use of the <b>curve function</b> tag precludes use of '.
892: ' the <b>curve data</b> tag. '.
893: 'The curve data tag will be omitted in favor of the '.
894: 'curve function declaration.');
895: delete $curves[-1]->{'data'} ;
896: }
897: my $function = &Apache::lonxml::get_all_text("/function",$parser,
898: $style);
899: $function = &Apache::run::evaluate($function,$safeeval,$$parstack[-1]);
900: $curves[-1]->{'function'} = $function;
901: } elsif ($target eq 'edit') {
902: $result .= &Apache::edit::tag_start($target,$token,'Gnuplot compatible curve function');
903: my $text = &Apache::lonxml::get_all_text("/function",$parser,$style);
904: $result .= &Apache::edit::editline('',$text,'',60);
905: } elsif ($target eq 'modified') {
906: $result.=&Apache::edit::rebuild_tag($token);
907: $result.=&Apache::edit::modifiedfield("/function",$parser);
908: }
909: return $result;
910: }
911:
912: sub end_function {
913: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
914: my $result = '';
915: if ($target eq 'web' || $target eq 'tex') {
916: } elsif ($target eq 'edit') {
917: $result .= &Apache::edit::end_table();
918: }
919: return $result;
920: }
921:
922: ##------------------------------------------------------------ curve data
923: sub start_data {
924: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
925: my $result='';
926: if ($target eq 'web' || $target eq 'tex') {
927: if (exists($curves[-1]->{'function'})) {
928: &Apache::lonxml::warning
929: ('Use of the <b>curve function</b> tag precludes use of '.
930: ' the <b>curve data</b> tag. '.
931: 'The curve function tag will be omitted in favor of the '.
932: 'curve data declaration.');
933: delete($curves[-1]->{'function'});
934: }
935: my $datatext = &Apache::lonxml::get_all_text("/data",$parser,$style);
936: $datatext=&Apache::run::evaluate($datatext,$safeeval,$$parstack[-1]);
937: # Deal with cases where we're given an array...
938: if ($datatext =~ /^\@/) {
939: $datatext = &Apache::run::run('return "'.$datatext.'"',
940: $safeeval,1);
941: }
942: $datatext =~ s/\s+/ /g;
943: # Need to do some error checking on the @data array -
944: # make sure it's all numbers and make sure each array
945: # is of the same length.
946: my @data;
947: if ($datatext =~ /,/) { # comma deliminated
948: @data = split /,/,$datatext;
949: } else { # Assume it's space separated.
950: @data = split / /,$datatext;
951: }
952: for (my $i=0;$i<=$#data;$i++) {
953: # Check that it's non-empty
954: if (! defined($data[$i])) {
955: &Apache::lonxml::warning(
956: 'undefined curve data value. Replacing with '.
957: ' pi/e = 1.15572734979092');
958: $data[$i] = 1.15572734979092;
959: }
960: # Check that it's a number
961: if (! &$real_test($data[$i]) & ! &$int_test($data[$i])) {
962: &Apache::lonxml::warning(
963: 'Bad curve data value of '.$data[$i].' Replacing with '.
964: ' pi/e = 1.15572734979092');
965: $data[$i] = 1.15572734979092;
966: }
967: }
968: # complain if the number of data points is not the same as
969: # in previous sets of data.
970: if (($curves[-1]->{'data'}) && ($#data != $#{@{$curves[-1]->{'data'}->[0]}})){
971: &Apache::lonxml::warning
972: ('Number of data points is not consistent with previous '.
973: 'number of data points');
974: }
975: push @{$curves[-1]->{'data'}},\@data;
976: } elsif ($target eq 'edit') {
977: $result .= &Apache::edit::tag_start($target,$token,'Comma or space deliminated curve data');
978: my $text = &Apache::lonxml::get_all_text("/data",$parser,$style);
979: $result .= &Apache::edit::editline('',$text,'',60);
980: } elsif ($target eq 'modified') {
981: $result.=&Apache::edit::rebuild_tag($token);
982: $result.=&Apache::edit::modifiedfield("/data",$parser);
983: }
984: return $result;
985: }
986:
987: sub end_data {
988: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
989: my $result = '';
990: if ($target eq 'web' || $target eq 'tex') {
991: } elsif ($target eq 'edit') {
992: $result .= &Apache::edit::end_table();
993: }
994: return $result;
995: }
996:
997: ##------------------------------------------------------------------- axis
998: sub start_axis {
999: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
1000: my $result='';
1001: if ($target eq 'web' || $target eq 'tex') {
1002: &get_attributes(\%axis,\%axis_defaults,$parstack,$safeeval,
1003: $tagstack->[-1]);
1004: } elsif ($target eq 'edit') {
1005: $result .= &Apache::edit::tag_start($target,$token,'Plot Axes');
1006: $result .= &edit_attributes($target,$token,\%axis_defaults,
1007: \@axis_edit_order);
1008: } elsif ($target eq 'modified') {
1009: my $constructtag=&Apache::edit::get_new_args
1010: ($token,$parstack,$safeeval,keys(%axis_defaults));
1011: if ($constructtag) {
1012: $result = &Apache::edit::rebuild_tag($token);
1013: }
1014: }
1015: return $result;
1016: }
1017:
1018: sub end_axis {
1019: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
1020: my $result = '';
1021: if ($target eq 'web' || $target eq 'tex') {
1022: } elsif ($target eq 'edit') {
1023: $result.=&Apache::edit::tag_end($target,$token);
1024: } elsif ($target eq 'modified') {
1025: }
1026: return $result;
1027: }
1028:
1029: ###################################################################
1030: ## ##
1031: ## Utility Functions ##
1032: ## ##
1033: ###################################################################
1034:
1035: ##----------------------------------------------------------- set_defaults
1036: sub set_defaults {
1037: my ($var,$defaults) = @_;
1038: my $key;
1039: foreach $key (keys(%$defaults)) {
1040: $var->{$key} = $defaults->{$key}->{'default'};
1041: }
1042: }
1043:
1044: ##------------------------------------------------------------------- misc
1045: sub get_attributes{
1046: my ($values,$defaults,$parstack,$safeeval,$tag) = @_;
1047: foreach my $attr (keys(%{$defaults})) {
1048: if ($attr eq 'texwidth' || $attr eq 'texfont') {
1049: $values->{$attr} =
1050: &Apache::lonxml::get_param($attr,$parstack,$safeeval,undef,1);
1051: } else {
1052: $values->{$attr} =
1053: &Apache::lonxml::get_param($attr,$parstack,$safeeval);
1054: }
1055: if ($values->{$attr} eq '' | !defined($values->{$attr})) {
1056: $values->{$attr} = $defaults->{$attr}->{'default'};
1057: next;
1058: }
1059: my $test = $defaults->{$attr}->{'test'};
1060: if (! &$test($values->{$attr})) {
1061: &Apache::lonxml::warning
1062: ($tag.':'.$attr.': Bad value.'.'Replacing your value with : '
1063: .$defaults->{$attr}->{'default'} );
1064: $values->{$attr} = $defaults->{$attr}->{'default'};
1065: }
1066: }
1067: return ;
1068: }
1069:
1070: ##------------------------------------------------------- write_gnuplot_file
1071: sub write_gnuplot_file {
1072: my ($tmpdir,$filename,$target)= @_;
1073: my $gnuplot_input = '';
1074: my $curve;
1075: my $pt = $Apache::lonplot::plot{'texfont'};
1076: #
1077: # Check to be sure we do not have any empty curves
1078: my @curvescopy;
1079: foreach my $curve (@curves) {
1080: if (exists($curve->{'function'})) {
1081: if ($curve->{'function'} !~ /^\s*$/) {
1082: push(@curvescopy,$curve);
1083: }
1084: } elsif (exists($curve->{'data'})) {
1085: foreach my $data (@{$curve->{'data'}}) {
1086: if (scalar(@$data) > 0) {
1087: push(@curvescopy,$curve);
1088: last;
1089: }
1090: }
1091: }
1092: }
1093: @curves = @curvescopy;
1094: # Collect all the colors
1095: my @Colors;
1096: push @Colors, $Apache::lonplot::plot{'bgcolor'};
1097: push @Colors, $Apache::lonplot::plot{'fgcolor'};
1098: push @Colors, (defined($axis{'color'})?$axis{'color'}:$Apache::lonplot::plot{'fgcolor'});
1099: foreach $curve (@curves) {
1100: push @Colors, ($curve->{'color'} ne '' ?
1101: $curve->{'color'} :
1102: $Apache::lonplot::plot{'fgcolor'} );
1103: }
1104: # set term
1105: if ($target eq 'web') {
1106: $gnuplot_input .= 'set term '.$weboutputformat .' ';
1107: $gnuplot_input .= 'transparent ' if ($Apache::lonplot::plot{'transparent'} eq 'on');
1108: $gnuplot_input .= $Apache::lonplot::plot{'font'} . ' ';
1109: $gnuplot_input .= 'size '.$Apache::lonplot::plot{'width'}.','.$Apache::lonplot::plot{'height'}.' ';
1110: $gnuplot_input .= "@Colors\n";
1111: # set output
1112: $gnuplot_input .= "set output\n";
1113: } elsif ($target eq 'tex') {
1114: $gnuplot_input .= "set term postscript eps $Apache::lonplot::plot{'plotcolor'} solid \"Helvetica\" $pt \n";
1115: $gnuplot_input .= "set output \"/home/httpd/perl/tmp/".
1116: &unescape($filename).".eps\"\n";
1117: }
1118: # cartesian or polar plot?
1119: if (lc($Apache::lonplot::plot{'plottype'}) eq 'polar') {
1120: $gnuplot_input .= 'set polar'.$/;
1121: } else {
1122: # Assume Cartesian
1123: }
1124: # cartesian or polar grid?
1125: if (lc($Apache::lonplot::plot{'gridtype'}) eq 'polar') {
1126: $gnuplot_input .= 'set grid polar'.$/;
1127: } else {
1128: # Assume Cartesian
1129: }
1130: # solid or pattern for boxes?
1131: if (lc($Apache::lonplot::plot{'fillstyle'}) eq 'solid') {
1132: $gnuplot_input .= 'set style fill solid '.
1133: $Apache::lonplot::plot{'solid'}.$Apache::lonplot::plot{'box_border'}.$/;
1134: } elsif (lc($Apache::lonplot::plot{'fillstyle'}) eq 'pattern') {
1135: $gnuplot_input .= 'set style fill pattern '.$Apache::lonplot::plot{'pattern'}.$Apache::lonplot::plot{'box_border'}.$/;
1136: } elsif (lc($Apache::lonplot::plot{'fillstyle'}) eq 'empty') {
1137: }
1138: # margin
1139: if (lc($Apache::lonplot::plot{'lmargin'}) ne 'default') {
1140: $gnuplot_input .= 'set lmargin '.$Apache::lonplot::plot{'lmargin'}.$/;
1141: }
1142: if (lc($Apache::lonplot::plot{'rmargin'}) ne 'default') {
1143: $gnuplot_input .= 'set rmargin '.$Apache::lonplot::plot{'rmargin'}.$/;
1144: }
1145: if (lc($Apache::lonplot::plot{'tmargin'}) ne 'default') {
1146: $gnuplot_input .= 'set tmargin '.$Apache::lonplot::plot{'tmargin'}.$/;
1147: }
1148: if (lc($Apache::lonplot::plot{'bmargin'}) ne 'default') {
1149: $gnuplot_input .= 'set bmargin '.$Apache::lonplot::plot{'bmargin'}.$/;
1150: }
1151: # tic scales
1152: $gnuplot_input .= 'set ticscale '.
1153: $Apache::lonplot::plot{'major_ticscale'}.' '.$Apache::lonplot::plot{'minor_ticscale'}.$/;
1154: #boxwidth
1155: if (lc($Apache::lonplot::plot{'boxwidth'}) ne '') {
1156: $gnuplot_input .= 'set boxwidth '.$Apache::lonplot::plot{'boxwidth'}.$/;
1157: }
1158: # gridlayer
1159: $gnuplot_input .= 'set grid noxtics noytics front '.$/
1160: if ($Apache::lonplot::plot{'gridlayer'} eq 'on');
1161:
1162: # grid
1163: $gnuplot_input .= 'set grid'.$/ if ($Apache::lonplot::plot{'grid'} eq 'on');
1164: # border
1165: $gnuplot_input .= ($Apache::lonplot::plot{'border'} eq 'on'?
1166: 'set border'.$/ :
1167: 'set noborder'.$/ );
1168: # sampling rate for non-data curves
1169: $gnuplot_input .= "set samples $Apache::lonplot::plot{'samples'}\n";
1170: # title, xlabel, ylabel
1171: # titles
1172: if ($target eq 'tex') {
1173: $gnuplot_input .= "set title \"$title\" font \"Helvetica,".$pt."pt\"\n" if (defined($title)) ;
1174: $gnuplot_input .= "set xlabel \"$xlabel\" font \"Helvetica,".$pt."pt\" \n" if (defined($xlabel));
1175: $gnuplot_input .= "set ylabel \"$ylabel\" font \"Helvetica,".$pt."pt\"\n" if (defined($ylabel));
1176: } else {
1177: $gnuplot_input .= "set title \"$title\" \n" if (defined($title)) ;
1178: $gnuplot_input .= "set xlabel \"$xlabel\" \n" if (defined($xlabel));
1179: $gnuplot_input .= "set ylabel \"$ylabel\" \n" if (defined($ylabel));
1180: }
1181: # tics
1182: if (%xtics) {
1183: $gnuplot_input .= "set xtics $xtics{'location'} ";
1184: $gnuplot_input .= ( $xtics{'mirror'} eq 'on'?"mirror ":"nomirror ");
1185: $gnuplot_input .= "$xtics{'start'}, ";
1186: $gnuplot_input .= "$xtics{'increment'}, ";
1187: $gnuplot_input .= "$xtics{'end'}\n";
1188: if ($xtics{'minorfreq'} != 0) {
1189: $gnuplot_input .= "set mxtics ".$xtics{'minorfreq'}."\n";
1190: }
1191: }
1192: if (%ytics) {
1193: $gnuplot_input .= "set ytics $ytics{'location'} ";
1194: $gnuplot_input .= ( $ytics{'mirror'} eq 'on'?"mirror ":"nomirror ");
1195: $gnuplot_input .= "$ytics{'start'}, ";
1196: $gnuplot_input .= "$ytics{'increment'}, ";
1197: $gnuplot_input .= "$ytics{'end'}\n";
1198: if ($ytics{'minorfreq'} != 0) {
1199: $gnuplot_input .= "set mytics ".$ytics{'minorfreq'}."\n";
1200: }
1201: }
1202: # axis
1203: if (%axis) {
1204: $gnuplot_input .= "set xrange \[$axis{'xmin'}:$axis{'xmax'}\]\n";
1205: $gnuplot_input .= "set yrange \[$axis{'ymin'}:$axis{'ymax'}\]\n";
1206: }
1207: # Key
1208: if (%key) {
1209: $gnuplot_input .= 'set key '.$key{'pos'}.' ';
1210: if ($key{'title'} ne '') {
1211: $gnuplot_input .= 'title "'.$key{'title'}.'" ';
1212: }
1213: $gnuplot_input .= ($key{'box'} eq 'on' ? 'box ' : 'nobox ').$/;
1214: } else {
1215: $gnuplot_input .= 'set nokey'.$/;
1216: }
1217: # labels
1218: my $label;
1219: foreach $label (@labels) {
1220: $gnuplot_input .= 'set label "'.$label->{'text'}.'" at '.
1221: $label->{'xpos'}.','.$label->{'ypos'}.' '.$label->{'justify'};
1222: if ($target eq 'tex') {
1223: $gnuplot_input .=' font "Helvetica,'.$pt.'pt"' ;
1224: }
1225: $gnuplot_input .= $/;
1226: }
1227: if ($target eq 'tex') {
1228: $gnuplot_input .="set size 1,".$Apache::lonplot::plot{'height'}/$Apache::lonplot::plot{'width'}*1.38;
1229: $gnuplot_input .="\n";
1230: }
1231: # curves
1232: $gnuplot_input .= 'plot ';
1233: for (my $i = 0;$i<=$#curves;$i++) {
1234: $curve = $curves[$i];
1235: $gnuplot_input.= ', ' if ($i > 0);
1236: if (exists($curve->{'function'})) {
1237: $gnuplot_input.=
1238: $curve->{'function'}.' title "'.
1239: $curve->{'name'}.'" with '.
1240: $curve->{'linestyle'};
1241: $gnuplot_input.= ' linewidth 4 ' if ($target eq 'tex');
1242: if (($curve->{'linestyle'} eq 'points') ||
1243: ($curve->{'linestyle'} eq 'linespoints') ||
1244: ($curve->{'linestyle'} eq 'errorbars') ||
1245: ($curve->{'linestyle'} eq 'xerrorbars') ||
1246: ($curve->{'linestyle'} eq 'yerrorbars') ||
1247: ($curve->{'linestyle'} eq 'xyerrorbars')) {
1248: $gnuplot_input.=' pointtype '.$curve->{'pointtype'};
1249: $gnuplot_input.=' pointsize '.$curve->{'pointsize'};
1250: } elsif ($curve->{'linestyle'} eq 'filledcurves') {
1251: $gnuplot_input.= ' '.$curve->{'limit'};
1252: }
1253: } elsif (exists($curve->{'data'})) {
1254: # Store data values in $datatext
1255: my $datatext = '';
1256: # get new filename
1257: my $datafilename = "$tmpdir/$filename.data.$i";
1258: my $fh=Apache::File->new(">$datafilename");
1259: # Compile data
1260: my @Data = @{$curve->{'data'}};
1261: my @Data0 = @{$Data[0]};
1262: for (my $i =0; $i<=$#Data0; $i++) {
1263: my $dataset;
1264: foreach $dataset (@Data) {
1265: $datatext .= $dataset->[$i] . ' ';
1266: }
1267: $datatext .= $/;
1268: }
1269: # write file
1270: print $fh $datatext;
1271: close ($fh);
1272: # generate gnuplot text
1273: $gnuplot_input.= '"'.$datafilename.'" title "'.
1274: $curve->{'name'}.'" with '.
1275: $curve->{'linestyle'};
1276: $gnuplot_input.= ' linewidth 4 ' if ($target eq 'tex');
1277: if (($curve->{'linestyle'} eq 'points') ||
1278: ($curve->{'linestyle'} eq 'linespoints') ||
1279: ($curve->{'linestyle'} eq 'errorbars') ||
1280: ($curve->{'linestyle'} eq 'xerrorbars') ||
1281: ($curve->{'linestyle'} eq 'yerrorbars') ||
1282: ($curve->{'linestyle'} eq 'xyerrorbars')) {
1283: $gnuplot_input.=' pointtype '.$curve->{'pointtype'};
1284: $gnuplot_input.=' pointsize '.$curve->{'pointsize'};
1285: } elsif ($curve->{'linestyle'} eq 'filledcurves') {
1286: $gnuplot_input.= ' '.$curve->{'limit'};
1287: }
1288: }
1289: }
1290: # Write the output to a file.
1291: my $fh=Apache::File->new(">$tmpdir$filename.data");
1292: print $fh $gnuplot_input;
1293: close($fh);
1294: # That's all folks.
1295: return ;
1296: }
1297:
1298: #---------------------------------------------- check_inputs
1299: sub check_inputs {
1300: ## Note: no inputs, no outputs - this acts only on global variables.
1301: ## Make sure we have all the input we need:
1302: if (! %Apache::lonplot::plot) { &set_defaults(\%Apache::lonplot::plot,\%gnuplot_defaults); }
1303: if (! %key ) {} # No key for this plot, thats okay
1304: # if (! %axis) { &set_defaults(\%axis,\%axis_defaults); }
1305: if (! defined($title )) {} # No title for this plot, thats okay
1306: if (! defined($xlabel)) {} # No xlabel for this plot, thats okay
1307: if (! defined($ylabel)) {} # No ylabel for this plot, thats okay
1308: if ($#labels < 0) { } # No labels for this plot, thats okay
1309: if ($#curves < 0) {
1310: &Apache::lonxml::warning("No curves specified for plot!!!!");
1311: return '';
1312: }
1313: my $curve;
1314: foreach $curve (@curves) {
1315: if (!defined($curve->{'function'})&&!defined($curve->{'data'})){
1316: &Apache::lonxml::warning("One of the curves specified did not contain any curve data or curve function declarations\n");
1317: return '';
1318: }
1319: }
1320: }
1321:
1322: #------------------------------------------------ make_edit
1323: sub edit_attributes {
1324: my ($target,$token,$defaults,$keys) = @_;
1325: my ($result,@keys);
1326: if ($keys && ref($keys) eq 'ARRAY') {
1327: @keys = @$keys;
1328: } else {
1329: @keys = sort(keys(%$defaults));
1330: }
1331: foreach my $attr (@keys) {
1332: # append a ' ' to the description if it doesn't have one already.
1333: my $description = $defaults->{$attr}->{'description'};
1334: $description .= ' ' if ($description !~ / $/);
1335: if ($defaults->{$attr}->{'edit_type'} eq 'entry') {
1336: $result .= &Apache::edit::text_arg
1337: ($description,$attr,$token,
1338: $defaults->{$attr}->{'size'});
1339: } elsif ($defaults->{$attr}->{'edit_type'} eq 'choice') {
1340: $result .= &Apache::edit::select_or_text_arg
1341: ($description,$attr,$defaults->{$attr}->{'choices'},$token);
1342: } elsif ($defaults->{$attr}->{'edit_type'} eq 'onoff') {
1343: $result .= &Apache::edit::select_or_text_arg
1344: ($description,$attr,['on','off'],$token);
1345: }
1346: $result .= '<br />';
1347: }
1348: return $result;
1349: }
1350:
1351:
1352: ###################################################################
1353: ## ##
1354: ## Insertion functions for editing plots ##
1355: ## ##
1356: ###################################################################
1357:
1358: sub insert_gnuplot {
1359: my $result = '';
1360: # plot attributes
1361: $result .= "\n<gnuplot ";
1362: foreach my $attr (keys(%gnuplot_defaults)) {
1363: $result .= "\n $attr=\"$gnuplot_defaults{$attr}->{'default'}\"";
1364: }
1365: $result .= ">";
1366: # Add the components (most are commented out for simplicity)
1367: # $result .= &insert_key();
1368: # $result .= &insert_axis();
1369: # $result .= &insert_title();
1370: # $result .= &insert_xlabel();
1371: # $result .= &insert_ylabel();
1372: $result .= &insert_curve();
1373: # close up the <gnuplot>
1374: $result .= "\n</gnuplot>";
1375: return $result;
1376: }
1377:
1378: sub insert_tics {
1379: my $result;
1380: $result .= &insert_xtics() . &insert_ytics;
1381: return $result;
1382: }
1383:
1384: sub insert_xtics {
1385: my $result;
1386: $result .= "\n <xtics ";
1387: foreach my $attr (keys(%tic_defaults)) {
1388: $result .= "\n $attr=\"$tic_defaults{$attr}->{'default'}\" ";
1389: }
1390: $result .= "/>";
1391: return $result;
1392: }
1393:
1394: sub insert_ytics {
1395: my $result;
1396: $result .= "\n <ytics ";
1397: foreach my $attr (keys(%tic_defaults)) {
1398: $result .= "\n $attr=\"$tic_defaults{$attr}->{'default'}\" ";
1399: }
1400: $result .= "/>";
1401: return $result;
1402: }
1403:
1404: sub insert_key {
1405: my $result;
1406: $result .= "\n <key ";
1407: foreach my $attr (keys(%key_defaults)) {
1408: $result .= "\n $attr=\"$key_defaults{$attr}->{'default'}\"";
1409: }
1410: $result .= " />";
1411: return $result;
1412: }
1413:
1414: sub insert_axis{
1415: my $result;
1416: $result .= "\n <axis ";
1417: foreach my $attr (keys(%axis_defaults)) {
1418: $result .= "\n $attr=\"$axis_defaults{$attr}->{'default'}\"";
1419: }
1420: $result .= " />";
1421: return $result;
1422: }
1423:
1424: sub insert_title { return "\n <title></title>"; }
1425: sub insert_xlabel { return "\n <xlabel></xlabel>"; }
1426: sub insert_ylabel { return "\n <ylabel></ylabel>"; }
1427:
1428: sub insert_label {
1429: my $result;
1430: $result .= "\n <label ";
1431: foreach my $attr (keys(%label_defaults)) {
1432: $result .= "\n $attr=\"".
1433: $label_defaults{$attr}->{'default'}."\"";
1434: }
1435: $result .= "></label>";
1436: return $result;
1437: }
1438:
1439: sub insert_curve {
1440: my $result;
1441: $result .= "\n <curve ";
1442: foreach my $attr (keys(%curve_defaults)) {
1443: $result .= "\n $attr=\"".
1444: $curve_defaults{$attr}->{'default'}."\"";
1445: }
1446: $result .= " >";
1447: $result .= &insert_data().&insert_data()."\n </curve>";
1448: }
1449:
1450: sub insert_function {
1451: my $result;
1452: $result .= "\n <function></function>";
1453: return $result;
1454: }
1455:
1456: sub insert_data {
1457: my $result;
1458: $result .= "\n <data></data>";
1459: return $result;
1460: }
1461:
1462: ##----------------------------------------------------------------------
1463: 1;
1464: __END__
1465:
1466:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>