1: # The LearningOnline Network with CAPA
2: # Construct and maintain state and binary representation of course for user
3: #
4: # $Id: lonuserstate.pm,v 1.149.2.5 2021/12/14 22:52:33 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: package Apache::lonuserstate;
31:
32: # ------------------------------------------------- modules used by this module
33: use strict;
34: use HTML::TokeParser;
35: use Apache::lonnet;
36: use Apache::lonlocal;
37: use Apache::loncommon();
38: use GDBM_File;
39: use Apache::lonmsg;
40: use Safe;
41: use Safe::Hole;
42: use Opcode;
43: use Apache::lonenc;
44: use Fcntl qw(:flock);
45: use LONCAPA;
46: use File::Basename;
47:
48:
49:
50: # ---------------------------------------------------- Globals for this package
51:
52: my $pc; # Package counter is this what 'Guts' calls the map counter?
53: my %hash; # The big tied hash
54: my %parmhash;# The hash with the parameters
55: my @cond; # Array with all of the conditions
56: my $errtext; # variable with all errors
57: my $retfrid; # variable with the very first RID in the course
58: my $retfurl; # first URL
59: my %randompick; # randomly picked resources
60: my %randompickseed; # optional seed for randomly picking resources
61: my %randomorder; # maps to order contents randomly
62: my %randomizationcode; # code used to grade folder for bubblesheet exam
63: my %encurl; # URLs in this folder are supposed to be encrypted
64: my %hiddenurl; # this URL (or complete folder) is supposed to be hidden
65: my %rescount; # count of unhidden items in each map
66: my %mapcount; # count of unhidden maps in each map
67:
68: # ----------------------------------- Remove version from URL and store in hash
69:
70: sub versionerror {
71: my ($uri,$usedversion,$unusedversion)=@_;
72: return '<br />'.&mt('Version discrepancy: resource [_1] included in both version [_2] and version [_3]. Using version [_2].',
73: $uri,$usedversion,$unusedversion).'<br />';
74: }
75:
76: # Removes the version number from a URI and returns the resulting
77: # URI (e.g. mumbly.version.stuff => mumbly.stuff).
78: #
79: # If the URI has not been seen with a versio before the
80: # hash{'version_'.resultingURI} is set to the version number.
81: # If the URI has been seen and the version does not match and error
82: # is added to the error string.
83: #
84: # Parameters:
85: # URI potentially with a version.
86: # Returns:
87: # URI with the version cut out.
88: # See above for side effects.
89: #
90:
91: sub versiontrack {
92: my $uri=shift;
93: if ($uri=~/\.(\d+)\.\w+$/) {
94: my $version=$1;
95: $uri=~s/\.\d+\.(\w+)$/\.$1/;
96: unless ($hash{'version_'.$uri}) {
97: $hash{'version_'.$uri}=$version;
98: } elsif ($version!=$hash{'version_'.$uri}) {
99: $errtext.=&versionerror($uri,$hash{'version_'.$uri},$version);
100: }
101: }
102: return $uri;
103: }
104:
105: # -------------------------------------------------------------- Put in version
106:
107: sub putinversion {
108: my $uri=shift;
109: my $key=$env{'request.course.id'}.'_'.&Apache::lonnet::clutter($uri);
110: if ($hash{'version_'.$uri}) {
111: my $version=$hash{'version_'.$uri};
112: if ($version eq 'mostrecent') { return $uri; }
113: if ($version eq &Apache::lonnet::getversion(
114: &Apache::lonnet::filelocation('',$uri)))
115: { return $uri; }
116: $uri=~s/\.(\w+)$/\.$version\.$1/;
117: }
118: &Apache::lonnet::do_cache_new('courseresversion',$key,&Apache::lonnet::declutter($uri),600);
119: return $uri;
120: }
121:
122: # ----------------------------------------- Processing versions file for course
123:
124: sub processversionfile {
125: my %cenv=@_;
126: my %versions=&Apache::lonnet::dump('resourceversions',
127: $cenv{'domain'},
128: $cenv{'num'});
129: foreach my $ver (keys(%versions)) {
130: if ($ver=~/^error\:/) { return; }
131: $hash{'version_'.$ver}=$versions{$ver};
132: }
133: }
134:
135: # --------------------------------------------------------- Loads from disk
136:
137:
138: #
139: # Loads a map file.
140: # Note that this may implicitly recurse via parse_resource if one of the resources
141: # is itself composed.
142: #
143: # Parameters:
144: # uri - URI of the map file.
145: # parent_rid - Resource id in the map of the parent resource (0.0 for the top level map)
146: # courseid - Course id for the course for which the map is being loaded
147: #
148: sub loadmap {
149: my ($uri,$parent_rid,$courseid)=@_;
150:
151: # Is the map already included?
152:
153: if ($hash{'map_pc_'.$uri}) {
154: $errtext.='<p class="LC_error">'.
155: &mt('Multiple use of sequence/page [_1]! The course will not function properly.','<tt>'.$uri.'</tt>').
156: '</p>';
157: return;
158: }
159: # Register the resource in it's map_pc_ [for the URL]
160: # map_id.nnn is the nesting level -> to the URI.
161:
162: $pc++;
163: my $lpc=$pc;
164: $hash{'map_pc_'.$uri}=$lpc;
165: $hash{'map_id_'.$lpc}=$uri;
166:
167: # If the parent is of the form n.m hang this map underneath it in the
168: # map hierarchy.
169:
170: if ($parent_rid =~ /^(\d+)\.\d+$/) {
171: my $parent_pc = $1;
172: if (defined($hash{'map_hierarchy_'.$parent_pc})) {
173: $hash{'map_hierarchy_'.$lpc}=$hash{'map_hierarchy_'.$parent_pc}.','.
174: $parent_pc;
175: } else {
176: $hash{'map_hierarchy_'.$lpc}=$parent_pc;
177: }
178: }
179:
180: # Determine and check filename of the sequence we need to read:
181:
182: my $fn=&Apache::lonnet::filelocation('',&putinversion($uri));
183:
184: my $ispage=($fn=~/\.page$/);
185:
186: # We can only nest sequences or pages. Anything else is an illegal nest.
187:
188: unless (($fn=~/\.sequence$/) || $ispage) {
189: $errtext.='<br />'.&mt('Invalid map: [_1]',"<tt>$fn</tt>");
190: return;
191: }
192:
193: # Read the XML that constitutes the file.
194:
195: my $instr=&Apache::lonnet::getfile($fn);
196:
197: if ($instr eq -1) {
198: $errtext.= '<br />'
199: .&mt('Map not loaded: The file [_1] does not exist.',
200: "<tt>$fn</tt>");
201: return;
202: }
203:
204: # Successfully got file, parse it
205:
206: # parse for parameter processing.
207: # Note that these are <param... / > tags
208: # so we only care about 'S' (tag start) nodes.
209:
210:
211: my $parser = HTML::TokeParser->new(\$instr);
212: $parser->attr_encoded(1);
213:
214: # first get all parameters
215:
216:
217: while (my $token = $parser->get_token) {
218: next if ($token->[0] ne 'S');
219: if ($token->[1] eq 'param') {
220: &parse_param($token,$lpc);
221: }
222: }
223:
224: # Get set to take another pass through the XML:
225: # for resources and links.
226:
227: $parser = HTML::TokeParser->new(\$instr);
228: $parser->attr_encoded(1);
229:
230: my $linkpc=0;
231:
232: $fn=~/\.(\w+)$/;
233:
234: $hash{'map_type_'.$lpc}=$1;
235:
236: my $randomize = ($randomorder{$parent_rid} =~ /^yes$/i);
237:
238: # Parse the resources, link and condition tags.
239: # Note that if randomorder or random select is chosen the links and
240: # conditions are meaningless but are determined by the randomization.
241: # This is handled in the next chunk of code.
242:
243: my @map_ids;
244: my $codechecked;
245: $rescount{$lpc} = 0;
246: $mapcount{$lpc} = 0;
247: while (my $token = $parser->get_token) {
248: next if ($token->[0] ne 'S');
249:
250: # Resource
251:
252: if ($token->[1] eq 'resource') {
253: my $resource_id = &parse_resource($token,$lpc,$ispage,$uri,$courseid);
254: if (defined $resource_id) {
255: push(@map_ids, $resource_id);
256: if ($hash{'src_'.$lpc.'.'.$resource_id}) {
257: $rescount{$lpc} ++;
258: if (($hash{'src_'.$lpc.'.'.$resource_id}=~/\.sequence$/) ||
259: ($hash{'src_'.$lpc.'.'.$resource_id}=~/\.page$/)) {
260: $mapcount{$lpc} ++;
261: }
262: }
263: unless ($codechecked) {
264: my $startsymb =
265: &Apache::lonnet::encode_symb($hash{'map_id_'.$lpc},$resource_id,
266: $hash{'src_'."$lpc.$resource_id"});
267: my $code =
268: &Apache::lonnet::EXT('resource.0.examcode',$startsymb,undef,undef,
269: undef,undef,$courseid);
270: if ($code) {
271: $randomizationcode{$parent_rid} = $code;
272: }
273: $codechecked = 1;
274: }
275: }
276:
277: # Link
278:
279: } elsif ($token->[1] eq 'link' && !$randomize) {
280: &make_link(++$linkpc,$lpc,$token->[2]->{'to'},
281: $token->[2]->{'from'},
282: $token->[2]->{'condition'}); # note ..condition may be undefined.
283:
284: # condition
285:
286: } elsif ($token->[1] eq 'condition' && !$randomize) {
287: &parse_condition($token,$lpc);
288: }
289: }
290: undef($codechecked);
291:
292: # Handle randomization and random selection
293:
294: if ($randomize) {
295: unless (&is_advanced($courseid)) {
296: # Order of resources is not randomized if user has and advanced role in the course.
297: my $seed;
298:
299: # If the map's random seed parameter has been specified
300: # it is used as the basis for computing the seed ...
301:
302: if (defined($randompickseed{$parent_rid})) {
303: $seed = $randompickseed{$parent_rid};
304: } else {
305:
306: # Otherwise the parent's fully encoded symb is used.
307:
308: my ($mapid,$resid)=split(/\./,$parent_rid);
309: my $symb=
310: &Apache::lonnet::encode_symb($hash{'map_id_'.$mapid},
311: $resid,$hash{'src_'.$parent_rid});
312:
313: $seed = $symb;
314: }
315:
316: # TODO: Here for sure we need to pass along the username/domain
317: # so that we can impersonate users in lonprintout e.g.
318:
319: my $setcode;
320: if (defined($randomizationcode{$parent_rid})) {
321: if ($env{'form.CODE'} eq '') {
322: $env{'form.CODE'} = $randomizationcode{$parent_rid};
323: $setcode = 1;
324: }
325: }
326:
327: my $rndseed=&Apache::lonnet::rndseed($seed);
328: &Apache::lonnet::setup_random_from_rndseed($rndseed);
329:
330: if ($setcode) {
331: undef($env{'form.CODE'});
332: undef($setcode);
333: }
334:
335: # Take the set of map ids we have decoded and permute them to a
336: # random order based on the seed set above. All of this is
337: # processing the randomorder parameter if it is set, not
338: # randompick.
339:
340: @map_ids=&Math::Random::random_permutation(@map_ids);
341: }
342:
343: my $from = shift(@map_ids);
344: my $from_rid = $lpc.'.'.$from;
345: $hash{'map_start_'.$uri} = $from_rid;
346: $hash{'type_'.$from_rid}='start';
347:
348: # Create links to reflect the random re-ordering done above.
349: # In the code to process the map XML, we did not process links or conditions
350: # if randomorder was set. This means that for an instructor to choose
351:
352: while (my $to = shift(@map_ids)) {
353: &make_link(++$linkpc,$lpc,$to,$from);
354: my $to_rid = $lpc.'.'.$to;
355: $hash{'type_'.$to_rid}='normal';
356: $from = $to;
357: $from_rid = $to_rid;
358: }
359:
360: $hash{'map_finish_'.$uri}= $from_rid;
361: $hash{'type_'.$from_rid}='finish';
362: }
363:
364: $parser = HTML::TokeParser->new(\$instr);
365: $parser->attr_encoded(1);
366:
367: # last parse out the mapalias params. These provide mnemonic
368: # tags to resources that can be used in conditions
369:
370: while (my $token = $parser->get_token) {
371: next if ($token->[0] ne 'S');
372: if ($token->[1] eq 'param') {
373: &parse_mapalias_param($token,$lpc);
374: }
375: }
376: }
377:
378: sub is_advanced {
379: my ($courseid) = @_;
380: my $advanced;
381: if ($env{'request.course.id'}) {
382: $advanced = (&Apache::lonnet::allowed('adv') eq 'F');
383: } else {
384: $env{'request.course.id'} = $courseid;
385: $advanced = (&Apache::lonnet::allowed('adv') eq 'F');
386: $env{'request.course.id'} = '';
387: }
388: return $advanced;
389: }
390:
391: # -------------------------------------------------------------------- Resource
392: #
393: # Parses a resource tag to produce the value to push into the
394: # map_ids array.
395: #
396: #
397: # Information about the actual type of resource is provided by the file extension
398: # of the uri (e.g. .problem, .sequence etc. etc.).
399: #
400: # Parameters:
401: # $token - A token from HTML::TokeParser
402: # This is an array that describes the most recently parsed HTML item.
403: # $lpc - Map nesting level (?)
404: # $ispage - True if this resource is encapsulated in a .page (assembled resourcde).
405: # $uri - URI of the enclosing resource.
406: # $courseid - Course id of the course containing the resource being parsed.
407: # Returns:
408: # Value of the id attribute of the tag.
409: #
410: # Note:
411: # The token is an array that contains the following elements:
412: # [0] => 'S' indicating this is a start token
413: # [1] => 'resource' indicating this tag is a <resource> tag.
414: # [2] => Hash of attribute =>value pairs.
415: # [3] => @(keys [2]).
416: # [4] => unused.
417: #
418: # The attributes of the resourcde tag include:
419: #
420: # id - The resource id.
421: # src - The URI of the resource.
422: # type - The resource type (e.g. start and finish).
423: # title - The resource title.
424:
425:
426: sub parse_resource {
427: my ($token,$lpc,$ispage,$uri,$courseid) = @_;
428:
429: # I refuse to countenance code like this that has
430: # such a dirty side effect (and forcing this sub to be called within a loop).
431: #
432: # if ($token->[2]->{'type'} eq 'zombie') { next; }
433: #
434: # The original code both returns _and_ skips to the next pass of the >caller's<
435: # loop, that's just dirty.
436: #
437:
438: # Zombie resources don't produce anything useful.
439:
440: if ($token->[2]->{'type'} eq 'zombie') {
441: return undef;
442: }
443:
444: my $rid=$lpc.'.'.$token->[2]->{'id'}; # Resource id in hash is levelcounter.id-in-xml.
445:
446: # Save the hash element type and title:
447:
448: $hash{'kind_'.$rid}='res';
449: $hash{'title_'.$rid}=$token->[2]->{'title'};
450:
451: # Get the version free URI for the resource.
452: # If a 'version' attribute was supplied, and this resource's version
453: # information has not yet been stored, store it.
454: #
455:
456: my $turi=&versiontrack($token->[2]->{'src'});
457: if ($token->[2]->{'version'}) {
458: unless ($hash{'version_'.$turi}) {
459: $hash{'version_'.$turi}=$1;
460: }
461: }
462: # Pull out the title and do entity substitution on &colon
463: # Q: Why no other entity substitutions?
464:
465: my $title=$token->[2]->{'title'};
466: $title=~s/\&colon\;/\:/gs;
467:
468:
469:
470: # I think the point of all this code is to construct a final
471: # URI that apache and its rewrite rules can use to
472: # fetch the resource. Thi s sonly necessary if the resource
473: # is not a page. If the resource is a page then it must be
474: # assembled (at fetch time?).
475:
476: if ($ispage) {
477: if ($token->[2]->{'external'} eq 'true') { # external
478: $turi=~s{^http\://}{/ext/};
479: }
480: } else {
481: $turi=~/\.(\w+)$/;
482: my $embstyle=&Apache::loncommon::fileembstyle($1);
483: if ($token->[2]->{'external'} eq 'true') { # external
484: $turi=~s/^https?\:\/\//\/adm\/wrapper\/ext\//;
485: } elsif ($turi=~/^\/*uploaded\//) { # uploaded
486: if (($embstyle eq 'img')
487: || ($embstyle eq 'emb')
488: || ($embstyle eq 'wrp')) {
489: $turi='/adm/wrapper'.$turi;
490: } elsif ($embstyle eq 'ssi') {
491: #do nothing with these
492: } elsif ($turi!~/\.(sequence|page)$/) {
493: $turi='/adm/coursedocs/showdoc'.$turi;
494: }
495: } elsif ($turi=~/\S/) { # normal non-empty internal resource
496: my $mapdir=$uri;
497: $mapdir=~s/[^\/]+$//;
498: $turi=&Apache::lonnet::hreflocation($mapdir,$turi);
499: if (($embstyle eq 'img')
500: || ($embstyle eq 'emb')
501: || ($embstyle eq 'wrp')) {
502: $turi='/adm/wrapper'.$turi;
503: }
504: }
505: }
506: # Store reverse lookup, remove query string resource 'ids'_uri => resource id.
507: # If the URI appears more than one time in the sequence, it's resourcde
508: # id's are constructed as a comma spearated list.
509:
510: my $idsuri=$turi;
511: $idsuri=~s/\?.+$//;
512: if (defined($hash{'ids_'.$idsuri})) {
513: $hash{'ids_'.$idsuri}.=','.$rid;
514: } else {
515: $hash{'ids_'.$idsuri}=''.$rid;
516: }
517:
518:
519:
520: if ($turi=~/\/(syllabus|aboutme|navmaps|smppg|bulletinboard|viewclasslist)$/) {
521: $turi.='?register=1';
522: }
523:
524:
525: # resource id lookup: 'src'_resourc-di => URI decorated with a query
526: # parameter as above if necessary due to the resource type.
527:
528: $hash{'src_'.$rid}=$turi;
529:
530: # Mark the external-ness of the resource:
531:
532: if ($token->[2]->{'external'} eq 'true') {
533: $hash{'ext_'.$rid}='true:';
534: } else {
535: $hash{'ext_'.$rid}='false:';
536: }
537:
538: # If the resource is a start/finish resource set those
539: # entries in the has so that navigation knows where everything starts.
540: # TODO? If there is a malformed sequence that has no start or no finish
541: # resource, should this be detected and errors thrown? How would such a
542: # resource come into being other than being manually constructed by a person
543: # and then uploaded? Could that happen if an author decided a sequence was almost
544: # right edited it by hand and then reuploaded it to 'fix it' but accidently cut the
545: # start or finish resources?
546: #
547: # All resourcess also get a type_id => (start | finish | normal) hash entr.
548: #
549: if ($token->[2]->{'type'}) {
550: $hash{'type_'.$rid}=$token->[2]->{'type'};
551: if ($token->[2]->{'type'} eq 'start') {
552: $hash{'map_start_'.$uri}="$rid";
553: }
554: if ($token->[2]->{'type'} eq 'finish') {
555: $hash{'map_finish_'.$uri}="$rid";
556: }
557: } else {
558: $hash{'type_'.$rid}='normal';
559: }
560:
561: # Sequences end pages are constructed entities. They require that the
562: # map that defines _them_ be loaded as well into the hash...with this resourcde
563: # as the base of the nesting.
564: # Resources like that are also marked with is_map_id => 1 entries.
565: #
566:
567: if (($turi=~/\.sequence$/) ||
568: ($turi=~/\.page$/)) {
569: $hash{'is_map_'.$rid}=1;
570: if ((!$hiddenurl{$rid}) || (&is_advanced($courseid))) {
571: &loadmap($turi,$rid,$courseid);
572: }
573: }
574: return $token->[2]->{'id'};
575: }
576:
577: #-------------------------------------------------------------------- link
578: # Links define how you are allowed to move from one resource to another.
579: # They are the transition edges in the directed graph that a map is.
580: # This sub takes informatino from a <link> tag and constructs the
581: # navigation bits and pieces of a map. There is no requirement that the
582: # resources that are linke are already defined, however clearly the map is
583: # badly broken if they are not _eventually_ defined.
584: #
585: # Note that links can be unconditional or conditional.
586: #
587: # Parameters:
588: # linkpc - The link counter for this level of map nesting (this is
589: # reset to zero by loadmap prior to starting to process
590: # links for map).
591: # lpc - The map level ocounter (how deeply nested this map is in
592: # the hierarchy of maps that are recursively read in.
593: # to - resource id (within the XML) of the target of the edge.
594: # from - resource id (within the XML) of the source of the edge.
595: # condition- id of condition associated with the edge (also within the XML).
596: #
597:
598: sub make_link {
599: my ($linkpc,$lpc,$to,$from,$condition) = @_;
600:
601: # Compute fully qualified ids for the link, the
602: # and from/to by prepending lpc.
603: #
604:
605: my $linkid=$lpc.'.'.$linkpc;
606: my $goesto=$lpc.'.'.$to;
607: my $comesfrom=$lpc.'.'.$from;
608: my $undercond=0;
609:
610:
611: # If there is a condition, qualify it with the level counter.
612:
613: if ($condition) {
614: $undercond=$lpc.'.'.$condition;
615: }
616:
617: # Links are represnted by:
618: # goesto_.fuullyqualifedlinkid => fully qualified to
619: # comesfrom.fullyqualifiedlinkid => fully qualified from
620: # undercond_.fullyqualifiedlinkid => fully qualified condition id.
621:
622: $hash{'goesto_'.$linkid}=$goesto;
623: $hash{'comesfrom_'.$linkid}=$comesfrom;
624: $hash{'undercond_'.$linkid}=$undercond;
625:
626: # In addition:
627: # to_.fully qualified from => comma separated list of
628: # link ids with that from.
629: # Similarly:
630: # from_.fully qualified to => comma separated list of link ids`
631: # with that to.
632: # That allows us given a resource id to know all edges that go to it
633: # and leave from it.
634: #
635:
636: if (defined($hash{'to_'.$comesfrom})) {
637: $hash{'to_'.$comesfrom}.=','.$linkid;
638: } else {
639: $hash{'to_'.$comesfrom}=''.$linkid;
640: }
641: if (defined($hash{'from_'.$goesto})) {
642: $hash{'from_'.$goesto}.=','.$linkid;
643: } else {
644: $hash{'from_'.$goesto}=''.$linkid;
645: }
646: }
647:
648: # ------------------------------------------------------------------- Condition
649: #
650: # Processes <condition> tags, storing sufficient information about them
651: # in the hash so that they can be evaluated and used to conditionalize
652: # what is presented to the student.
653: #
654: # these can have the following attributes
655: #
656: # id = A unique identifier of the condition within the map.
657: #
658: # value = Is a perl script-let that, when evaluated in safe space
659: # determines whether or not the condition is true.
660: # Normally this takes the form of a test on an Apache::lonnet::EXT call
661: # to find the value of variable associated with a resource in the
662: # map identified by a mapalias.
663: # Here's a fragment of XML code that illustrates this:
664: #
665: # <param to="5" value="mainproblem" name="parameter_0_mapalias" type="string" />
666: # <resource src="" id="1" type="start" title="Start" />
667: # <resource src="/res/msu/albertel/b_and_c/p1.problem" id="5" title="p1.problem" />
668: # <condition value="&EXT('user.resource.resource.0.tries','mainproblem')
669: # <2 " id="61" type="stop" />
670: # <link to="5" index="1" from="1" condition="61" />
671: #
672: # In this fragment:
673: # - The param tag establishes an alias to resource id 5 of 'mainproblem'.
674: # - The resource that is the start of the map is identified.
675: # - The resource tag identifies the resource associated with this tag
676: # and gives it the id 5.
677: # - The condition is true if the tries variable associated with mainproblem
678: # is less than 2 (that is the user has had more than 2 tries).
679: # The condition type is a stop condition which inhibits(?) the associated
680: # link if the condition is false.
681: # - The link to resource 5 from resource 1 is affected by this condition.
682: #
683: # type = Type of the condition. The type determines how the condition affects the
684: # link associated with it and is one of
685: # - 'force'
686: # - 'stop'
687: # anything else including not supplied..which treated as:
688: # - 'normal'.
689: # Presumably maps get created by the resource assembly tool and therefore
690: # illegal type values won't squirm their way into the XML.
691: #
692: # Side effects:
693: # - The kind_level-qualified-condition-id hash element is set to 'cond'.
694: # - The condition text is pushed into the cond array and its element number is
695: # set in the condid_level-qualified-condition-id element of the hash.
696: # - The condition type is colon appneded to the cond array element for this condition.
697: sub parse_condition {
698: my ($token,$lpc) = @_;
699: my $rid=$lpc.'.'.$token->[2]->{'id'};
700:
701: $hash{'kind_'.$rid}='cond';
702:
703: my $condition = $token->[2]->{'value'};
704: $condition =~ s/[\n\r]+/ /gs;
705: push(@cond, $condition);
706: $hash{'condid_'.$rid}=$#cond;
707: if ($token->[2]->{'type'}) {
708: $cond[$#cond].=':'.$token->[2]->{'type'};
709: } else {
710: $cond[$#cond].=':normal';
711: }
712: }
713:
714: # ------------------------------------------------------------------- Parameter
715: # Parse a <parameter> tag in the map.
716: # Parmameters:
717: # $token Token array for a start tag from HTML::TokeParser
718: # [0] = 'S'
719: # [1] = tagname ("param")
720: # [2] = Hash of {attribute} = values.
721: # [3] = Array of the keys in [2].
722: # [4] = unused.
723: # $lpc Current map nesting level.a
724: #
725: # Typical attributes:
726: # to=n - Number of the resource the parameter applies to.
727: # type=xx - Type of parameter value (e.g. string_yesno or int_pos).
728: # name=xxx - Name of parameter (e.g. parameter_randompick or parameter_randomorder).
729: # value=xxx - value of the parameter.
730:
731: sub parse_param {
732: my ($token,$lpc) = @_;
733: my $referid=$lpc.'.'.$token->[2]->{'to'}; # Resource param applies to.
734: my $name=$token->[2]->{'name'}; # Name of parameter
735: my $part;
736:
737:
738: if ($name=~/^parameter_(.*)_/) {
739: $part=$1;
740: } else {
741: $part=0;
742: }
743:
744: # Peel the parameter_ off the parameter name.
745:
746: $name=~s/^.*_([^_]*)$/$1/;
747:
748: # The value is:
749: # type.part.name.value
750:
751: my $newparam=
752: &escape($token->[2]->{'type'}).':'.
753: &escape($part.'.'.$name).'='.
754: &escape($token->[2]->{'value'});
755:
756: # The hash key is param_resourceid.
757: # Multiple parameters for a single resource are & separated in the hash.
758:
759:
760: if (defined($hash{'param_'.$referid})) {
761: $hash{'param_'.$referid}.='&'.$newparam;
762: } else {
763: $hash{'param_'.$referid}=''.$newparam;
764: }
765: #
766: # These parameters have to do with randomly selecting
767: # resources, therefore a separate hash is also created to
768: # make it easy to locate them when actually computing the resource set later on
769: # See the code conditionalized by ($randomize) in loadmap().
770:
771: if ($token->[2]->{'name'}=~/^parameter_(0_)*randompick$/) { # Random selection turned on
772: $randompick{$referid}=$token->[2]->{'value'};
773: }
774: if ($token->[2]->{'name'}=~/^parameter_(0_)*randompickseed$/) { # Randomseed provided.
775: $randompickseed{$referid}=$token->[2]->{'value'};
776: }
777: if ($token->[2]->{'name'}=~/^parameter_(0_)*randomorder$/) { # Random order turned on.
778: $randomorder{$referid}=$token->[2]->{'value'};
779: }
780:
781: # These parameters have to do with how the URLs of resources are presented to
782: # course members(?). encrypturl presents encypted url's while
783: # hiddenresource hides the URL.
784: #
785:
786: if ($token->[2]->{'name'}=~/^parameter_(0_)*encrypturl$/) {
787: if ($token->[2]->{'value'}=~/^yes$/i) {
788: $encurl{$referid}=1;
789: }
790: }
791: if ($token->[2]->{'name'}=~/^parameter_(0_)*hiddenresource$/) {
792: if ($token->[2]->{'value'}=~/^yes$/i) {
793: $hiddenurl{$referid}=1;
794: }
795: }
796: }
797: #
798: # Parse mapalias parameters.
799: # these are tags of the form:
800: # <param to="nn"
801: # value="some-alias-for-resourceid-nn"
802: # name="parameter_0_mapalias"
803: # type="string" />
804: # A map alias is a textual name for a resource:
805: # - The to attribute identifies the resource (this gets level qualified below)
806: # - The value attributes provides the alias string.
807: # - name must be of the regexp form: /^parameter_(0_)*mapalias$/
808: # - e.g. the string 'parameter_' followed by 0 or more "0_" strings
809: # terminating with the string 'mapalias'.
810: # Examples:
811: # 'parameter_mapalias', 'parameter_0_mapalias', parameter_0_0_mapalias'
812: # Invalid to ids are silently ignored.
813: #
814: # Parameters:
815: # token - The token array fromthe HMTML::TokeParser
816: # lpc - The current map level counter.
817: #
818: sub parse_mapalias_param {
819: my ($token,$lpc) = @_;
820:
821: # Fully qualify the to value and ignore the alias if there is no
822: # corresponding resource.
823:
824: my $referid=$lpc.'.'.$token->[2]->{'to'};
825: return if (!exists($hash{'src_'.$referid}));
826:
827: # If this is a valid mapalias parameter,
828: # Append the target id to the count_mapalias element for that
829: # alias so that we can detect doubly defined aliases
830: # e.g.:
831: # <param to="1" value="george" name="parameter_0_mapalias" type="string" />
832: # <param to="2" value="george" name="parameter_0_mapalias" type="string" />
833: #
834: # The example above is trivial but the case that's important has to do with
835: # constructing a map that includes a nested map where the nested map may have
836: # aliases that conflict with aliases established in the enclosing map.
837: #
838: # ...and create/update the hash mapalias entry to actually store the alias.
839: #
840:
841: if ($token->[2]->{'name'}=~/^parameter_(0_)*mapalias$/) {
842: &count_mapalias($token->[2]->{'value'},$referid);
843: $hash{'mapalias_'.$token->[2]->{'value'}}=$referid;
844: }
845: }
846:
847: # --------------------------------------------------------- Simplify expression
848:
849:
850: #
851: # Someone should really comment this to describe what it does to what and why.
852: #
853: sub simplify {
854: my $expression=shift;
855: # (0&1) = 1
856: $expression=~s/\(0\&([_\.\d]+)\)/$1/g;
857: # (8)=8
858: $expression=~s/\(([_\.\d]+)\)/$1/g;
859: # 8&8=8
860: $expression=~s/([^_\.\d])([_\.\d]+)\&\2([^_\.\d])/$1$2$3/g;
861: # 8|8=8
862: $expression=~s/([^_\.\d])([_\.\d]+)(?:\|\2)+([^_\.\d])/$1$2$3/g;
863: # (5&3)&4=5&3&4
864: $expression=~s/\(([_\.\d]+)((?:\&[_\.\d]+)+)\)\&([_\.\d]+[^_\.\d])/$1$2\&$3/g;
865: # (((5&3)|(4&6)))=((5&3)|(4&6))
866: $expression=~
867: s/\((\(\([_\.\d]+(?:\&[_\.\d]+)*\)(?:\|\([_\.\d]+(?:\&[_\.\d]+)*\))+\))\)/$1/g;
868: # ((5&3)|(4&6))|(1&2)=(5&3)|(4&6)|(1&2)
869: $expression=~
870: s/\((\([_\.\d]+(?:\&[_\.\d]+)*\))((?:\|\([_\.\d]+(?:\&[_\.\d]+)*\))+)\)\|(\([_\.\d]+(?:\&[_\.\d]+)*\))/\($1$2\|$3\)/g;
871: return $expression;
872: }
873:
874: # -------------------------------------------------------- Build condition hash
875:
876: #
877: # Traces a route recursively through the map after it has been loaded
878: # (I believe this really visits each resourcde that is reachable fromt he
879: # start top node.
880: #
881: # - Marks hidden resources as hidden.
882: # - Marks which resource URL's must be encrypted.
883: # - Figures out (if necessary) the first resource in the map.
884: # - Further builds the chunks of the big hash that define how
885: # conditions work
886: #
887: # Note that the tracing strategy won't visit resources that are not linked to
888: # anything or islands in the map (groups of resources that form a path but are not
889: # linked in to the path that can be traced from the start resource...but that's ok
890: # because by definition, those resources are not reachable by users of the course.
891: #
892: # Parameters:
893: # sofar - _URI of the prior entry or 0 if this is the top.
894: # rid - URI of the resource to visit.
895: # beenhere - list of resources (each resource enclosed by &'s) that have
896: # already been visited.
897: # encflag - If true the resource that resulted in a recursive call to us
898: # has an encoded URL (which means contained resources should too).
899: # hdnflag - If true,the resource that resulted in a recursive call to us
900: # was hidden (which means contained resources should be hidden too).
901: # Returns
902: # new value indicating how far the map has been traversed (the sofar).
903: #
904: sub traceroute {
905: my ($sofar,$rid,$beenhere,$encflag,$hdnflag)=@_;
906: my $newsofar=$sofar=simplify($sofar);
907:
908: unless ($beenhere=~/\&\Q$rid\E\&/) {
909: $beenhere.=$rid.'&';
910: my ($mapid,$resid)=split(/\./,$rid);
911: my $symb=&Apache::lonnet::encode_symb($hash{'map_id_'.$mapid},$resid,$hash{'src_'.$rid});
912: my $hidden=&Apache::lonnet::EXT('resource.0.hiddenresource',$symb);
913:
914: if ($hdnflag || lc($hidden) eq 'yes') {
915: $hiddenurl{$rid}=1;
916: }
917: if (!$hdnflag && lc($hidden) eq 'no') {
918: delete($hiddenurl{$rid});
919: }
920:
921: my $encrypt=&Apache::lonnet::EXT('resource.0.encrypturl',$symb);
922: if ($encflag || lc($encrypt) eq 'yes') { $encurl{$rid}=1; }
923:
924: if (($retfrid eq '') && ($hash{'src_'.$rid})
925: && ($hash{'src_'.$rid}!~/\.sequence$/)) {
926: $retfrid=$rid;
927: }
928:
929: if (defined($hash{'conditions_'.$rid})) {
930: $hash{'conditions_'.$rid}=simplify(
931: '('.$hash{'conditions_'.$rid}.')|('.$sofar.')');
932: } else {
933: $hash{'conditions_'.$rid}=$sofar;
934: }
935:
936: # if the expression is just the 0th condition keep it
937: # otherwise leave a pointer to this condition expression
938:
939: $newsofar = ($sofar eq '0') ? $sofar : '_'.$rid;
940:
941: # Recurse if the resource is a map:
942:
943: if (defined($hash{'is_map_'.$rid})) {
944: if (defined($hash{'map_start_'.$hash{'src_'.$rid}})) {
945: $sofar=$newsofar=
946: &traceroute($sofar,
947: $hash{'map_start_'.$hash{'src_'.$rid}},
948: $beenhere,
949: $encflag || $encurl{$rid},
950: $hdnflag || $hiddenurl{$rid});
951: }
952: }
953:
954: # Processes links to this resource:
955: # - verify the existence of any conditionals on the link to here.
956: # - Recurse to any resources linked to us.
957: #
958: if (defined($hash{'to_'.$rid})) {
959: foreach my $id (split(/\,/,$hash{'to_'.$rid})) {
960: my $further=$sofar;
961: #
962: # If there's a condition associated with this link be sure
963: # it's been defined else that's an error:
964: #
965: if ($hash{'undercond_'.$id}) {
966: if (defined($hash{'condid_'.$hash{'undercond_'.$id}})) {
967: $further=simplify('('.'_'.$rid.')&('.
968: $hash{'condid_'.$hash{'undercond_'.$id}}.')');
969: } else {
970: $errtext.= '<br />'.
971: &mt('Undefined condition ID: [_1]',
972: $hash{'undercond_'.$id});
973: }
974: }
975: # Recurse to resoruces that have to's to us.
976: $newsofar=&traceroute($further,$hash{'goesto_'.$id},$beenhere,
977: $encflag,$hdnflag);
978: }
979: }
980: }
981: return $newsofar;
982: }
983:
984: # ------------------------------ Cascading conditions, quick access, parameters
985:
986: #
987: # Seems a rather strangely named sub given what the comment above says it does.
988:
989:
990: sub accinit {
991: my ($uri,$short,$fn)=@_;
992: my %acchash=();
993: my %captured=();
994: my $condcounter=0;
995: $acchash{'acc.cond.'.$short.'.0'}=0;
996:
997: # This loop is only interested in conditions and
998: # parameters in the big hash:
999:
1000: foreach my $key (keys(%hash)) {
1001:
1002: # conditions:
1003:
1004: if ($key=~/^conditions/) {
1005: my $expr=$hash{$key};
1006:
1007: # try to find and factor out common sub-expressions
1008: # Any subexpression that is found is simplified, removed from
1009: # the original condition expression and the simplified sub-expression
1010: # substituted back in to the epxression..I'm not actually convinced this
1011: # factors anything out...but instead maybe simplifies common factors(?)
1012:
1013: foreach my $sub ($expr=~m/(\(\([_\.\d]+(?:\&[_\.\d]+)+\)(?:\|\([_\.\d]+(?:\&[_\.\d]+)+\))+\))/g) {
1014: my $orig=$sub;
1015:
1016: my ($factor) = ($sub=~/\(\(([_\.\d]+\&(:?[_\.\d]+\&)*)(?:[_\.\d]+\&*)+\)(?:\|\(\1(?:[_\.\d]+\&*)+\))+\)/);
1017: next if (!defined($factor));
1018:
1019: $sub=~s/\Q$factor\E//g;
1020: $sub=~s/^\(/\($factor\(/;
1021: $sub.=')';
1022: $sub=simplify($sub);
1023: $expr=~s/\Q$orig\E/$sub/;
1024: }
1025: $hash{$key}=$expr;
1026:
1027: # If not yet seen, record in acchash and that we've seen it.
1028:
1029: unless (defined($captured{$expr})) {
1030: $condcounter++;
1031: $captured{$expr}=$condcounter;
1032: $acchash{'acc.cond.'.$short.'.'.$condcounter}=$expr;
1033: }
1034: # Parameters:
1035:
1036: } elsif ($key=~/^param_(\d+)\.(\d+)/) {
1037: my $prefix=&Apache::lonnet::encode_symb($hash{'map_id_'.$1},$2,
1038: $hash{'src_'.$1.'.'.$2});
1039: foreach my $param (split(/\&/,$hash{$key})) {
1040: my ($typename,$value)=split(/\=/,$param);
1041: my ($type,$name)=split(/\:/,$typename);
1042: $parmhash{$prefix.'.'.&unescape($name)}=
1043: &unescape($value);
1044: $parmhash{$prefix.'.'.&unescape($name).'.type'}=
1045: &unescape($type);
1046: }
1047: }
1048: }
1049: # This loop only processes id entries in the big hash.
1050:
1051: foreach my $key (keys(%hash)) {
1052: if ($key=~/^ids/) {
1053: foreach my $resid (split(/\,/,$hash{$key})) {
1054: my $uri=$hash{'src_'.$resid};
1055: my ($uripath,$urifile) =
1056: &Apache::lonnet::split_uri_for_cond($uri);
1057: if ($uripath) {
1058: my $uricond='0';
1059: if (defined($hash{'conditions_'.$resid})) {
1060: $uricond=$captured{$hash{'conditions_'.$resid}};
1061: }
1062: if (defined($acchash{'acc.res.'.$short.'.'.$uripath})) {
1063: if ($acchash{'acc.res.'.$short.'.'.$uripath}=~
1064: /(\&\Q$urifile\E\:[^\&]*)/) {
1065: my $replace=$1;
1066: my $regexp=$replace;
1067: #$regexp=~s/\|/\\\|/g;
1068: $acchash{'acc.res.'.$short.'.'.$uripath} =~
1069: s/\Q$regexp\E/$replace\|$uricond/;
1070: } else {
1071: $acchash{'acc.res.'.$short.'.'.$uripath}.=
1072: $urifile.':'.$uricond.'&';
1073: }
1074: } else {
1075: $acchash{'acc.res.'.$short.'.'.$uripath}=
1076: '&'.$urifile.':'.$uricond.'&';
1077: }
1078: }
1079: }
1080: }
1081: }
1082: $acchash{'acc.res.'.$short.'.'}='&:0&';
1083: my $courseuri=$uri;
1084: $courseuri=~s/^\/res\///;
1085: my $regexp = 1;
1086: &Apache::lonnet::delenv('(acc\.|httpref\.)',$regexp);
1087: &Apache::lonnet::appenv(\%acchash);
1088: }
1089:
1090: # ---------------- Selectively delete from randompick maps and hidden url parms
1091:
1092: sub hiddenurls {
1093: my $randomoutentry='';
1094: foreach my $rid (keys(%randompick)) {
1095: my $rndpick=$randompick{$rid};
1096: my $mpc=$hash{'map_pc_'.$hash{'src_'.$rid}};
1097: # ------------------------------------------- put existing resources into array
1098: my @currentrids=();
1099: foreach my $key (sort(keys(%hash))) {
1100: if ($key=~/^src_($mpc\.\d+)/) {
1101: if ($hash{'src_'.$1}) { push @currentrids, $1; }
1102: }
1103: }
1104: # rids are number.number and we want to numercially sort on
1105: # the second number
1106: @currentrids=sort {
1107: my (undef,$aid)=split(/\./,$a);
1108: my (undef,$bid)=split(/\./,$b);
1109: $aid <=> $bid;
1110: } @currentrids;
1111: next if ($#currentrids<$rndpick);
1112: # -------------------------------- randomly eliminate the ones that should stay
1113: my (undef,$id)=split(/\./,$rid);
1114: if ($randompickseed{$rid}) { $id=$randompickseed{$rid}; }
1115: my $setcode;
1116: if (defined($randomizationcode{$rid})) {
1117: if ($env{'form.CODE'} eq '') {
1118: $env{'form.CODE'} = $randomizationcode{$rid};
1119: $setcode = 1;
1120: }
1121: }
1122: my $rndseed=&Apache::lonnet::rndseed($id); # use id instead of symb
1123: if ($setcode) {
1124: undef($env{'form.CODE'});
1125: undef($setcode);
1126: }
1127: &Apache::lonnet::setup_random_from_rndseed($rndseed);
1128: my @whichids=&Math::Random::random_permuted_index($#currentrids+1);
1129: for (my $i=1;$i<=$rndpick;$i++) { $currentrids[$whichids[$i]]=''; }
1130: #&Apache::lonnet::logthis("$id,$rndseed,".join(':',@whichids));
1131: # -------------------------------------------------------- delete the leftovers
1132: for (my $k=0; $k<=$#currentrids; $k++) {
1133: if ($currentrids[$k]) {
1134: $hash{'randomout_'.$currentrids[$k]}=1;
1135: my ($mapid,$resid)=split(/\./,$currentrids[$k]);
1136: if ($rescount{$mapid}) {
1137: $rescount{$mapid} --;
1138: }
1139: if ($hash{'is_map_'.$currentrids[$k]}) {
1140: if ($mapcount{$mapid}) {
1141: $mapcount{$mapid} --;
1142: }
1143: }
1144: $randomoutentry.='&'.
1145: &Apache::lonnet::encode_symb($hash{'map_id_'.$mapid},
1146: $resid,
1147: $hash{'src_'.$currentrids[$k]}
1148: ).'&';
1149: }
1150: }
1151: }
1152: # ------------------------------ take care of explicitly hidden urls or folders
1153: foreach my $rid (keys(%hiddenurl)) {
1154: $hash{'randomout_'.$rid}=1;
1155: my ($mapid,$resid)=split(/\./,$rid);
1156: if ($rescount{$mapid}) {
1157: $rescount{$mapid} --;
1158: }
1159: if ($hash{'is_map_'.$rid}) {
1160: if ($mapcount{$mapid}) {
1161: $mapcount{$mapid} --;
1162: }
1163: }
1164: $randomoutentry.='&'.
1165: &Apache::lonnet::encode_symb($hash{'map_id_'.$mapid},$resid,
1166: $hash{'src_'.$rid}).'&';
1167: }
1168: # --------------------------------------- append randomout entry to environment
1169: if ($randomoutentry) {
1170: &Apache::lonnet::appenv({'acc.randomout' => $randomoutentry});
1171: }
1172: }
1173:
1174: # -------------------------------------- populate big hash with map breadcrumbs
1175:
1176: # Create map_breadcrumbs_$pc from map_hierarchy_$pc by omitting intermediate
1177: # maps not shown in Course Contents table.
1178:
1179: sub mapcrumbs {
1180: foreach my $key (keys(%rescount)) {
1181: if ($hash{'map_hierarchy_'.$key}) {
1182: my $skipnext = 0;
1183: foreach my $id (split(/,/,$hash{'map_hierarchy_'.$key}),$key) {
1184: unless ($skipnext) {
1185: $hash{'map_breadcrumbs_'.$key} .= "$id,";
1186: }
1187: unless (($id == 0) || ($id == 1)) {
1188: if ((!$rescount{$id}) || ($rescount{$id} == 1 && $mapcount{$id} == 1)) {
1189: $skipnext = 1;
1190: } else {
1191: $skipnext = 0;
1192: }
1193: }
1194: }
1195: $hash{'map_breadcrumbs_'.$key} =~ s/,$//;
1196: }
1197: }
1198: }
1199:
1200: # ---------------------------------------------------- Read map and all submaps
1201:
1202: sub readmap {
1203: my ($short,$critmsg_check) = @_;
1204: $short=~s/^\///;
1205:
1206: # TODO: Hidden dependency on current user:
1207:
1208: my %cenv=&Apache::lonnet::coursedescription($short,{'freshen_cache'=>1});
1209:
1210: my $fn=$cenv{'fn'};
1211: my $uri;
1212: $short=~s/\//\_/g;
1213: unless ($uri=$cenv{'url'}) {
1214: &Apache::lonnet::logthis('<font color="blue">WARNING: '.
1215: "Could not load course $short.</font>");
1216: return ('',&mt('No course data available.'));;
1217: }
1218: @cond=('true:normal');
1219:
1220: unless (open(LOCKFILE,">","$fn.db.lock")) {
1221: #
1222: # Most likely a permissions problem on the lockfile or its directory.
1223: #
1224: $retfurl = '';
1225: return ($retfurl,'<br />'.&mt('Map not loaded - Lock file could not be opened when reading map:').' <tt>'.$fn.'</tt>.');
1226: }
1227: my $lock=0;
1228: my $gotstate=0;
1229:
1230: # If we can get the lock without delay any files there are idle
1231: # and from some prior request. We'll kill them off and regenerate them:
1232:
1233: if (flock(LOCKFILE,LOCK_EX|LOCK_NB)) {
1234: $lock=1; # Remember that we hold the lock.
1235: &unlink_tmpfiles($fn);
1236: }
1237: undef %randompick;
1238: undef %randompickseed;
1239: undef %randomorder;
1240: undef %randomizationcode;
1241: undef %hiddenurl;
1242: undef %encurl;
1243: undef %rescount;
1244: undef %mapcount;
1245: $retfrid='';
1246: $errtext='';
1247: my ($untiedhash,$untiedparmhash,$tiedhash,$tiedparmhash); # More state flags.
1248:
1249: # if we got the lock, regenerate course regnerate empty files and tie them.
1250:
1251: if ($lock) {
1252: if (tie(%hash,'GDBM_File',"$fn.db",&GDBM_WRCREAT(),0640)) {
1253: $tiedhash = 1;
1254: if (tie(%parmhash,'GDBM_File',$fn.'_parms.db',&GDBM_WRCREAT(),0640)) {
1255: $tiedparmhash = 1;
1256: $gotstate = &build_tmp_hashes($uri,
1257: $fn,
1258: $short,
1259: \%cenv); # TODO: Need to provide requested user@dom
1260: unless ($gotstate) {
1261: &Apache::lonnet::logthis('Failed to write statemap at first attempt '.$fn.' for '.$uri.'.</font>');
1262: }
1263: $untiedparmhash = untie(%parmhash);
1264: unless ($untiedparmhash) {
1265: &Apache::lonnet::logthis('<font color="blue">WARNING: '.
1266: 'Could not untie coursemap parmhash '.$fn.' for '.$uri.'.</font>');
1267: }
1268: }
1269: $untiedhash = untie(%hash);
1270: unless ($untiedhash) {
1271: &Apache::lonnet::logthis('<font color="blue">WARNING: '.
1272: 'Could not untie coursemap hash '.$fn.' for '.$uri.'.</font>');
1273: }
1274: }
1275: flock(LOCKFILE,LOCK_UN); # RF: this is what I don't get unless there are other
1276: # unlocked places the remainder happens..seems like if we
1277: # just kept the lock here the rest of the code would have
1278: # been much easier?
1279: }
1280: unless ($lock && $tiedhash && $tiedparmhash) {
1281: # if we are here it is likely because we are already trying to
1282: # initialize the course in another child, busy wait trying to
1283: # tie the hashes for the next 90 seconds, if we succeed forward
1284: # them on to navmaps, if we fail, throw up the Could not init
1285: # course screen
1286: #
1287: # RF: I'm not seeing the case where the ties/unties can fail in a way
1288: # that can be remedied by this. Since we owned the lock seems
1289: # Tie/untie failures are a result of something like a permissions problem instead?
1290: #
1291:
1292: # In any vent, undo what we did manage to do above first:
1293: if ($lock) {
1294: # Got the lock but not the DB files
1295: flock(LOCKFILE,LOCK_UN);
1296: $lock = 0;
1297: }
1298: if ($tiedhash) {
1299: unless($untiedhash) {
1300: untie(%hash);
1301: }
1302: }
1303: if ($tiedparmhash) {
1304: unless($untiedparmhash) {
1305: untie(%parmhash);
1306: }
1307: }
1308: # Log our failure:
1309:
1310: &Apache::lonnet::logthis('<font color="blue">WARNING: '.
1311: "Could not tie coursemap $fn for $uri.</font>");
1312: $tiedhash = '';
1313: $tiedparmhash = '';
1314: my $i=0;
1315:
1316: # Keep on retrying the lock for 90 sec until we succeed.
1317:
1318: while($i<90) {
1319: $i++;
1320: sleep(1);
1321: if (flock(LOCKFILE,LOCK_EX|LOCK_NB)) {
1322:
1323: # Got the lock, tie the hashes...the assumption in this code is
1324: # that some other worker thread has created the db files quite recently
1325: # so no load is needed:
1326:
1327: $lock = 1;
1328: if (tie(%hash,'GDBM_File',"$fn.db",&GDBM_READER(),0640)) {
1329: $tiedhash = 1;
1330: if (tie(%parmhash,'GDBM_File',$fn.'_parms.db',&GDBM_READER(),0640)) {
1331: $tiedparmhash = 1;
1332: if (-e "$fn.state") {
1333: $retfurl='/adm/navmaps';
1334:
1335: # BUG BUG: Side effect!
1336: # Should conditionalize on something so that we can use this
1337: # to load maps for courses that are not current?
1338: #
1339: &Apache::lonnet::appenv({"request.course.id" => $short,
1340: "request.course.fn" => $fn,
1341: "request.course.uri" => $uri,
1342: "request.course.tied" => time});
1343:
1344: $untiedhash = untie(%hash);
1345: $untiedparmhash = untie(%parmhash);
1346: $gotstate = 1;
1347: last;
1348: }
1349: $untiedparmhash = untie(%parmhash);
1350: }
1351: $untiedhash = untie(%hash);
1352: }
1353: }
1354: }
1355: if ($lock) {
1356: flock(LOCKFILE,LOCK_UN);
1357: $lock = 0;
1358: if ($tiedparmhash) {
1359: unless ($untiedparmhash) {
1360: &Apache::lonnet::logthis('<font color="blue">WARNING: '.
1361: 'Could not untie coursemap parmhash '.$fn.' for '.$uri.'.</font>');
1362: }
1363: }
1364: if ($tiedparmhash) {
1365: unless ($untiedhash) {
1366: &Apache::lonnet::logthis('<font color="blue">WARNING: '.
1367: 'Could not untie coursemap hash '.$fn.' for '.$uri.'.</font>');
1368: }
1369: }
1370: }
1371: }
1372: # I think this branch of code is all about what happens if we just did the stuff above,
1373: # but found that the state file did not exist...again if we'd just held the lock
1374: # would that have made this logic simpler..as generating all the files would be
1375: # an atomic operation with respect to the lock.
1376: #
1377: unless ($gotstate) {
1378: $lock = 0;
1379: &Apache::lonnet::logthis('<font color="blue">WARNING: '.
1380: 'Could not read statemap '.$fn.' for '.$uri.'.</font>');
1381: &unlink_tmpfiles($fn);
1382: if (flock(LOCKFILE,LOCK_EX|LOCK_NB)) {
1383: $lock=1;
1384: }
1385: undef %randompick;
1386: undef %randompickseed;
1387: undef %randomorder;
1388: undef %randomizationcode;
1389: undef %hiddenurl;
1390: undef %encurl;
1391: undef %rescount;
1392: undef %mapcount;
1393: $errtext='';
1394: $retfrid='';
1395: #
1396: # Once more through the routine of tying and loading and so on.
1397: #
1398: if ($lock) {
1399: if (tie(%hash,'GDBM_File',"$fn.db",&GDBM_WRCREAT(),0640)) {
1400: if (tie(%parmhash,'GDBM_File',$fn.'_parms.db',&GDBM_WRCREAT(),0640)) {
1401: $gotstate = &build_tmp_hashes($uri,$fn,$short,\%cenv); # TODO: User dependent?
1402: unless ($gotstate) {
1403: &Apache::lonnet::logthis('<font color="blue">WARNING: '.
1404: 'Failed to write statemap at second attempt '.$fn.' for '.$uri.'.</font>');
1405: }
1406: unless (untie(%parmhash)) {
1407: &Apache::lonnet::logthis('<font color="blue">WARNING: '.
1408: 'Could not untie coursemap parmhash '.$fn.'.db for '.$uri.'.</font>');
1409: }
1410: } else {
1411: &Apache::lonnet::logthis('<font color="blue">WARNING: '.
1412: 'Could not tie coursemap '.$fn.'__parms.db for '.$uri.'.</font>');
1413: }
1414: unless (untie(%hash)) {
1415: &Apache::lonnet::logthis('<font color="blue">WARNING: '.
1416: 'Could not untie coursemap hash '.$fn.'.db for '.$uri.'.</font>');
1417: }
1418: } else {
1419: &Apache::lonnet::logthis('<font color="blue">WARNING: '.
1420: 'Could not tie coursemap '.$fn.'.db for '.$uri.'.</font>');
1421: }
1422: flock(LOCKFILE,LOCK_UN);
1423: $lock = 0;
1424: } else {
1425: # Failed to get the immediate lock.
1426:
1427: &Apache::lonnet::logthis('<font color="blue">WARNING: '.
1428: 'Could not obtain lock to tie coursemap hash '.$fn.'.db for '.$uri.'.</font>');
1429: }
1430: }
1431: close(LOCKFILE);
1432: unless (($errtext eq '') || ($env{'request.course.uri'} =~ m{^/uploaded/})) {
1433: &Apache::lonmsg::author_res_msg($env{'request.course.uri'},
1434: $errtext); # TODO: User dependent?
1435: }
1436: # ------------------------------------------------- Check for critical messages
1437:
1438: # Depends on user must parameterize this as well..or separate as this is:
1439: # more part of determining what someone sees on entering a course?
1440: # When lonuserstate::readmap() is called from lonroles.pm, i.e.,
1441: # after selecting a role in a course, critical_redirect will be called,
1442: # unless the course has a blocking event in effect, which suppresses
1443: # critical message checking (users without evb priv).
1444: #
1445:
1446: if ($critmsg_check) {
1447: my ($redirect,$url) = &Apache::loncommon::critical_redirect();
1448: if ($redirect) {
1449: $retfurl = $url;
1450: }
1451: }
1452: return ($retfurl,$errtext);
1453: }
1454:
1455: #
1456: # This sub is called when the course hash and the param hash have been tied and
1457: # their lock file is held.
1458: # Parameters:
1459: # $uri - URI that identifies the course.
1460: # $fn - The base path/filename of the files that make up the context
1461: # being built.
1462: # $short - Short course name.
1463: # $cenvref - Reference to the course environment hash returned by
1464: # Apache::lonnet::coursedescription
1465: #
1466: # Assumptions:
1467: # The globals
1468: # %hash, %paramhash are tied to their gdbm files and we hold the lock on them.
1469: #
1470: sub build_tmp_hashes {
1471: my ($uri,$fn,$short,$cenvref) = @_;
1472:
1473: unless(ref($cenvref) eq 'HASH') {
1474: return;
1475: }
1476: my %cenv = %{$cenvref};
1477: my $gotstate = 0;
1478: %hash=(); # empty the global course and parameter hashes.
1479: %parmhash=();
1480: $errtext=''; # No error messages yet.
1481: $pc=0;
1482: &clear_mapalias_count();
1483: &processversionfile(%cenv);
1484:
1485: # URI Of the map file.
1486:
1487: my $furi=&Apache::lonnet::clutter($uri);
1488: #
1489: # the map staring points.
1490: #
1491: $hash{'src_0.0'}=&versiontrack($furi);
1492: $hash{'title_0.0'}=&Apache::lonnet::metadata($uri,'title');
1493: $hash{'ids_'.$furi}='0.0';
1494: $hash{'is_map_0.0'}=1;
1495:
1496: # Load the map.. note that loadmap may implicitly recurse if the map contains
1497: # sub-maps.
1498:
1499:
1500: &loadmap($uri,'0.0',$short);
1501:
1502: # The code below only executes if there is a starting point for the map>
1503: # Q/BUG??? If there is no start resource for the map should that be an error?
1504: #
1505:
1506: if (defined($hash{'map_start_'.$uri})) {
1507: &Apache::lonnet::appenv({"request.course.id" => $short,
1508: "request.course.fn" => $fn,
1509: "request.course.uri" => $uri,
1510: "request.course.tied" => time});
1511: $env{'request.course.id'}=$short;
1512: &traceroute('0',$hash{'map_start_'.$uri},'&');
1513: &accinit($uri,$short,$fn);
1514: &hiddenurls();
1515: &mapcrumbs();
1516: }
1517: $errtext .= &get_mapalias_errors();
1518: # ------------------------------------------------------- Put versions into src
1519: foreach my $key (keys(%hash)) {
1520: if ($key=~/^src_/) {
1521: $hash{$key}=&putinversion($hash{$key});
1522: } elsif ($key =~ /^(map_(?:start|finish|pc)_)(.*)/) {
1523: my ($type, $url) = ($1,$2);
1524: my $value = $hash{$key};
1525: $hash{$type.&putinversion($url)}=$value;
1526: }
1527: }
1528: # ---------------------------------------------------------------- Encrypt URLs
1529: foreach my $id (keys(%encurl)) {
1530: # $hash{'src_'.$id}=&Apache::lonenc::encrypted($hash{'src_'.$id});
1531: $hash{'encrypted_'.$id}=1;
1532: }
1533: # ----------------------------------------------- Close hashes to finally store
1534: # --------------------------------- Routine must pass this point, no early outs
1535: $hash{'first_rid'}=$retfrid;
1536: my ($mapid,$resid)=split(/\./,$retfrid);
1537: $hash{'first_mapurl'}=$hash{'map_id_'.$mapid};
1538: my $symb=&Apache::lonnet::encode_symb($hash{'map_id_'.$mapid},$resid,$hash{'src_'.$retfrid});
1539: $retfurl=&add_get_param($hash{'src_'.$retfrid},{ 'symb' => $symb });
1540: if ($hash{'encrypted_'.$retfrid}) {
1541: $retfurl=&Apache::lonenc::encrypted($retfurl,(&Apache::lonnet::allowed('adv') ne 'F'));
1542: }
1543: $hash{'first_url'}=$retfurl;
1544: # ---------------------------------------------------- Store away initial state
1545: {
1546: my $cfh;
1547: if (open($cfh,">","$fn.state")) {
1548: print $cfh join("\n",@cond);
1549: $gotstate = 1;
1550: } else {
1551: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
1552: "Could not write statemap $fn for $uri.</font>");
1553: }
1554: }
1555: return $gotstate;
1556: }
1557:
1558: sub unlink_tmpfiles {
1559: my ($fn) = @_;
1560: my $file_dir = dirname($fn);
1561:
1562: if ("$file_dir/" eq LONCAPA::tempdir()) {
1563: my @files = qw (.db _symb.db .state _parms.db);
1564: foreach my $file (@files) {
1565: if (-e $fn.$file) {
1566: unless (unlink($fn.$file)) {
1567: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
1568: "Could not unlink ".$fn.$file."</font>");
1569: }
1570: }
1571: }
1572: }
1573: return;
1574: }
1575:
1576: # ------------------------------------------------------- Evaluate state string
1577:
1578: sub evalstate {
1579: my $fn=$env{'request.course.fn'}.'.state';
1580: my $state='';
1581: if (-e $fn) {
1582: my @conditions=();
1583: {
1584: open(my $fh,"<",$fn);
1585: @conditions=<$fh>;
1586: close($fh);
1587: }
1588: my $safeeval = new Safe;
1589: my $safehole = new Safe::Hole;
1590: $safeeval->permit("entereval");
1591: $safeeval->permit(":base_math");
1592: $safeeval->deny(":base_io");
1593: $safehole->wrap(\&Apache::lonnet::EXT,$safeeval,'&EXT');
1594: foreach my $line (@conditions) {
1595: chomp($line);
1596: my ($condition,$weight)=split(/\:/,$line);
1597: if ($safeeval->reval($condition)) {
1598: if ($weight eq 'force') {
1599: $state.='3';
1600: } else {
1601: $state.='2';
1602: }
1603: } else {
1604: if ($weight eq 'stop') {
1605: $state.='0';
1606: } else {
1607: $state.='1';
1608: }
1609: }
1610: }
1611: }
1612: &Apache::lonnet::appenv({'user.state.'.$env{'request.course.id'} => $state});
1613: return $state;
1614: }
1615:
1616: # This block seems to have code to manage/detect doubly defined
1617: # aliases in maps.
1618:
1619: {
1620: my %mapalias_cache;
1621: sub count_mapalias {
1622: my ($value,$resid) = @_;
1623: push(@{ $mapalias_cache{$value} }, $resid);
1624: }
1625:
1626: sub get_mapalias_errors {
1627: my $error_text;
1628: foreach my $mapalias (sort(keys(%mapalias_cache))) {
1629: next if (scalar(@{ $mapalias_cache{$mapalias} } ) == 1);
1630: my $count;
1631: my $which =
1632: join('</li><li>',
1633: map {
1634: my $id = $_;
1635: if (exists($hash{'src_'.$id})) {
1636: $count++;
1637: }
1638: my ($mapid) = split(/\./,$id);
1639: &mt('Resource [_1][_2]in Map [_3]',
1640: $hash{'title_'.$id},'<br />',
1641: $hash{'title_'.$hash{'ids_'.$hash{'map_id_'.$mapid}}});
1642: } (@{ $mapalias_cache{$mapalias} }));
1643: next if ($count < 2);
1644: $error_text .= '<div class="LC_error">'.
1645: &mt('Error: Found the mapalias "[_1]" defined multiple times.',
1646: $mapalias).
1647: '</div><ul><li>'.$which.'</li></ul>';
1648: }
1649: &clear_mapalias_count();
1650: return $error_text;
1651: }
1652: sub clear_mapalias_count {
1653: undef(%mapalias_cache);
1654: }
1655: }
1656: 1;
1657: __END__
1658:
1659: =head1 NAME
1660:
1661: Apache::lonuserstate - Construct and maintain state and binary representation
1662: of course for user
1663:
1664: =head1 SYNOPSIS
1665:
1666: Invoked by lonroles.pm.
1667:
1668: &Apache::lonuserstate::readmap($cdom.'/'.$cnum);
1669:
1670: =head1 INTRODUCTION
1671:
1672: This module constructs and maintains state and binary representation
1673: of course for user.
1674:
1675: This is part of the LearningOnline Network with CAPA project
1676: described at http://www.lon-capa.org.
1677:
1678: =head1 SUBROUTINES
1679:
1680: =over
1681:
1682: =item loadmap()
1683:
1684: Loads map from disk
1685:
1686: =item simplify()
1687:
1688: Simplify expression
1689:
1690: =item traceroute()
1691:
1692: Build condition hash
1693:
1694: =item accinit()
1695:
1696: Cascading conditions, quick access, parameters
1697:
1698: =item readmap()
1699:
1700: Read map and all submaps
1701:
1702: =item evalstate()
1703:
1704: Evaluate state string
1705:
1706: =back
1707:
1708: =cut
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>