1: # The LearningOnline Network with CAPA
2: # XML Parser Module
3: #
4: # last modified 06/26/00 by Alexander Sakharuk
5: # 11/6 Gerd Kortemeyer
6: # 6/1/1 Gerd Kortemeyer
7: # 2/21,3/13 Guy
8: # 3/29,5/4 Gerd Kortemeyer
9: # 5/10 Scott Harrison
10: # 5/26 Gerd Kortemeyer
11: # 5/27 H. K. Ng
12: # 6/2,6/3,6/8,6/9 Gerd Kortemeyer
13: # 6/12,6/13 H. K. Ng
14: # 6/16 Gerd Kortemeyer
15: # 7/27 H. K. Ng
16: # 8/7,8/9 Gerd Kortemeyer
17:
18: package Apache::lonxml;
19: use vars
20: qw(@pwd @outputstack $redirection $import @extlinks $metamode $evaluate %insertlist @namespace);
21: use strict;
22: use HTML::TokeParser;
23: use HTML::TreeBuilder;
24: use Safe;
25: use Safe::Hole;
26: use Math::Cephes qw(:trigs :hypers :bessels erf erfc);
27: use Math::Random qw(:all);
28: use Opcode;
29:
30: sub register {
31: my $space;
32: my @taglist;
33: my $temptag;
34: ($space,@taglist) = @_;
35: foreach $temptag (@taglist) {
36: $Apache::lonxml::alltags{$temptag}=$space;
37: }
38: }
39:
40: use Apache::Constants qw(:common);
41: use Apache::lontexconvert;
42: use Apache::style;
43: use Apache::run;
44: use Apache::londefdef;
45: use Apache::scripttag;
46: use Apache::edit;
47: use Apache::lonnet;
48: use Apache::File;
49:
50: #================================================== Main subroutine: xmlparse
51: #debugging control, to turn on debugging modify the correct handler
52: $Apache::lonxml::debug=0;
53:
54: #path to the directory containing the file currently being processed
55: @pwd=();
56:
57: #these two are used for capturing a subset of the output for later processing,
58: #don't touch them directly use &startredirection and &endredirection
59: @outputstack = ();
60: $redirection = 0;
61:
62: #controls wheter the <import> tag actually does
63: $import = 1;
64: @extlinks=();
65:
66: # meta mode is a bit weird only some output is to be turned off
67: #<output> tag turns metamode off (defined in londefdef.pm)
68: $metamode = 0;
69:
70: # turns on and of run::evaluate actually derefencing var refs
71: $evaluate = 1;
72:
73: # data structure for eidt mode, determines what tags can go into what other tags
74: %insertlist=();
75:
76: # stores the list of active tag namespaces
77: @namespace=();
78:
79: # has the dynamic menu been updated to know about this resource
80: $Apache::lonxml::registered=0;
81:
82: sub xmlbegin {
83: my $output='';
84: if ($ENV{'browser.mathml'}) {
85: $output='<?xml version="1.0"?>'
86: .'<?xml-stylesheet type="text/css" href="/adm/MathML/mathml.css"?>'
87: .'<!DOCTYPE html SYSTEM "/adm/MathML/mathml.dtd" '
88: .'[<!ENTITY mathns "http://www.w3.org/1998/Math/MathML">]>'
89: .'<html xmlns:math="http://www.w3.org/1998/Math/MathML" '
90: .'xmlns="http://www.w3.org/TR/REC-html40">';
91: } else {
92: $output='<html>';
93: }
94: return $output;
95: }
96:
97: sub xmlend {
98: my $discussion='';
99: if ($ENV{'request.course.id'}) {
100: my $symb=&Apache::lonnet::symbread();
101: if ($symb) {
102: my %contrib=&Apache::lonnet::restore($symb,$ENV{'request.course.id'},
103: $ENV{'course.'.$ENV{'request.course.id'}.'.domain'},
104: $ENV{'course.'.$ENV{'request.course.id'}.'.num'});
105: if ($contrib{'version'}) {
106: $discussion.=
107: '<address><hr /><h2>Course Discussion of Resource</h2>';
108: my $idx;
109: for ($idx=1;$idx<=$contrib{'version'};$idx++) {
110: my $message=$contrib{$idx.':message'};
111: $message=~s/\n/\<br \/\>/g;
112: $discussion.='<p><b>'.$contrib{$idx.':sendername'}.' at '.
113: $contrib{$idx.':senderdomain'}.'</b> ('.
114: localtime($contrib{$idx.':timestamp'}).
115: '):<blockquote>'.$message.
116: '</blockquote></p>';
117: }
118: $discussion.='</address>';
119: }
120: }
121: }
122: return $discussion.'</html>';
123: }
124:
125: sub fontsettings() {
126: my $headerstring='';
127: if (($ENV{'browser.os'} eq 'mac') && (!$ENV{'browser.mathml'})) {
128: $headerstring.=
129: '<meta Content-Type="text/html; charset=x-mac-roman">';
130: }
131: return $headerstring;
132: }
133:
134: sub registerurl {
135: my $forcereg=shift;
136: if ($Apache::lonxml::registered) { return ''; }
137: $Apache::lonxml::registered=1;
138: if (($ENV{'REQUEST_URI'}!~/^\/(res\/)*adm\//) || ($forcereg)) {
139: my $hwkadd='';
140: if ($ENV{'REQUEST_URI'}=~/\.(problem|exam|quiz|assess|survey|form)$/) {
141: if (&Apache::lonnet::allowed('vgr',$ENV{'request.course.id'})) {
142: $hwkadd.=(<<ENDSUBM);
143: menu.switchbutton
144: (7,1,'subm.gif','view sub','missions',
145: 'gocmd("/adm/grades","submission")');
146: ENDSUBM
147: }
148: if (&Apache::lonnet::allowed('mgr',$ENV{'request.course.id'})) {
149: $hwkadd.=(<<ENDGRDS);
150: menu.switchbutton
151: (7,2,'pgrd.gif','problem','grades',
152: 'gocmd("/adm/grades","viewgrades")');
153: ENDGRDS
154: }
155: if (&Apache::lonnet::allowed('opa',$ENV{'request.course.id'})) {
156: $hwkadd.=(<<ENDPARM);
157: menu.switchbutton
158: (7,3,'pparm.gif','problem','parms',
159: 'gocmd("/adm/parmset","set")');
160: ENDPARM
161: }
162: }
163: return (<<ENDREGTHIS);
164:
165: <script language="JavaScript">
166: // BEGIN LON-CAPA Internal
167:
168: function LONCAPAreg() {
169: menu=window.open("","LONCAPAmenu");
170: menu.clearTimeout(menu.menucltim);
171: menu.currentURL=window.location.pathname;
172: menu.currentStale=0;
173: menu.clearbut(3,1);
174: menu.switchbutton
175: (6,3,'catalog.gif','catalog','info','catalog_info()');
176: menu.switchbutton
177: (8,1,'eval.gif','evaluate','this','gopost("/adm/evaluate",currentURL)');
178: menu.switchbutton
179: (8,2,'fdbk.gif','feedback','on this','gopost("/adm/feedback",currentURL)');
180: menu.switchbutton
181: (8,3,'prt.gif','prepare','printout','gopost("/adm/printout",currentURL)');
182: menu.switchbutton
183: (2,1,'back.gif','backward','','gopost("/adm/flip","back:"+currentURL)');
184: menu.switchbutton
185: (2,3,'forw.gif','forward','','gopost("/adm/flip","forward:"+currentURL)');
186: menu.switchbutton
187: (9,1,'sbkm.gif','set','bookmark','set_bookmark()');
188: menu.switchbutton
189: (9,2,'vbkm.gif','view','bookmark','edit_bookmarks()');
190: menu.switchbutton
191: (9,3,'anot.gif','anno-','tations','annotate()');
192: $hwkadd
193: }
194:
195: function LONCAPAstale() {
196: menu=window.open("","LONCAPAmenu");
197: menu.currentStale=1;
198: menu.switchbutton
199: (3,1,'reload.gif','return','location','go(currentURL)');
200: menu.clearbut(7,1);
201: menu.clearbut(7,2);
202: menu.clearbut(7,3);
203: menu.menucltim=menu.setTimeout(
204: 'clearbut(2,1);clearbut(2,3);clearbut(8,1);clearbut(8,2);clearbut(8,3);'+
205: 'clearbut(9,1);clearbut(9,2);clearbut(9,3);clearbut(6,3)',
206: 2000);
207:
208: }
209:
210: // END LON-CAPA Internal
211: </script>
212: ENDREGTHIS
213:
214: } else {
215: return (<<ENDDONOTREGTHIS);
216:
217: <script language="JavaScript">
218: // BEGIN LON-CAPA Internal
219:
220: function LONCAPAreg() {
221: menu=window.open("","LONCAPAmenu");
222: menu.currentStale=1;
223: menu.clearbut(2,1);
224: menu.clearbut(2,3);
225: menu.clearbut(8,1);
226: menu.clearbut(8,2);
227: menu.clearbut(8,3);
228: if (menu.currentURL) {
229: menu.switchbutton
230: (3,1,'reload.gif','return','location','go(currentURL)');
231: } else {
232: menu.clearbut(3,1);
233: }
234: }
235:
236: function LONCAPAstale() {
237: }
238:
239: // END LON-CAPA Internal
240: </script>
241: ENDDONOTREGTHIS
242:
243: }
244: }
245:
246: sub loadevents() {
247: return 'LONCAPAreg();';
248: }
249:
250: sub unloadevents() {
251: return 'LONCAPAstale();';
252: }
253:
254: sub printalltags {
255: my $temp;
256: foreach $temp (sort keys %Apache::lonxml::alltags) {
257: &Apache::lonxml::debug("$temp -- $Apache::lonxml::alltags{$temp}");
258: }
259: }
260:
261: sub xmlparse {
262: my ($target,$content_file_string,$safeinit,%style_for_target) = @_;
263:
264: &setup_globals($target);
265: #&printalltags();
266: my @pars = ();
267: my $pwd=$ENV{'request.filename'};
268: $pwd =~ s:/[^/]*$::;
269: &newparser(\@pars,\$content_file_string,$pwd);
270:
271: my $safeeval = new Safe;
272: my $safehole = new Safe::Hole;
273: &init_safespace($target,$safeeval,$safehole,$safeinit);
274: #-------------------- Redefinition of the target in the case of compound target
275:
276: ($target, my @tenta) = split('&&',$target);
277:
278: my @stack = ();
279: my @parstack = ();
280: &initdepth;
281:
282: my $finaloutput = &inner_xmlparse($target,\@stack,\@parstack,\@pars,
283: $safeeval,\%style_for_target);
284:
285: return $finaloutput;
286: }
287:
288: sub htmlclean {
289: my ($raw,$full)=@_;
290:
291: my $tree = HTML::TreeBuilder->new;
292: $tree->ignore_unknown(0);
293:
294: $tree->parse($raw);
295:
296: my $output= $tree->as_HTML(undef,' ');
297:
298: $output=~s/\<(br|hr|img)([^\>\/]*)\>/\<$1$2 \/\>/gis;
299: $output=~s/\<\/(br|hr|img)\>//gis;
300: unless ($full) {
301: $output=~s/\<[\/]*(body|head|html)\>//gis;
302: }
303:
304: $tree = $tree->delete;
305:
306: return $output;
307: }
308:
309: sub inner_xmlparse {
310: my ($target,$stack,$parstack,$pars,$safeeval,$style_for_target)=@_;
311: &Apache::lonxml::debug('Reentrant parser starting, again?');
312: my $finaloutput = '';
313: my $result;
314: my $token;
315: while ( $#$pars > -1 ) {
316: while ($token = $$pars['-1']->get_token) {
317: if (($token->[0] eq 'T') || ($token->[0] eq 'C') || ($token->[0] eq 'D') ) {
318: if ($metamode<1) {
319: $result=$token->[1];
320: }
321: } elsif ($token->[0] eq 'PI') {
322: if ($metamode<1) {
323: $result=$token->[2];
324: }
325: } elsif ($token->[0] eq 'S') {
326: # add tag to stack
327: push (@$stack,$token->[1]);
328: # add parameters list to another stack
329: push (@$parstack,&parstring($token));
330: &increasedepth($token);
331: if (exists $$style_for_target{$token->[1]}) {
332: if ($Apache::lonxml::redirection) {
333: $Apache::lonxml::outputstack['-1'] .=
334: &recurse($$style_for_target{$token->[1]},$target,$safeeval,
335: $style_for_target,@$parstack);
336: } else {
337: $finaloutput .= &recurse($$style_for_target{$token->[1]},$target,
338: $safeeval,$style_for_target,@$parstack);
339: }
340: } else {
341: $result = &callsub("start_$token->[1]", $target, $token, $stack,
342: $parstack, $pars, $safeeval, $style_for_target);
343: }
344: } elsif ($token->[0] eq 'E') {
345: #clear out any tags that didn't end
346: while ($token->[1] ne $$stack['-1'] && ($#$stack > -1)) {
347: &Apache::lonxml::warning("Unbalanced tags in resource $$stack['-1']");
348: &end_tag($stack,$parstack,$token);
349: }
350:
351: if (exists $$style_for_target{'/'."$token->[1]"}) {
352: if ($Apache::lonxml::redirection) {
353: $Apache::lonxml::outputstack['-1'] .=
354: &recurse($$style_for_target{'/'."$token->[1]"},
355: $target,$safeeval,$style_for_target,@$parstack);
356: } else {
357: $finaloutput .= &recurse($$style_for_target{'/'."$token->[1]"},
358: $target,$safeeval,$style_for_target,
359: @$parstack);
360: }
361:
362: } else {
363: $result = &callsub("end_$token->[1]", $target, $token, $stack,
364: $parstack, $pars,$safeeval, $style_for_target);
365: }
366: } else {
367: &Apache::lonxml::error("Unknown token event :$token->[0]:$token->[1]:");
368: }
369: #evaluate variable refs in result
370: if ($result ne "") {
371: if ( $#$parstack > -1 ) {
372: if ($Apache::lonxml::redirection) {
373: $Apache::lonxml::outputstack['-1'] .=
374: &Apache::run::evaluate($result,$safeeval,$$parstack['-1']);
375: } else {
376: $finaloutput .= &Apache::run::evaluate($result,$safeeval,
377: $$parstack['-1']);
378: }
379: } else {
380: $finaloutput .= &Apache::run::evaluate($result,$safeeval,'');
381: }
382: $result = '';
383: }
384: if ($token->[0] eq 'E') {
385: &end_tag($stack,$parstack,$token);
386: }
387: }
388: pop @$pars;
389: pop @Apache::lonxml::pwd;
390: }
391:
392: # if ($target eq 'meta') {
393: # $finaloutput.=&endredirection;
394: # }
395:
396: if (($ENV{'QUERY_STRING'}) && ($target eq 'web')) {
397: $finaloutput=&afterburn($finaloutput);
398: }
399: return $finaloutput;
400: }
401:
402: sub recurse {
403: my @innerstack = ();
404: my @innerparstack = ();
405: my ($newarg,$target,$safeeval,$style_for_target,@parstack) = @_;
406: my @pat = ();
407: &newparser(\@pat,\$newarg);
408: my $tokenpat;
409: my $partstring = '';
410: my $output='';
411: my $decls='';
412: while ( $#pat > -1 ) {
413: while ($tokenpat = $pat[$#pat]->get_token) {
414: if (($tokenpat->[0] eq 'T') || ($tokenpat->[0] eq 'C') || ($tokenpat->[0] eq 'D') ) {
415: if ($metamode<1) { $partstring=$tokenpat->[1]; }
416: } elsif ($tokenpat->[0] eq 'PI') {
417: if ($metamode<1) { $partstring=$tokenpat->[2]; }
418: } elsif ($tokenpat->[0] eq 'S') {
419: push (@innerstack,$tokenpat->[1]);
420: push (@innerparstack,&parstring($tokenpat));
421: &increasedepth($tokenpat);
422: $partstring = &callsub("start_$tokenpat->[1]", $target, $tokenpat,
423: \@innerstack, \@innerparstack, \@pat,
424: $safeeval, $style_for_target);
425: } elsif ($tokenpat->[0] eq 'E') {
426: #clear out any tags that didn't end
427: while ($tokenpat->[1] ne $innerstack[$#innerstack]
428: && ($#innerstack > -1)) {
429: &Apache::lonxml::warning("Unbalanced tags in resource $innerstack['-1']");
430: &end_tag(\@innerstack,\@innerparstack,$tokenpat);
431: }
432: $partstring = &callsub("end_$tokenpat->[1]", $target, $tokenpat,
433: \@innerstack, \@innerparstack, \@pat,
434: $safeeval, $style_for_target);
435: } else {
436: &Apache::lonxml::error("Unknown token event :$tokenpat->[0]:$tokenpat->[1]:");
437: }
438: #pass both the variable to the style tag, and the tag we
439: #are processing inside the <definedtag>
440: if ( $partstring ne "" ) {
441: if ( $#parstack > -1 ) {
442: if ( $#innerparstack > -1 ) {
443: $decls= $parstack[$#parstack].$innerparstack[$#innerparstack];
444: } else {
445: $decls= $parstack[$#parstack];
446: }
447: } else {
448: if ( $#innerparstack > -1 ) {
449: $decls=$innerparstack[$#innerparstack];
450: } else {
451: $decls='';
452: }
453: }
454: $output .= &Apache::run::evaluate($partstring,$safeeval,$decls);
455: $partstring = '';
456: }
457: if ($tokenpat->[0] eq 'E') { pop @innerstack;pop @innerparstack;
458: &decreasedepth($tokenpat);}
459: }
460: pop @pat;
461: pop @Apache::lonxml::pwd;
462: }
463: return $output;
464: }
465:
466: sub callsub {
467: my ($sub,$target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
468: my $currentstring='';
469: my $nodefault;
470: {
471: my $sub1;
472: no strict 'refs';
473: my $tag=$token->[1];
474: my $space=$Apache::lonxml::alltags{$tag};
475: if (!$space) {
476: $tag=~tr/A-Z/a-z/;
477: $sub=~tr/A-Z/a-z/;
478: $space=$Apache::lonxml::alltags{$tag}
479: }
480:
481: my $deleted=0;
482: $Apache::lonxml::curdepth=join('_',@Apache::lonxml::depthcounter);
483: if (($token->[0] eq 'S') && ($target eq 'modified')) {
484: $deleted=&Apache::edit::handle_delete($space,$target,$token,$tagstack,
485: $parstack,$parser,$safeeval,
486: $style);
487: }
488: if (!$deleted) {
489: if ($space) {
490: #&Apache::lonxml::debug("Calling sub $sub in $space $metamode<br />\n");
491: $sub1="$space\:\:$sub";
492: ($currentstring,$nodefault) = &$sub1($target,$token,$tagstack,
493: $parstack,$parser,$safeeval,
494: $style);
495: } else {
496: #&Apache::lonxml::debug("NOT Calling sub $sub in $space $metamode<br />\n");
497: if ($metamode <1) {
498: if (defined($token->[4]) && ($metamode < 1)) {
499: $currentstring = $token->[4];
500: } else {
501: $currentstring = $token->[2];
502: }
503: }
504: }
505: # &Apache::lonxml::debug("nodefalt:$nodefault:");
506: if ($currentstring eq '' && $nodefault eq '') {
507: if ($target eq 'edit') {
508: &Apache::lonxml::debug("doing default edit for $token->[1]");
509: if ($token->[0] eq 'S') {
510: $currentstring = &Apache::edit::tag_start($target,$token);
511: } elsif ($token->[0] eq 'E') {
512: $currentstring = &Apache::edit::tag_end($target,$token);
513: }
514: } elsif ($target eq 'modified') {
515: if ($token->[0] eq 'S') {
516: $currentstring = $token->[4];
517: $currentstring.=&Apache::edit::handle_insert();
518: } else {
519: $currentstring = $token->[2];
520: }
521: }
522: }
523: }
524: use strict 'refs';
525: }
526: return $currentstring;
527: }
528:
529: sub setup_globals {
530: my ($target)=@_;
531: $Apache::lonxml::registered = 0;
532: @Apache::lonxml::pwd=();
533: if ($target eq 'meta') {
534: $Apache::lonxml::redirection = 0;
535: $Apache::lonxml::metamode = 1;
536: $Apache::lonxml::evaluate = 1;
537: $Apache::lonxml::import = 0;
538: } elsif ($target eq 'grade') {
539: &startredirection;
540: $Apache::lonxml::metamode = 0;
541: $Apache::lonxml::evaluate = 1;
542: $Apache::lonxml::import = 1;
543: } elsif ($target eq 'modified') {
544: $Apache::lonxml::redirection = 0;
545: $Apache::lonxml::metamode = 0;
546: $Apache::lonxml::evaluate = 0;
547: $Apache::lonxml::import = 0;
548: } elsif ($target eq 'edit') {
549: $Apache::lonxml::redirection = 0;
550: $Apache::lonxml::metamode = 0;
551: $Apache::lonxml::evaluate = 0;
552: $Apache::lonxml::import = 0;
553: } else {
554: $Apache::lonxml::redirection = 0;
555: $Apache::lonxml::metamode = 0;
556: $Apache::lonxml::evaluate = 1;
557: $Apache::lonxml::import = 1;
558: }
559: }
560:
561: sub init_safespace {
562: my ($target,$safeeval,$safehole,$safeinit) = @_;
563: $safeeval->permit("entereval");
564: $safeeval->permit(":base_math");
565: $safeeval->permit("sort");
566: $safeeval->deny(":base_io");
567: $safehole->wrap(\&Apache::scripttag::xmlparse,$safeeval,'&xmlparse');
568: $safehole->wrap(\&Apache::lonnet::EXT,$safeeval,'&EXT');
569:
570: $safehole->wrap(\&Math::Cephes::asin,$safeeval,'&asin');
571: $safehole->wrap(\&Math::Cephes::acos,$safeeval,'&acos');
572: $safehole->wrap(\&Math::Cephes::atan,$safeeval,'&atan');
573: $safehole->wrap(\&Math::Cephes::sinh,$safeeval,'&sinh');
574: $safehole->wrap(\&Math::Cephes::cosh,$safeeval,'&cosh');
575: $safehole->wrap(\&Math::Cephes::tanh,$safeeval,'&tanh');
576: $safehole->wrap(\&Math::Cephes::asinh,$safeeval,'&asinh');
577: $safehole->wrap(\&Math::Cephes::acosh,$safeeval,'&acosh');
578: $safehole->wrap(\&Math::Cephes::atanh,$safeeval,'&atanh');
579: $safehole->wrap(\&Math::Cephes::erf,$safeeval,'&erf');
580: $safehole->wrap(\&Math::Cephes::erfc,$safeeval,'&erfc');
581: $safehole->wrap(\&Math::Cephes::j0,$safeeval,'&j0');
582: $safehole->wrap(\&Math::Cephes::j1,$safeeval,'&j1');
583: $safehole->wrap(\&Math::Cephes::jn,$safeeval,'&jn');
584: $safehole->wrap(\&Math::Cephes::jv,$safeeval,'&jv');
585: $safehole->wrap(\&Math::Cephes::y0,$safeeval,'&y0');
586: $safehole->wrap(\&Math::Cephes::y1,$safeeval,'&y1');
587: $safehole->wrap(\&Math::Cephes::yn,$safeeval,'&yn');
588: $safehole->wrap(\&Math::Cephes::yv,$safeeval,'&yv');
589: $safehole->wrap(\&Math::Random::random_beta,$safeeval,'&math_random_beta');
590: $safehole->wrap(\&Math::Random::random_chi_square,$safeeval,'&math_random_chi_square');
591: $safehole->wrap(\&Math::Random::random_exponential,$safeeval,'&math_random_exponential');
592: $safehole->wrap(\&Math::Random::random_f,$safeeval,'&math_random_f');
593: $safehole->wrap(\&Math::Random::random_gamma,$safeeval,'&math_random_gamma');
594: $safehole->wrap(\&Math::Random::random_multivariate_normal,$safeeval,'&math_random_multivariate_normal');
595: $safehole->wrap(\&Math::Random::random_multinomial,$safeeval,'&math_random_multinomial');
596: $safehole->wrap(\&Math::Random::random_noncentral_chi_square,$safeeval,'&math_random_noncentral_chi_square');
597: $safehole->wrap(\&Math::Random::random_noncentral_f,$safeeval,'&math_random_noncentral_f');
598: $safehole->wrap(\&Math::Random::random_normal,$safeeval,'&math_random_normal');
599: $safehole->wrap(\&Math::Random::random_permutation,$safeeval,'&math_random_permutation');
600: $safehole->wrap(\&Math::Random::random_permuted_index,$safeeval,'&math_random_permuted_index');
601: $safehole->wrap(\&Math::Random::random_uniform,$safeeval,'&math_random_uniform');
602: $safehole->wrap(\&Math::Random::random_poisson,$safeeval,'&math_random_poisson');
603: $safehole->wrap(\&Math::Random::random_uniform_integer,$safeeval,'&math_random_uniform_integer');
604: $safehole->wrap(\&Math::Random::random_negative_binomial,$safeeval,'&math_random_negative_binomial');
605: $safehole->wrap(\&Math::Random::random_binomial,$safeeval,'&math_random_binomial');
606: $safehole->wrap(\&Math::Random::random_seed_from_phrase,$safeeval,'&random_seed_from_phrase');
607: $safehole->wrap(\&Math::Random::random_set_seed_from_phrase,$safeeval,'&random_set_seed_from_phrase');
608: $safehole->wrap(\&Math::Random::random_get_seed,$safeeval,'&random_get_seed');
609: $safehole->wrap(\&Math::Random::random_set_seed,$safeeval,'&random_set_seed');
610:
611: #need to inspect this class of ops
612: # $safeeval->deny(":base_orig");
613: $safeinit .= ';$external::target="'.$target.'";';
614: $safeinit .= ';$external::randomseed='.&Apache::lonnet::rndseed().';';
615: &Apache::run::run($safeinit,$safeeval);
616: }
617:
618: sub startredirection {
619: $Apache::lonxml::redirection++;
620: push (@Apache::lonxml::outputstack, '');
621: }
622:
623: sub endredirection {
624: if (!$Apache::lonxml::redirection) {
625: &Apache::lonxml::error("Endredirection was called, before a startredirection, perhaps you have unbalanced tags. Some debuging information:".join ":",caller);
626: return '';
627: }
628: $Apache::lonxml::redirection--;
629: pop @Apache::lonxml::outputstack;
630: }
631:
632: sub end_tag {
633: my ($tagstack,$parstack,$token)=@_;
634: pop(@$tagstack);
635: pop(@$parstack);
636: &decreasedepth($token);
637: }
638:
639: sub initdepth {
640: @Apache::lonxml::depthcounter=();
641: $Apache::lonxml::depth=-1;
642: $Apache::lonxml::olddepth=-1;
643: }
644:
645: sub increasedepth {
646: my ($token) = @_;
647: $Apache::lonxml::depth++;
648: $Apache::lonxml::depthcounter[$Apache::lonxml::depth]++;
649: if ($Apache::lonxml::depthcounter[$Apache::lonxml::depth]==1) {
650: $Apache::lonxml::olddepth=$Apache::lonxml::depth;
651: }
652: my $curdepth=join('_',@Apache::lonxml::depthcounter);
653: &Apache::lonxml::debug("s $Apache::lonxml::depth : $Apache::lonxml::olddepth : $curdepth : $token->[1]\n");
654: #print "<br />s $Apache::lonxml::depth : $Apache::lonxml::olddepth : $curdepth : $token->[1]\n";
655: }
656:
657: sub decreasedepth {
658: my ($token) = @_;
659: $Apache::lonxml::depth--;
660: if ($Apache::lonxml::depth<$Apache::lonxml::olddepth-1) {
661: $#Apache::lonxml::depthcounter--;
662: $Apache::lonxml::olddepth=$Apache::lonxml::depth+1;
663: }
664: if ( $Apache::lonxml::depth < -1) {
665: &Apache::lonxml::warning("Unbalanced tags in resource");
666: $Apache::lonxml::depth='-1';
667: }
668: my $curdepth=join('_',@Apache::lonxml::depthcounter);
669: &Apache::lonxml::debug("e $Apache::lonxml::depth : $Apache::lonxml::olddepth : $token->[1] : $curdepth\n");
670: #print "<br />e $Apache::lonxml::depth : $Apache::lonxml::olddepth : $token->[1] : $curdepth\n";
671: }
672:
673: sub get_all_text {
674:
675: my($tag,$pars)= @_;
676: my $depth=0;
677: my $token;
678: my $result='';
679: if ( $tag =~ m:^/: ) {
680: my $tag=substr($tag,1);
681: # &Apache::lonxml::debug("have:$tag:");
682: while (($depth >=0) && ($token = $pars->get_token)) {
683: # &Apache::lonxml::debug("e token:$token->[0]:$depth:$token->[1]");
684: if (($token->[0] eq 'T')||($token->[0] eq 'C')||($token->[0] eq 'D')) {
685: $result.=$token->[1];
686: } elsif ($token->[0] eq 'PI') {
687: $result.=$token->[2];
688: } elsif ($token->[0] eq 'S') {
689: if ($token->[1] eq $tag) { $depth++; }
690: $result.=$token->[4];
691: } elsif ($token->[0] eq 'E') {
692: if ( $token->[1] eq $tag) { $depth--; }
693: #skip sending back the last end tag
694: if ($depth > -1) { $result.=$token->[2]; } else {
695: $pars->unget_token($token);
696: }
697: }
698: }
699: } else {
700: while ($token = $pars->get_token) {
701: # &Apache::lonxml::debug("s token:$token->[0]:$depth:$token->[1]");
702: if (($token->[0] eq 'T')||($token->[0] eq 'C')||($token->[0] eq 'D')) {
703: $result.=$token->[1];
704: } elsif ($token->[0] eq 'PI') {
705: $result.=$token->[2];
706: } elsif ($token->[0] eq 'S') {
707: if ( $token->[1] eq $tag) {
708: $pars->unget_token($token); last;
709: } else {
710: $result.=$token->[4];
711: }
712: } elsif ($token->[0] eq 'E') {
713: $result.=$token->[2];
714: }
715: }
716: }
717: # &Apache::lonxml::debug("Exit:$result:");
718: return $result
719: }
720:
721: sub newparser {
722: my ($parser,$contentref,$dir) = @_;
723: push (@$parser,HTML::TokeParser->new($contentref));
724: $$parser['-1']->xml_mode('1');
725: if ( $dir eq '' ) {
726: push (@Apache::lonxml::pwd, $Apache::lonxml::pwd[$#Apache::lonxml::pwd]);
727: } else {
728: push (@Apache::lonxml::pwd, $dir);
729: }
730: # &Apache::lonxml::debug("pwd:$#Apache::lonxml::pwd");
731: # &Apache::lonxml::debug("pwd:$Apache::lonxml::pwd[$#Apache::lonxml::pwd]");
732: }
733:
734: sub parstring {
735: my ($token) = @_;
736: my $temp='';
737: map {
738: unless ($_=~/\W/) {
739: my $val=$token->[2]->{$_};
740: $val =~ s/([\%\@\\])/\\$1/g;
741: #if ($val =~ m/^[\%\@]/) { $val="\\".$val; }
742: $temp .= "my \$$_=\"$val\";"
743: }
744: } @{$token->[3]};
745: return $temp;
746: }
747:
748: sub writeallows {
749: my $thisurl='/res/'.&Apache::lonnet::declutter(shift);
750: my $thisdir=$thisurl;
751: $thisdir=~s/\/[^\/]+$//;
752: my %httpref=();
753: map {
754: $httpref{'httpref.'.
755: &Apache::lonnet::hreflocation($thisdir,$_)}=$thisurl; } @extlinks;
756: &Apache::lonnet::appenv(%httpref);
757: }
758:
759: #
760: # Afterburner handles anchors, highlights and links
761: #
762: sub afterburn {
763: my $result=shift;
764: map {
765: my ($name, $value) = split(/=/,$_);
766: $value =~ tr/+/ /;
767: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
768: if (($name eq 'highlight')||($name eq 'anchor')||($name eq 'link')) {
769: unless ($ENV{'form.'.$name}) {
770: $ENV{'form.'.$name}=$value;
771: }
772: }
773: } (split(/&/,$ENV{'QUERY_STRING'}));
774: if ($ENV{'form.highlight'}) {
775: map {
776: my $anchorname=$_;
777: my $matchthis=$anchorname;
778: $matchthis=~s/\_+/\\s\+/g;
779: $result=~s/($matchthis)/\<font color=\"red\"\>$1\<\/font\>/gs;
780: } split(/\,/,$ENV{'form.highlight'});
781: }
782: if ($ENV{'form.link'}) {
783: map {
784: my ($anchorname,$linkurl)=split(/\>/,$_);
785: my $matchthis=$anchorname;
786: $matchthis=~s/\_+/\\s\+/g;
787: $result=~s/($matchthis)/\<a href=\"$linkurl\"\>$1\<\/a\>/gs;
788: } split(/\,/,$ENV{'form.link'});
789: }
790: if ($ENV{'form.anchor'}) {
791: my $anchorname=$ENV{'form.anchor'};
792: my $matchthis=$anchorname;
793: $matchthis=~s/\_+/\\s\+/g;
794: $result=~s/($matchthis)/\<a name=\"$anchorname\"\>$1\<\/a\>/s;
795: $result.=(<<"ENDSCRIPT");
796: <script>
797: document.location.hash='$anchorname';
798: </script>
799: ENDSCRIPT
800: }
801: return $result;
802: }
803:
804: sub storefile {
805: my ($file,$contents)=@_;
806: if (my $fh=Apache::File->new('>'.$file)) {
807: print $fh $contents;
808: $fh->close();
809: }
810: }
811:
812: sub inserteditinfo {
813: my ($result,$filecontents)=@_;
814: unless ($filecontents) {
815: $filecontents=(<<SIMPLECONTENT);
816: <html>
817: <head>
818: <title>
819: Title of Document Goes Here
820: </title>
821: </head>
822: <body bgcolor="#FFFFFF">
823:
824: Body of Document Goes Here
825:
826: </body>
827: </html>
828: SIMPLECONTENT
829: }
830: my $editheader='<a href="#editsection">Edit below</a><hr />';
831: my $editfooter=(<<ENDFOOTER);
832: <hr />
833: <a name="editsection" />
834: <form method="post">
835: <textarea cols="80" rows="40" name="filecont">$filecontents</textarea>
836: <br />
837: <input type="submit" name="attemptclean"
838: value="Save and then attempt to clean HTML" />
839: <input type="submit" name="savethisfile" value="Save this" />
840: </form>
841: ENDFOOTER
842: $result=~s/(\<body[^\>]*\>)/$1$editheader/is;
843: $result=~s/(\<\/body\>)/$editfooter/is;
844: return $result;
845: }
846:
847: sub handler {
848: my $request=shift;
849:
850: my $target='web';
851:
852: $Apache::lonxml::debug=0;
853:
854: if ($ENV{'browser.mathml'}) {
855: $request->content_type('text/xml');
856: } else {
857: $request->content_type('text/html');
858: }
859:
860: $request->send_http_header;
861:
862: return OK if $request->header_only;
863:
864:
865: my $file=&Apache::lonnet::filelocation("",$request->uri);
866: #
867: # Edit action? Save file.
868: #
869: unless ($ENV{'request.state'} eq 'published') {
870: if (($ENV{'form.savethisfile'}) || ($ENV{'form.attemptclean'})) {
871: &storefile($file,$ENV{'form.filecont'});
872: }
873: }
874: my %mystyle;
875: my $result = '';
876: my $filecontents=&Apache::lonnet::getfile($file);
877: if ($filecontents == -1) {
878: $result=(<<ENDNOTFOUND);
879: <html>
880: <head>
881: <title>File not found</title>
882: </head>
883: <body bgcolor="#FFFFFF">
884: <b>File not found: $file</b>
885: </body>
886: </html>
887: ENDNOTFOUND
888: $filecontents='';
889: } else {
890: unless ($ENV{'request.state'} eq 'published') {
891: if ($ENV{'form.attemptclean'}) {
892: $filecontents=&htmlclean($filecontents,1);
893: }
894: }
895: $result = &Apache::lonxml::xmlparse($target,$filecontents,'',%mystyle);
896: }
897:
898: #
899: # Edit action? Insert editing commands
900: #
901: unless ($ENV{'request.state'} eq 'published') {
902: $result=&inserteditinfo($result,$filecontents);
903: }
904:
905: $request->print($result);
906:
907: writeallows($request->uri);
908: return OK;
909: }
910:
911: sub debug {
912: if ($Apache::lonxml::debug eq 1) {
913: print("DEBUG:".$_[0]."<br />\n");
914: }
915: }
916:
917: sub error {
918: if (($Apache::lonxml::debug eq 1) || ($ENV{'request.state'} eq 'construct') ) {
919: print "<b>ERROR:</b>".$_[0]."<br />\n";
920: } else {
921: print "<b>An Error occured while processing this resource. The instructor has been notified.</b> <br />";
922: #notify author
923: &Apache::lonmsg::author_res_msg($ENV{'request.filename'},$_[0]);
924: #notify course
925: if ( $ENV{'request.course.id'} ) {
926: my $users=$ENV{'course.'.$ENV{'request.course.id'}.'.comment.email'};
927: foreach my $user (split /\,/, $users) {
928: ($user,my $domain) = split /:/, $user;
929: &Apache::lonmsg::user_normal_msg($user,$domain,"Error in $ENV{'request.filename'}",$_[0]);
930: }
931: }
932:
933: #FIXME probably shouldn't have me get everything forever.
934: &Apache::lonmsg::user_normal_msg('albertel','msu',"Error in $ENV{'request.filename'}",$_[0]);
935: #&Apache::lonmsg::user_normal_msg('albertel','103',"Error in $ENV{'request.filename'}",$_[0]);
936: }
937: }
938:
939: sub warning {
940: if ($ENV{'request.state'} eq 'construct') {
941: print "<b>W</b>ARNING<b>:</b>".$_[0]."<br />\n";
942: }
943: }
944:
945: sub get_param {
946: my ($param,$parstack,$safeeval,$context) = @_;
947: if ( ! $context ) { $context = -1; }
948: my $args ='';
949: if ( $#$parstack > (-2-$context) ) { $args=$$parstack[$context]; }
950: return &Apache::run::run("{$args;".'return $'.$param.'}',$safeeval); #'
951: }
952:
953: sub register_insert {
954: my @data = split /\n/, &Apache::lonnet::getfile('/home/httpd/lonTabs/insertlist.tab');
955: my $i;
956: my $tagnum=0;
957: my @order;
958: for ($i=0;$i < $#data; $i++) {
959: my $line = $data[$i];
960: if ( $line =~ /^\#/ || $line =~ /^\s*\n/) { next; }
961: if ( $line =~ /TABLE/ ) { last; }
962: my ($tag,$descrip,$color,$function,$show) = split(/,/, $line);
963: $insertlist{"$tagnum.tag"} = $tag;
964: $insertlist{"$tagnum.description"} = $descrip;
965: $insertlist{"$tagnum.color"} = $color;
966: $insertlist{"$tagnum.function"} = $function;
967: $insertlist{"$tagnum.show"}= $show;
968: $insertlist{"$tag.num"}=$tagnum;
969: $tagnum++;
970: }
971: $i++; #skipping TABLE line
972: $tagnum = 0;
973: for (;$i < $#data;$i++) {
974: my $line = $data[$i];
975: my ($mnemonic,@which) = split(/ +/,$line);
976: my $tag = $insertlist{"$tagnum.tag"};
977: for (my $j=0;$j <$#which;$j++) {
978: if ( $which[$j] eq 'Y' ) {
979: if ($insertlist{"$j.show"} ne 'no') {
980: push(@{ $insertlist{"$tag.which"} },$j);
981: }
982: }
983: }
984: $tagnum++;
985: }
986: }
987:
988: sub description {
989: my ($token)=@_;
990: return $insertlist{$insertlist{"$token->[1].num"}.'.description'};
991: }
992: 1;
993: __END__
994:
995:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>