[BACK]Return to lonxml.pm CVS log [TXT] [DIR] Up to [LON-CAPA] / loncom / xml
File:  [LON-CAPA] / loncom / xml / lonxml.pm
Revision 1.80: download - view: text, annotated - select for diffs
Mon May 28 18:27:46 2001 UTC (23 years, 5 months ago) by harris41
Branches: MAIN
CVS tags: HEAD
add Math::Trig
add Math::Cephes qw(j0 j1 jn jv y0 y1 yn yv)

# The LearningOnline Network with CAPA
# XML Parser Module 
#
# last modified 06/26/00 by Alexander Sakharuk
# 11/6 Gerd Kortemeyer
# 6/1/1 Gerd Kortemeyer
# 2/21,3/13 Guy
# 3/29,5/4 Gerd Kortemeyer
# 5/10 Scott Harrison
# 5/26 Gerd Kortemeyer
# 5/27 H. K. Ng

package Apache::lonxml; 
use vars 
qw(@pwd @outputstack $redirection $import @extlinks $metamode $evaluate %insertlist @namespace);
use strict;
use HTML::TokeParser;
use Safe;
use Safe::Hole;
use Math::Trig;
use Math::Cephes qw(j0 j1 jn jv y0 y1 yn yv);
use Opcode;

sub register {
  my $space;
  my @taglist;
  my $temptag;
  ($space,@taglist) = @_;
  foreach $temptag (@taglist) {
    $Apache::lonxml::alltags{$temptag}=$space;
  }
}

use Apache::Constants qw(:common);
use Apache::lontexconvert;
use Apache::style;
use Apache::run;
use Apache::londefdef;
use Apache::scripttag;
use Apache::edit;
use Apache::lonnet;
use Apache::File;

#==================================================   Main subroutine: xmlparse  
#debugging control, to turn on debugging modify the correct handler
$Apache::lonxml::debug=0;

#path to the directory containing the file currently being processed
@pwd=();

#these two are used for capturing a subset of the output for later processing,
#don't touch them directly use &startredirection and &endredirection
@outputstack = ();
$redirection = 0;

#controls wheter the <import> tag actually does
$import = 1;
@extlinks=();

# meta mode is a bit weird only some output is to be turned off
#<output> tag turns metamode off (defined in londefdef.pm)
$metamode = 0;

# turns on and of run::evaluate actually derefencing var refs
$evaluate = 1;

# data structure for eidt mode, determines what tags can go into what other tags
%insertlist=();

#stores the list of active tag namespaces
@namespace=();

sub xmlbegin {
  my $output='';
  if ($ENV{'browser.mathml'}) {
      $output='<?xml version="1.0"?>'
            .'<?xml-stylesheet type="text/css" href="/adm/MathML/mathml.css"?>'
            .'<!DOCTYPE html SYSTEM "/adm/MathML/mathml.dtd" '
            .'[<!ENTITY mathns "http://www.w3.org/1998/Math/MathML">]>'
            .'<html xmlns:math="http://www.w3.org/1998/Math/MathML" ' 
		.'xmlns="http://www.w3.org/TR/REC-html40">';
  } else {
      $output='<html>';
  }
  return $output;
}

sub xmlend {
    return '</html>';
}

sub fontsettings() {
    my $headerstring='';
    if (($ENV{'browser.os'} eq 'mac') && (!$ENV{'browser.mathml'})) { 
         $headerstring.=
             '<meta Content-Type="text/html; charset=x-mac-roman">';
    }
    return $headerstring;
}

sub registerurl {
  return (<<ENDSCRIPT);
<script language="JavaScript">
// BEGIN LON-CAPA Internal
    function LONCAPAreg() {
       if (window.location.pathname!="/res/adm/pages/menu.html") {
	  menu=window.open("","LONCAPAmenu");
	  menu.currentURL=window.location.pathname;
          menu.currentStale=0;
       }
    }
  
    function LONCAPAstale() {
       if (window.location.pathname!="/res/adm/pages/menu.html") {
	  menu=window.open("","LONCAPAmenu");
          menu.currentStale=1;
       }
    }
// END LON-CAPA Internal
</script>
ENDSCRIPT
}

sub loadevents() {
    return 'LONCAPAreg();';
}

sub unloadevents() {
    return 'LONCAPAstale();';
}

sub printalltags {
  my $temp;
  foreach $temp (sort keys %Apache::lonxml::alltags) {
    &Apache::lonxml::debug("$temp -- $Apache::lonxml::alltags{$temp}");
  }
}

sub xmlparse {

 my ($target,$content_file_string,$safeinit,%style_for_target) = @_;
 if ($target eq 'meta') {
   $Apache::lonxml::redirection = 0;
   $Apache::lonxml::metamode = 1;
   $Apache::lonxml::evaluate = 1;
   $Apache::lonxml::import = 0;
 } elsif ($target eq 'grade') {
   &startredirection;
   $Apache::lonxml::metamode = 0;
   $Apache::lonxml::evaluate = 1;
   $Apache::lonxml::import = 1;
 } elsif ($target eq 'modified') {
   $Apache::lonxml::redirection = 0;
   $Apache::lonxml::metamode = 0;
   $Apache::lonxml::evaluate = 0;
   $Apache::lonxml::import = 0;
 } else {
   $Apache::lonxml::redirection = 0;
   $Apache::lonxml::metamode = 0;
   $Apache::lonxml::evaluate = 1;
   $Apache::lonxml::import = 1;
 }
 #&printalltags();
 my @pars = ();
 @Apache::lonxml::pwd=();
 my $pwd=$ENV{'request.filename'};
 $pwd =~ s:/[^/]*$::;
 &newparser(\@pars,\$content_file_string,$pwd);
 my $currentstring = '';
 my $finaloutput = ''; 
 my $newarg = '';
 my $result;

 my $safeeval = new Safe;
 my $safehole = new Safe::Hole;
 $safeeval->permit("entereval");
 $safeeval->permit(":base_math");
 $safeeval->permit("sort");
 $safeeval->deny(":base_io");
# $safe->share_from('Math::Trig',['acsc','asin','acos','atan']);
 $safehole->wrap(\&Apache::lonnet::EXT,$safeeval,'&EXT');
 $safehole->wrap(\&Math::Trig::acsc,$safeeval,'&acsc');
 $safehole->wrap(\&Math::Trig::acosec,$safeeval,'&acosec');
 $safehole->wrap(\&Math::Trig::asec,$safeeval,'&asec');
 $safehole->wrap(\&Math::Trig::acot,$safeeval,'&acot');
 $safehole->wrap(\&Math::Trig::acotan,$safeeval,'&acotan');
 $safehole->wrap(\&Math::Trig::acsch,$safeeval,'&acsch');
 $safehole->wrap(\&Math::Trig::acosech,$safeeval,'&acosech');
 $safehole->wrap(\&Math::Trig::asech,$safeeval,'&asech');
 $safehole->wrap(\&Math::Trig::acoth,$safeeval,'&acoth');
 $safehole->wrap(\&Math::Trig::acotanh,$safeeval,'&acotanh');
 $safehole->wrap(\&Math::Trig::asin,$safeeval,'&asin');
 $safehole->wrap(\&Math::Trig::acos,$safeeval,'&acos');
 $safehole->wrap(\&Math::Trig::atan,$safeeval,'&atan');
 $safehole->wrap(\&Math::Trig::asinh,$safeeval,'&asinh');
 $safehole->wrap(\&Math::Trig::acosh,$safeeval,'&acosh');
 $safehole->wrap(\&Math::Trig::atanh,$safeeval,'&atanh');
 $safehole->wrap(\&Math::Trig::atan2,$safeeval,'&atan2');
 $safehole->wrap(\&Math::Trig::csc,$safeeval,'&csc');
 $safehole->wrap(\&Math::Trig::cosec,$safeeval,'&cosec');
 $safehole->wrap(\&Math::Trig::sec,$safeeval,'&sec');
 $safehole->wrap(\&Math::Trig::cot,$safeeval,'&cot');
 $safehole->wrap(\&Math::Trig::cotan,$safeeval,'&cotan');
 $safehole->wrap(\&Math::Trig::csch,$safeeval,'&csch');
 $safehole->wrap(\&Math::Trig::cosech,$safeeval,'&cosech');
 $safehole->wrap(\&Math::Trig::sech,$safeeval,'&sech');
 $safehole->wrap(\&Math::Trig::coth,$safeeval,'&coth');
 $safehole->wrap(\&Math::Trig::cotanh,$safeeval,'&cptanh');
 $safehole->wrap(\&Math::Trig::deg2rad,$safeeval,'&deg2rad');
 $safehole->wrap(\&Math::Trig::deg2grad,$safeeval,'&deg2grad');
 $safehole->wrap(\&Math::Trig::grad2deg,$safeeval,'&grad2deg');
 $safehole->wrap(\&Math::Trig::grad2rad,$safeeval,'&grad2rad');
 $safehole->wrap(\&Math::Trig::rad2deg,$safeeval,'&rad2deg');
 $safehole->wrap(\&Math::Trig::rad2grad,$safeeval,'&rad2grad');
 $safehole->wrap(\&Math::Trig::pi,$safeeval,'&pi');
 $safehole->wrap(\&Math::Cephes::erf,$safeeval,'&erf');
 $safehole->wrap(\&Math::Cephes::erfc,$safeeval,'&erfc');
 $safehole->wrap(\&Math::Cephes::j0,$safeeval,'&j0');
 $safehole->wrap(\&Math::Cephes::j1,$safeeval,'&j1');
 $safehole->wrap(\&Math::Cephes::jn,$safeeval,'&jn');
 $safehole->wrap(\&Math::Cephes::jv,$safeeval,'&jv');
 $safehole->wrap(\&Math::Cephes::y0,$safeeval,'&y0');
 $safehole->wrap(\&Math::Cephes::y1,$safeeval,'&y1');
 $safehole->wrap(\&Math::Cephes::yn,$safeeval,'&yn');
 $safehole->wrap(\&Math::Cephes::yv,$safeeval,'&yv');

#need to inspect this class of ops
# $safeeval->deny(":base_orig");
 $safeinit .= ';$external::target='.$target.';';
 $safeinit .= ';$external::randomseed='.&Apache::lonnet::rndseed().';';
 &Apache::run::run($safeinit,$safeeval);
#-------------------- Redefinition of the target in the case of compound target

 ($target, my @tenta) = split('&&',$target);

 my @stack = (); 
 my @parstack = ();
 &initdepth;
 my $token;
 while ( $#pars > -1 ) {
   while ($token = $pars[$#pars]->get_token) {
     if (($token->[0] eq 'T') || ($token->[0] eq 'C') || ($token->[0] eq 'D') ) {
       if ($metamode<1) { $result=$token->[1]; }
     } elsif ($token->[0] eq 'PI') {
       if ($metamode<1) { $result=$token->[2]; }
     } elsif ($token->[0] eq 'S') {
       # add tag to stack 	    
       push (@stack,$token->[1]);
       # add parameters list to another stack
       push (@parstack,&parstring($token));
       &increasedepth($token);       
       if (exists $style_for_target{$token->[1]}) {
	 if ($Apache::lonxml::redirection) {
	   $Apache::lonxml::outputstack['-1'] .=  
	     &recurse($style_for_target{$token->[1]},$target,$safeeval,
		      \%style_for_target,@parstack);
	 } else {
	   $finaloutput .= &recurse($style_for_target{$token->[1]},$target,
				    $safeeval,\%style_for_target,@parstack);
	 }
       } else {
	 $result = &callsub("start_$token->[1]", $target, $token,\@parstack,
			    \@pars, $safeeval, \%style_for_target);
       }              
     } elsif ($token->[0] eq 'E')  {
       #clear out any tags that didn't end
       while ($token->[1] ne $stack[$#stack] && ($#stack > -1)) {
	 &Apache::lonxml::warning("Unbalanced tags in resource $stack['-1']");
	 pop @stack;pop @parstack;&decreasedepth($token);
       }
       
       if (exists $style_for_target{'/'."$token->[1]"}) {
	 if ($Apache::lonxml::redirection) {
	   $Apache::lonxml::outputstack['-1'] .=  
	     &recurse($style_for_target{'/'."$token->[1]"},
		      $target,$safeeval,\%style_for_target,@parstack);
	 } else {
	   $finaloutput .= &recurse($style_for_target{'/'."$token->[1]"},
				    $target,$safeeval,\%style_for_target,
				    @parstack);
	 }

       } else {
	 $result = &callsub("end_$token->[1]", $target, $token, \@parstack,
			    \@pars,$safeeval, \%style_for_target);
       }
     } else {
       &Apache::lonxml::error("Unknown token event :$token->[0]:$token->[1]:");
     }
     #evaluate variable refs in result
     if ($result ne "") {
       if ( $#parstack > -1 ) {
	 if ($Apache::lonxml::redirection) {
	   $Apache::lonxml::outputstack['-1'] .= 
	     &Apache::run::evaluate($result,$safeeval,$parstack[$#parstack]);
	 } else {
	   $finaloutput .= &Apache::run::evaluate($result,$safeeval,
						  $parstack[$#parstack]);
	 }
       } else {
	 $finaloutput .= &Apache::run::evaluate($result,$safeeval,'');
       }
       $result = '';
     } 
     if ($token->[0] eq 'E') { 
       pop @stack;pop @parstack;&decreasedepth($token);
     }
   }
   pop @pars;
   pop @Apache::lonxml::pwd;
 }

# if ($target eq 'meta') {
#   $finaloutput.=&endredirection;
# }

  if (($ENV{'QUERY_STRING'}) && ($target eq 'web')) {
      $finaloutput=&afterburn($finaloutput);
  }

 return $finaloutput;
}


sub recurse {
  
  my @innerstack = (); 
  my @innerparstack = ();
  my ($newarg,$target,$safeeval,$style_for_target,@parstack) = @_;
  my @pat = ();
  &newparser(\@pat,\$newarg);
  my $tokenpat;
  my $partstring = '';
  my $output='';
  my $decls='';
  while ( $#pat > -1 ) {
    while  ($tokenpat = $pat[$#pat]->get_token) {
      if (($tokenpat->[0] eq 'T') || ($tokenpat->[0] eq 'C') || ($tokenpat->[0] eq 'D') ) {
	if ($metamode<1) { $partstring=$tokenpat->[1]; }
      } elsif ($tokenpat->[0] eq 'PI') {
	if ($metamode<1) { $partstring=$tokenpat->[2]; }
      } elsif ($tokenpat->[0] eq 'S') {
	push (@innerstack,$tokenpat->[1]);
	push (@innerparstack,&parstring($tokenpat));
	&increasedepth($tokenpat);
	$partstring = &callsub("start_$tokenpat->[1]", 
			       $target, $tokenpat, \@innerparstack,
			       \@pat, $safeeval, $style_for_target);
      } elsif ($tokenpat->[0] eq 'E') {
	#clear out any tags that didn't end
	while ($tokenpat->[1] ne $innerstack[$#innerstack] 
	       && ($#innerstack > -1)) {
	  &Apache::lonxml::warning("Unbalanced tags in resource $innerstack['-1']");
	  pop @innerstack;pop @innerparstack;&decreasedepth($tokenpat);
	}
	$partstring = &callsub("end_$tokenpat->[1]",
			       $target, $tokenpat, \@innerparstack,
			       \@pat, $safeeval, $style_for_target);
      } else {
	&Apache::lonxml::error("Unknown token event :$tokenpat->[0]:$tokenpat->[1]:");
      }
      #pass both the variable to the style tag, and the tag we 
      #are processing inside the <definedtag>
      if ( $partstring ne "" ) {
	if ( $#parstack > -1 ) { 
	  if ( $#innerparstack > -1 ) { 
	    $decls= $parstack[$#parstack].$innerparstack[$#innerparstack];
	  } else {
	    $decls= $parstack[$#parstack];
	  }
	} else {
	  if ( $#innerparstack > -1 ) { 
	    $decls=$innerparstack[$#innerparstack];
	  } else {
	    $decls='';
	  }
	}
	$output .= &Apache::run::evaluate($partstring,$safeeval,$decls);
	$partstring = '';
      }
      if ($tokenpat->[0] eq 'E') { pop @innerstack;pop @innerparstack;
				 &decreasedepth($tokenpat);}
    }
    pop @pat;
    pop @Apache::lonxml::pwd;
  }
  return $output;
}

sub callsub {
  my ($sub,$target,$token,$parstack,$parser,$safeeval,$style)=@_;
  my $currentstring='';
  my $nodefault;
  {
    my $sub1;
    no strict 'refs';
    if ($target eq 'edit' && $token->[0] eq 'S') {
      $currentstring = &Apache::edit::tag_start($target,$token,$parstack,$parser,
						$safeeval,$style);
    }
    my $tag=$token->[1];
    my $space=$Apache::lonxml::alltags{$tag};
    if (!$space) {
	$tag=~tr/A-Z/a-z/;
	$sub=~tr/A-Z/a-z/;
	$space=$Apache::lonxml::alltags{$tag}
    }
    if ($space) {
      #&Apache::lonxml::debug("Calling sub $sub in $space $metamode<br />\n");
      $sub1="$space\:\:$sub";
      $Apache::lonxml::curdepth=join('_',@Apache::lonxml::depthcounter);
      ($currentstring,$nodefault) = &$sub1($target,$token,$parstack,$parser,
					   $safeeval,$style);
    } else {
      #&Apache::lonxml::debug("NOT Calling sub $sub in $space $metamode<br />\n");
      if ($metamode <1) {
	if (defined($token->[4]) && ($metamode < 1)) {
	  $currentstring = $token->[4];
	} else {
	  $currentstring = $token->[2];
	}
      }
    }
    &Apache::lonxml::debug("nodefalt:$nodefault:");
    if ($currentstring eq '' && $nodefault eq '') {
      if ($target eq 'edit') {
	&Apache::lonxml::debug("doing default edit for $token->[1]");
	if ($token->[0] eq 'S') {
	  $currentstring = &Apache::edit::tag_start($target,$token);
	} elsif ($token->[0] eq 'E') {
	  $currentstring = &Apache::edit::tag_end($target,$token);
	}
      } elsif ($target eq 'modified') {
	if ($token->[0] eq 'S') {
	  $currentstring = $token->[4];
	  $currentstring.=&Apache::edit::handle_insert();
	} else {
	  $currentstring = $token->[2];
	}
      }
    }
    use strict 'refs';
  }
  return $currentstring;
}

sub startredirection {
  $Apache::lonxml::redirection++;
  push (@Apache::lonxml::outputstack, '');
}

sub endredirection {
  if (!$Apache::lonxml::redirection) {
    &Apache::lonxml::error("Endredirection was called, before a startredirection, perhaps you have unbalanced tags. Some debuging information:".join ":",caller);
    return '';
  }
  $Apache::lonxml::redirection--;
  pop @Apache::lonxml::outputstack;
}

sub initdepth {
  @Apache::lonxml::depthcounter=();
  $Apache::lonxml::depth=-1;
  $Apache::lonxml::olddepth=-1;
}

sub increasedepth {
  my ($token) = @_;
  $Apache::lonxml::depth++;
  $Apache::lonxml::depthcounter[$Apache::lonxml::depth]++;
  if ($Apache::lonxml::depthcounter[$Apache::lonxml::depth]==1) {
    $Apache::lonxml::olddepth=$Apache::lonxml::depth;
  }
  my $curdepth=join('_',@Apache::lonxml::depthcounter);
  &Apache::lonxml::debug("s $Apache::lonxml::depth : $Apache::lonxml::olddepth : $curdepth : $token->[1]\n");
#print "<br />s $Apache::lonxml::depth : $Apache::lonxml::olddepth : $curdepth : $token->[1]\n";
}

sub decreasedepth {
  my ($token) = @_;
  $Apache::lonxml::depth--;
  if ($Apache::lonxml::depth<$Apache::lonxml::olddepth-1) {
    $#Apache::lonxml::depthcounter--;
    $Apache::lonxml::olddepth=$Apache::lonxml::depth+1;
  }
  if (  $Apache::lonxml::depth < -1) {
    &Apache::lonxml::warning("Unbalanced tags in resource");   
    $Apache::lonxml::depth='-1';
  }
  my $curdepth=join('_',@Apache::lonxml::depthcounter);
  &Apache::lonxml::debug("e $Apache::lonxml::depth : $Apache::lonxml::olddepth : $token->[1] : $curdepth\n");
#print "<br />e $Apache::lonxml::depth : $Apache::lonxml::olddepth : $token->[1] : $curdepth\n";
}

sub get_all_text {

 my($tag,$pars)= @_;
 my $depth=0;
 my $token;
 my $result='';
 if ( $tag =~ m:^/: ) { 
   my $tag=substr($tag,1); 
#   &Apache::lonxml::debug("have:$tag:");
   while (($depth >=0) && ($token = $pars->get_token)) {
#     &Apache::lonxml::debug("e token:$token->[0]:$depth:$token->[1]");
     if (($token->[0] eq 'T')||($token->[0] eq 'C')||($token->[0] eq 'D')) {
       $result.=$token->[1];
     } elsif ($token->[0] eq 'PI') {
       $result.=$token->[2];
     } elsif ($token->[0] eq 'S') {
       if ($token->[1] eq $tag) { $depth++; }
       $result.=$token->[4];
     } elsif ($token->[0] eq 'E')  {
       if ( $token->[1] eq $tag) { $depth--; }
       #skip sending back the last end tag
       if ($depth > -1) { $result.=$token->[2]; } else {
	 $pars->unget_token($token);
       }
     }
   }
 } else {
   while ($token = $pars->get_token) {
#     &Apache::lonxml::debug("s token:$token->[0]:$depth:$token->[1]");
     if (($token->[0] eq 'T')||($token->[0] eq 'C')||($token->[0] eq 'D')) {
       $result.=$token->[1];
     } elsif ($token->[0] eq 'PI') {
       $result.=$token->[2];
     } elsif ($token->[0] eq 'S') {
       if ( $token->[1] eq $tag) { 
	 $pars->unget_token($token); last;
       } else {
	 $result.=$token->[4];
       }
     } elsif ($token->[0] eq 'E')  {
       $result.=$token->[2];
     }
   }
 }
# &Apache::lonxml::debug("Exit:$result:");
 return $result
}

sub newparser {
  my ($parser,$contentref,$dir) = @_;
  push (@$parser,HTML::TokeParser->new($contentref));
  $$parser['-1']->xml_mode('1');
  if ( $dir eq '' ) {
    push (@Apache::lonxml::pwd, $Apache::lonxml::pwd[$#Apache::lonxml::pwd]);
  } else {
    push (@Apache::lonxml::pwd, $dir);
  } 
#  &Apache::lonxml::debug("pwd:$#Apache::lonxml::pwd");
#  &Apache::lonxml::debug("pwd:$Apache::lonxml::pwd[$#Apache::lonxml::pwd]");
}

sub parstring {
  my ($token) = @_;
  my $temp='';
  map {
    unless ($_=~/\W/) {
      my $val=$token->[2]->{$_};
      $val =~ s/([\%\@\\])/\\$1/g;
      #if ($val =~ m/^[\%\@]/) { $val="\\".$val; }
      $temp .= "my \$$_=\"$val\";"
    }
  } @{$token->[3]};
  return $temp;
}

sub writeallows {
    my $thisurl='/res/'.&Apache::lonnet::declutter(shift);
    my $thisdir=$thisurl;
    $thisdir=~s/\/[^\/]+$//;
    my %httpref=();
    map {
       $httpref{'httpref.'.
 	        &Apache::lonnet::hreflocation($thisdir,$_)}=$thisurl;              } @extlinks;
    &Apache::lonnet::appenv(%httpref);
}

#
# Afterburner handles anchors, highlights and links
#
sub afterburn {
    my $result=shift;
    map {
       my ($name, $value) = split(/=/,$_);
       $value =~ tr/+/ /;
       $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
       if (($name eq 'highlight')||($name eq 'anchor')||($name eq 'link')) {
           unless ($ENV{'form.'.$name}) {
              $ENV{'form.'.$name}=$value;
	   }
       }
    } (split(/&/,$ENV{'QUERY_STRING'}));
    if ($ENV{'form.highlight'}) {
        map {
           my $anchorname=$_;
	   my $matchthis=$anchorname;
           $matchthis=~s/\_+/\\s\+/g;
           $result=~s/($matchthis)/\<font color=\"red\"\>$1\<\/font\>/gs;
       } split(/\,/,$ENV{'form.highlight'});
    }
    if ($ENV{'form.link'}) {
        map {
           my ($anchorname,$linkurl)=split(/\>/,$_);
	   my $matchthis=$anchorname;
           $matchthis=~s/\_+/\\s\+/g;
           $result=~s/($matchthis)/\<a href=\"$linkurl\"\>$1\<\/a\>/gs;
       } split(/\,/,$ENV{'form.link'});
    }
    if ($ENV{'form.anchor'}) {
        my $anchorname=$ENV{'form.anchor'};
	my $matchthis=$anchorname;
        $matchthis=~s/\_+/\\s\+/g;
        $result=~s/($matchthis)/\<a name=\"$anchorname\"\>$1\<\/a\>/s;
        $result.=(<<"ENDSCRIPT");
<script>
    document.location.hash='$anchorname';
</script>
ENDSCRIPT
    }
    return $result;
}

sub storefile {
    my ($file,$contents)=@_;
    if (my $fh=Apache::File->new('>'.$file)) {
	print $fh $contents;
        $fh->close();
    }
}

sub inserteditinfo {
      my ($result,$filecontents)=@_;
      unless ($filecontents) {
	  $filecontents=(<<SIMPLECONTENT);
<html>
<head>
<title>
                           Title of Document Goes Here
</title>
</head>
<body bgcolor="#FFFFFF">

                           Body of Document Goes Here

</body>
</html>
SIMPLECONTENT
      }
      my $editheader='<a href="#editsection">Edit below</a><hr />';
      my $editfooter=(<<ENDFOOTER);
<hr />
<a name="editsection" />
<form method="post">
<textarea cols="80" rows="40" name="filecont">$filecontents</textarea>
<br />
<input type="submit" name="savethisfile" value="Save this file" />
</form>
ENDFOOTER
      $result=~s/(\<body[^\>]*\>)/$1$editheader/is;
      $result=~s/(\<\/body\>)/$editfooter/is;
      return $result;
}

sub handler {
  my $request=shift;

  my $target='web';

  $Apache::lonxml::debug=0;

  if ($ENV{'browser.mathml'}) {
    $request->content_type('text/xml');
  } else {
    $request->content_type('text/html');
  }
  
  $request->send_http_header;
  
  return OK if $request->header_only;


  my $file=&Apache::lonnet::filelocation("",$request->uri);
#
# Edit action? Save file.
#
  unless ($ENV{'request.state'} eq 'published') {
      if ($ENV{'form.savethisfile'}) {
	  &storefile($file,$ENV{'form.filecont'});
      }
  }
  my %mystyle;
  my $result = ''; 
  my $filecontents=&Apache::lonnet::getfile($file);
  if ($filecontents == -1) {
    $result=(<<ENDNOTFOUND);
<html>
<head>
<title>File not found</title>
</head>
<body bgcolor="#FFFFFF">
<b>File not found: $file</b>
</body>
</html>
ENDNOTFOUND
    $filecontents='';
  } else {
    $result = &Apache::lonxml::xmlparse($target,$filecontents,'',%mystyle);
  }

#
# Edit action? Insert editing commands
#
  unless ($ENV{'request.state'} eq 'published') {
      $result=&inserteditinfo($result,$filecontents);
  }

  $request->print($result);

  writeallows($request->uri);
  return OK;
}
 
sub debug {
  if ($Apache::lonxml::debug eq 1) {
    print "DEBUG:".$_[0]."<br />\n";
  }
}

sub error {
  if (($Apache::lonxml::debug eq 1) || ($ENV{'request.state'} eq 'construct') ) {
    print "<b>ERROR:</b>".$_[0]."<br />\n";
  } else {
    print "<b>An Error occured while processing this resource. The instructor has been notified.</b> <br />";
    #notify author
    &Apache::lonmsg::author_res_msg($ENV{'request.filename'},$_[0]);
    #notify course
    if ( $ENV{'request.course.id'} ) {
      my $users=$ENV{'course.'.$ENV{'request.course.id'}.'.comment.email'};
      foreach my $user (split /\,/, $users) {
	($user,my $domain) = split /:/, $user;
	&Apache::lonmsg::user_normal_msg($user,$domain,"Error in $ENV{'request.filename'}",$_[0]);
      }
    }

    #FIXME probably shouldn't have me get everything forever.
    &Apache::lonmsg::user_normal_msg('albertel','msu',"Error in $ENV{'request.filename'}",$_[0]);
    #&Apache::lonmsg::user_normal_msg('albertel','103',"Error in $ENV{'request.filename'}",$_[0]);
  }
}

sub warning {
  if ($ENV{'request.state'} eq 'construct') {
    print "<b>W</b>ARNING<b>:</b>".$_[0]."<br />\n";
  }
}

sub register_insert {
  my @data = split /\n/, &Apache::lonnet::getfile('/home/httpd/lonTabs/insertlist.tab');
  my $i;
  my $tagnum=0;
  my @order;
  for ($i=0;$i < $#data; $i++) {
    my $line = $data[$i];
    if ( $line =~ /^\#/ || $line =~ /^\s*\n/) { next; }
    if ( $line =~ /TABLE/ ) { last; }
    my ($tag,$descrip,$function,$show) = split(/,/, $line);
    $insertlist{"$tagnum.tag"} = $tag;
    $insertlist{"$tagnum.description"} = $descrip;
    $insertlist{"$tagnum.function"} = $function;
    $insertlist{"$tagnum.show"}= $show;
    $tagnum++;
  }
  $i++; #skipping TABLE line
  $tagnum = 0;
  for (;$i < $#data;$i++) {
    my $line = $data[$i];
    my ($mnemonic,@which) = split(/ +/,$line);
    my $tag = $insertlist{"$tagnum.tag"};
    for (my $j=0;$j <$#which;$j++) {
      if ( $which[$j] eq 'Y' ) {
	if ($insertlist{"$j.show"} ne 'no') {
	  push(@{ $insertlist{"$tag.which"} },$j);
	}
      }
    }
    $tagnum++;
  }
}
1;
__END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>