Return to lonwrapper.pm CVS log

Up to [LON-CAPA] / rat

- Update POD.

# The LearningOnline Network with CAPA
# Wrapper for external and binary files as standalone resources
#
# $Id: lonwrapper.pm,v 1.86 2023/12/31 21:45:03 raeburn Exp $
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#


package Apache::lonwrapper;

use strict;
use Apache::Constants qw(:common);
use Apache::lonenc();
use Apache::lonnet;
use Apache::lonlocal;
use Apache::loncommon();
use Apache::lonhtmlcommon();
use Apache::lonextresedit();
use Apache::lonexttool();
use Apache::lonhomework();
use Apache::lonnavmaps();
use LONCAPA qw(:DEFAULT :match);
use HTML::Entities();
use Digest::MD5();

# ================================================================ Main Handler
sub wrapper {
    my ($r,$url,$brcrum,$absolute,$is_ext,$is_pdf,$exttool,$linktext,$explanation,
        $title,$width,$height,$reuse,$is_supp) = @_;

    my $forcereg;
    unless ($env{'form.folderpath'}) {
        $forcereg = 1;
    }
    my %lt = &Apache::lonlocal::texthash(
                                          'noif' => 'No iframe support.',
                                          'show' => 'Show content in pop-up window',
                                        );

    (undef,undef,undef,undef,undef,undef,my $clientmobile) =
        &Apache::loncommon::decode_user_agent($r);

    my ($anchor,$uselink);
    if ($is_ext) {
        if ($env{'form.symb'}) {
            (undef,undef,my $res) = &Apache::lonnet::decode_symb($env{'form.symb'});
            if ($res =~ /(#[^#]+)$/) {
                $anchor = $1;
            }
        } elsif ($env{'form.anchor'} ne '') {
            $anchor = '#'.$env{'form.anchor'};
        }
        if (($is_ext eq 'tab') || ($is_ext eq 'window')) {
            $uselink = 1;
        }
        unless (($is_pdf && $clientmobile) || $uselink) {
            my $hostname = $r->hostname();
            my $lonhost = $r->dir_config('lonHostID');
            my $ip = &Apache::lonnet::get_host_ip($lonhost);
            $uselink = &Apache::loncommon::is_nonframeable($url,$absolute,$hostname,$ip);
        }
    }

    my $noiframe = &Apache::loncommon::modal_link(&HTML::Entities::encode($url.$anchor,'&<>"\''),$lt{'show'},500,400);
    my $args = {'bgcolor' => '#FFFFFF'};
    if ($forcereg) {
        $args->{'force_register'} = $forcereg;
    }
    if (ref($brcrum) eq 'ARRAY') {
        $args->{'bread_crumbs'} = $brcrum;
    }
    if ($absolute) {
        $args->{'use_absolute'} = $absolute;
    }
    if ($env{'form.only_body'}) {
        $args->{'only_body'} = $env{'form.only_body'};
    } elsif (($is_supp) && ($env{'form.folderpath'} ne '')) {
        $args->{'bread_crumbs_nomenu'} = 1;
    }

    my ($countdown,$donemsg,$headjs);
    if (($exttool) && (&Apache::lonnet::EXT('resource.0.gradable') =~ /^yes$/i)) {
        $Apache::lonhomework::browse = &Apache::lonnet::allowed('bre',$url);
        if ($env{'form.markaccess'}) {
            my $symb=&Apache::lonnet::symbread($url);
            my @interval=&Apache::lonnet::EXT('resource.0.interval',$symb);
            my ($timelimit) = split(/_/,$interval[0]);
            my $setres = &Apache::lonnet::set_first_access($interval[1],$timelimit);
            if ($setres eq 'ok') {
                delete($env{'form.markaccess'});
            }
        } elsif ($env{'form.LC_interval_done'} eq 'true') {
            my $symb=&Apache::lonnet::symbread($url);
            if ($symb) {
                (my $donebuttonresult,$donemsg) = &Apache::lonhomework::zero_timer($symb);
                undef($env{'form.LC_interval_done'});
                undef($env{'form.LC_interval_done_proctorpass'});
            }
        }
        my ($status,$result,$resource_due) =
            &Apache::lonexttool::gradabletool_access_check();
        undef($Apache::lonhomework::browse);
        if ($status eq 'CAN_ANSWER') {
            if ($resource_due) {
                my $time_left = $resource_due - time();
                if ($resource_due && ($time_left > 0)) {
                    $countdown ='
<script type="text/javascript">
// <![CDATA['."\n".
                             &Apache::lonhtmlcommon::countdown().'
// ]]>
</script>'."\n".
                    &Apache::lonhtmlcommon::set_due_date($resource_due);
                }
            }
        } else {
            if ($status eq 'SHOW_ANSWER') {
                $result = &Apache::lonexttool::display_score().
                          &Apache::lonfeedback::list_discussion('tool','OPEN');
            }
            return &Apache::loncommon::start_page('Menu',undef,$args).
                   $result.
                   &Apache::loncommon::end_page();
        }
    }

#
# Where iframe is in use, if window.onload() executes before the custom resize function
# has been defined (jQuery), two global javascript vars (LCnotready and LCresizedef)
# are used to ensure document.ready() triggers a call to resize, so the iframe contents
# do not obscure the Functions menu.
#

    unless ($clientmobile || ($exttool eq 'window') || ($exttool eq 'tab') || $uselink) {
        $headjs = &Apache::loncommon::iframe_wrapper_headjs();
    }

    my $startpage = &Apache::loncommon::start_page('Menu',$headjs,$args).$countdown.$donemsg;
    my $endpage = &Apache::loncommon::end_page();

    if (($uselink) && ($title eq '')) {
        if ($env{'form.symb'}) {
            $title=&Apache::lonnet::gettitle($env{'form.symb'});
        } elsif (!$is_supp) {
            my $symb=&Apache::lonnet::symbread($r->uri);
            if ($symb) {
                $title=&Apache::lonnet::gettitle($symb);
            }
        }
    }
    if ($clientmobile || ($exttool eq 'window') || ($exttool eq 'tab') ||
        ($is_ext eq 'tab') || ($is_ext eq 'window')) {
        my $output = $startpage;
        if ($is_pdf) {
            $linktext = &mt('Link to PDF (for mobile devices)');
            $output .= &create_link($url,$anchor,$title,$linktext);
        } elsif (($exttool eq 'window') || ($exttool eq 'tab') ||
                 ($is_ext eq 'tab') || ($is_ext eq 'window')) {
            my $preamble;
            if ($linktext eq '') {
                if ($exttool) {
                    $linktext = &mt('Launch External Tool');
                } else {
                    $linktext = &mt('Link to External Resource');
                }
            }
            if ($exttool) {
                $url = &HTML::Entities::encode($url,'"<>&');
            } else {
                $url = &HTML::Entities::encode($url.$anchor,'&<>"');
            }
            if (($exttool eq 'tab') || ($is_ext eq 'tab')) {
                my $target;
                if ($exttool) {
                    $target = 'LCExternalToolTab';
                } else {
                    if ($reuse) {
                        $target = 'LCExternalResTab';
                    } else {
                        $target = '_blank';
                    }
                    if ($title ne '') {
                        $preamble = '<span style="font-weight:bold;">'.$title.'</span><br />';
                    }
                }
                $output .= '<div>'.$preamble.
                           '<a href="'.$url.'" target="'.$target.'" style="padding:0;clear:both;margin:0;border:0">'.
                           $linktext.'</a>'.
                           '</div>';
            } else {
                my ($target,$extlinkimg);
                if ($exttool) {
                    $target = 'LCExternalToolPopUp';
                } else {
                    $target = 'LCExternalResPopUp';
                    if ($title ne '') {
                        $preamble = '<span style="font-weight:bold;">'.$title.'</span><br />';
                    }
                    $extlinkimg = '<img src="'.&Apache::loncommon::lonhttpdurl($r->dir_config('lonIconsURL').'/externallink.gif').'" width="19" height="18" border="0" />';
                    unless ($reuse) {
                        my $resid;
                        if ($env{'request.course.id'}) {
                            unless (($is_supp) || ($env{'form.folderpath'} =~ /^supplemental/)) {
                                my $symb=&Apache::lonnet::symbread($r->uri);
                                if ($symb) {
                                    my $navmap = Apache::lonnavmaps::navmap->new();
                                    if (ref($navmap)) {
                                        my $res = $navmap->getBySymb($symb);
                                        if (ref($res)) {
                                            $resid = $res->id;
                                            $resid =~ s/\./_/g;
                                        }
                                    }
                                }
                            }
                        }
                        if ($resid eq '') {
                            $resid = substr(Digest::MD5::md5_hex(Digest::MD5::md5_hex(time(). {}. rand(). $$)), 0, 8);
                        }
                        &js_escape(\$resid);
                        $target .= $resid;
                    }
                }
                $output .= <<"ENDLINK";
<script type="text/javascript">
// <![CDATA[
var windowObjectReference = null;
var PreviousUrl;

function openSinglePopup(strUrl) {
    if (windowObjectReference == null || windowObjectReference.closed) {
        windowObjectReference = window.open(strUrl, "$target",
                                            "height=$height,width=$width,scrollbars=yes,resizable=yes,status=yes,menubar=no,location=no'");
    } else if(PreviousUrl != strUrl) {
        windowObjectReference = window.open(strUrl, "$target",
                                            "height=$height,width=$width,scrollbars=yes,resizable=yes,status=yes,menubar=no,location=no'");
        windowObjectReference.focus();
    } else {
        windowObjectReference.focus();
    };
    PreviousUrl = strUrl;
}
// ]]>
</script>
<div>$preamble
<a href="$url" target="$target" onclick="openSinglePopup(this.href); return false;">
$linktext$extlinkimg</a>
</div>
ENDLINK
            }
            if ($exttool) {
                if ($explanation ne '') {
                    $output .= '<div>'.$explanation.'</div>';
                }
                if (&Apache::lonnet::EXT('resource.0.gradable')) {
                    $output .= &Apache::lonfeedback::list_discussion('tool','OPEN');
                }
            }
        } else {
            if ($uselink) {
                $linktext = &mt('Link to resource');
                $output .= &create_link($url,$anchor,$title,$linktext);
            } else {
                my $dest = &HTML::Entities::encode($url.$anchor,'&<>"');
                $output .= '<div style="overflow:scroll; -webkit-overflow-scrolling:touch;">'."\n".
                           '<iframe src="'.$dest.'" height="100%" width="100%" frameborder="0">'."\n".
                           "$lt{'noif'} $noiframe\n".
                           "</iframe>\n".
                           "</div>\n";
            }
        }
        $output .= $endpage;
        return $output;
    } elsif ($uselink) {
        $linktext = &mt('Link to resource');
        return $startpage.&create_link($url,$anchor,$title,$linktext).$endpage;
    } else {
        # javascript will position the iframe if window was resized (or zoomed)
        my $script = &Apache::loncommon::iframe_wrapper_resizejs();
        my $dest = &HTML::Entities::encode($url.$anchor,'&<>"');
        return <<ENDFRAME;
        $startpage
        $script
        <div class="LC_iframecontainer">
            <iframe src="$dest">$lt{'noif'} $noiframe</iframe>
        </div>
        $endpage
ENDFRAME
    }
}

sub create_link {
    my ($url,$anchor,$title,$linktext) = @_;
    my $shownlink;
    if ($title eq '') {
        $title = $env{'form.title'};
        if ($title eq '') {
            unless ($env{'request.enc'}) {
                ($title) = ($url =~ m{/([^/]+)$});
                $title =~ s/(\?[^\?]+)$//;
            }
        }
    }
    unless ($title eq '') {
        $shownlink = '<span style="font-weight:bold;">'.$title.'</span><br />';
    }
    my $dest = &HTML::Entities::encode($url.$anchor,'&<>"');
    $shownlink .= '<a href="'.$dest.'">'.$linktext.'</a>';
    return $shownlink;
}

sub handler {
    my $r=shift;
    &Apache::loncommon::content_type($r,'text/html');
    $r->send_http_header;

    return OK if $r->header_only;

    my $url = $r->uri;
    my ($is_ext,$brcrum,$absolute,$is_pdf,$exttool,$cdom,$cnum,$hostname,
        $linktext,$explanation,$width,$height,$reuse,$is_supp);

    for ($url){
        s|^/adm/wrapper||;
        $is_ext = $_ =~ s|^/ext/|http://|;
        s|http://https://|https://| if ($is_ext);
        s|&colon;|:|g;
    }

    if ($url =~ /\.pdf$/i) {
        $is_pdf = 1;
    } elsif (($is_ext) && ($env{'request.course.id'})) {
        if ($env{'course.'.$env{'request.course.id'}.'.extresource'}) {
            (my $selected,$reuse,$width,$height) = split(/:/,$env{'course.'.$env{'request.course.id'}.'.extresource'});
            if ($selected eq 'tab') {
                $is_ext = 'tab';
                $width = '';
                $height = '';
            } elsif ($selected eq 'window') {
                $is_ext = 'window';
                unless ($width =~ /^\d+$/) {
                    $width = '';
                }
                unless ($height =~ /^\d+$/) {
                    $height = '';
                }
            } else {
                $width = '';
                $height = '';
                $reuse = '';
            }
        }
    } elsif ($url =~ m{^/adm/($match_domain)/($match_courseid)/(\d+)/ext\.tool$}) {
        $cdom = $1;
        $cnum = $2;
        my $marker = $3;
        $exttool = 'iframe';
        my $exttoolremote;
        my %toolhash = &Apache::lonnet::get('exttool_'.$marker,['target','linktext','explanation','id','width','height'],
                                            $cdom,$cnum);
        if ($toolhash{'id'}) {
            my ($idx,%ltitools);
            if ($toolhash{'id'} =~ /^c(\d+)$/) {
                $idx = $1;
                %ltitools = &Apache::lonnet::get_course_lti($cnum,$cdom,'consumer');
            } else {
                $idx = $toolhash{'id'};
                %ltitools = &Apache::lonnet::get_domain_lti($cdom,'consumer');
            }
            if (ref($ltitools{$idx}) eq 'HASH') {
                $exttoolremote = $ltitools{$idx}{'url'};
            }
        }
        if ($toolhash{'target'} eq 'window') {
            $exttool = 'window';
            $width = $toolhash{'width'};
            $height = $toolhash{'height'};
        } elsif ($toolhash{'target'} eq 'tab') {
            $exttool = 'tab';
        }
        if (($exttool eq 'window') || ($exttool eq 'tab')) {
            $linktext = $toolhash{'linktext'};
            $explanation = $toolhash{'explanation'};
        } elsif (($exttoolremote =~ /^http:/) && ($ENV{'SERVER_PORT'} == 443)) {
            $exttool = 'tab';
        }
    }
    if (($is_ext) || ($exttool)) {
        &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},
            ['forceedit','register','folderpath','symb','idx','title','anchor','only_body']);
        if (($env{'form.forceedit'}) &&
            (&Apache::lonnet::allowed('mdc',$env{'request.course.id'})) &&
            (($env{'form.folderpath'} =~ /^supplemental/) ||
             ($env{'form.symb'} =~ /^uploaded/))) {
            if ($env{'form.symb'}) {
                (undef,undef,my $res) = &Apache::lonnet::decode_symb($env{'form.symb'});
                if ($res =~ /(#[^#]+)$/) {
                    $url .= $1;
                }
            } elsif ($env{'form.folderpath'} =~ /^supplemental/) {
                if ($env{'form.anchor'} ne '') {
                    $url .= '#'.$env{'form.anchor'};
                }
                $is_supp = 1;
            }
            my $type = 'ext';
            if ($exttool) {
                $type = 'tool';
            } elsif (($url =~ /^http:/) && ($ENV{'SERVER_PORT'} == 443)) {
                $hostname = $r->hostname();
            }
            $r->print(
                &Apache::lonextresedit::display_editor($url,$env{'form.folderpath'},
                                                       $env{'form.symb'},
                                                       $env{'form.idx'},$type,$cdom,
                                                       $cnum,$hostname));
            return OK;
        } elsif ($env{'form.folderpath'} =~ /^supplemental/) {
            my $crstype = &Apache::loncommon::course_type();
            my $title = $env{'form.title'};
            if ($title eq '') {
                if ($is_ext) {
                    $title = &mt('External Resource');
                } else {
                    $title = &mt('External Tool');
                }
            }
            $title = &HTML::Entities::encode($title,'\'"<>&');
            $is_supp = 1;
            if ($env{'request.course.id'}) {
                $cnum = $env{'course.'.$env{'request.course.id'}.'.num'};
                $cdom = $env{'course.'.$env{'request.course.id'}.'.domain'};
                &Apache::loncommon::validate_folderpath(1,'',$cnum,$cdom);
            }
            unless ($env{'form.only_body'}) {
                $brcrum =
                    &Apache::lonhtmlcommon::docs_breadcrumbs(undef,$crstype,undef,$title,1);
            }
        }
    } elsif ($env{'request.course.id'}) {
        my $courseurl = &Apache::lonnet::courseid_to_courseurl($env{'request.course.id'});
        $courseurl =~ s{^/}{};
        if ($url =~ m{^\Q/uploaded/$courseurl/supplemental/\E}) {
            $is_supp = 1;
            &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},
                                                    ['folderpath','title','only_body']);
            if ($env{'form.folderpath'}) {
                $cnum = $env{'course.'.$env{'request.course.id'}.'.num'};
                $cdom = $env{'course.'.$env{'request.course.id'}.'.domain'};
                &Apache::loncommon::validate_folderpath(1,'',$cnum,$cdom);
            }
            my $title = $env{'form.title'};
            $title = &HTML::Entities::encode($title,'\'"<>&');
            my $crstype = &Apache::loncommon::course_type();
            unless ($env{'form.only_body'}) {
                $brcrum =
                    &Apache::lonhtmlcommon::docs_breadcrumbs(undef,$crstype,undef,$title,1);
            }
        }
    }

#
# Actual URL
#
    if (($url=~/$LONCAPA::assess_re/) && (!$exttool)) {
#
# This is uploaded homework
#
        $env{'request.state'}='uploaded';
        &Apache::lonhomework::renderpage($r,$url);
    } else {
#
# This is not homework
#
        if (($is_ext) || ($exttool)) {
            $absolute = $env{'request.use_absolute'};
            $ENV{'QUERY_STRING'} =~ s/(^|\&)symb=[^\&]*/$1/;
            $ENV{'QUERY_STRING'} =~ s/\&$//;
        }

        unless ($ENV{'QUERY_STRING'} eq '') {
            $url.=(($url=~/\?/)?'&':'?').$ENV{'QUERY_STRING'};
        }

        # encrypt url if not external
        unless ($is_ext) {
            &Apache::lonenc::check_encrypt(\$url);
        }

        $r->print( wrapper($r,$url,$brcrum,$absolute,$is_ext,$is_pdf,$exttool,
                           $linktext,$explanation,undef,$width,$height,$reuse,
                           $is_supp) );

    } # not just the menu
    
    return OK;
} # handler

1;
__END__

=pod

=head1 NAME

Apache::lonwrapper - External and binary file management.

=head1 SYNOPSIS

Wrapper for external and binary files as standalone resources. Edit handler for rat maps; TeX content handler.

This is part of the LearningOnline Network with CAPA project
described at http://www.lon-capa.org.

=head1 Subroutines

=over

=item wrapper()

Args: $r,$url,$brcrum,$absolute,$is_ext,$is_pdf,$exttool,$linktext,$explanation,$title,$width,$height,$reuse,$is_supp

=over

=item $r

request object

=item $url

url to display either by including in an iframe within a
LON-CAPA page which has a standard LON-CAPA inline menu,
or in some cases launched in a separate tab or window,
launched via a link in a LON-CAPA page with standard inline
menu.

=item $brcrum

breadcrumbs for unregistered urls
(i.e., external resources in Supplemental Content).

=item $absolute

contains protocol (http or https) followed by
the hostname, if menu items in the standard LON-CAPA
interface created by the call to loncommon::start_page()
within &wrapper() need to use absolute URLs rather than
relative URLs.

That will be the case where an external resource has been 
served from port 80, when the server customarily serves
requests using Apache/SSL (i.e., port 443). mod_rewrite 
is used to switch requests for external resources and
the syllabus: /public/<domain>/<courseid>/syllabus
(which might also point at an external resource)
from https:// to http:// where the the URL of the remote site 
specified in the resource itself is http://.

This is done to avoid default mixed content blocking
in Firefox 23 and later, when serving from Apache/SSL.

=item $is_ext

true if URL is for an external resource. Default true value
is 1 (display in iframe, unless $uselink is true).
If external resource is to be displayed in a tab,
value of $is_ext will be tab, if to be displayed in a pop-up window,
value of $is_ext will be window.

=item $is_pdf

true if URL is for a PDF (based on file extension).

=item $exttool

If URL is for an External Tool, will contain the target type: iframe, window or tab.

=item $linktext

optional. If URL is for an External Tool, and target type is window or tab,
then the link text may be an option set in the course for each tool instance,
or may be a default defined in the domain for all instances of the tool.

=item $explanation

optional. If URL is for an External Tool, and target type is window or tab,
then the explanation is an option set in the course for each tool instance,
or may be a default defined in the domain for all instances of the tool.

=item $title

optional. If wrapped item is a PDF, and $clientmobile is true,
a link to a PDF is shown. The "title" will be displayed
above the link, but if not provided as an arg, $env{'form.title'}
will be used, otherwise, the filename will be displayed (unless
hidden URL set for the resource).

=item $width

optional. If URL is for an External Tool, and target type is window,
then a default width may have been defined in the domain for all instances of
the tool.  If so, that width will be used for the window opened (via a link)
to launch the external tool. If the URL is for an External Resource, and
$is_ext is window, then a default width (px) may have been defined in the current
course for all external resource instances.

=item $height

optional. If URL is for an External Tool, and target type is window,
then a default height may have been defined in the domain for all instances of
the tool.  If so, that height will be used for the window opened (via a link)
to launch the external tool.  If the URL is for an External Resource, and
$is_ext is window, then a default height (px) may have been defined in the current
course for all external resource instances.

=item $reuse

optional. If the URL is for an External Resource, and $is_ext is tab or window,
then $reuse will be true if the same tab or window is to be reused for display
of all external resource instances in a a course.

=back

Returns markup for the entire page.

=item create_link()

Args: $url,$anchor,$title,$linktext

=over

=item $url

URL to link to

=item $anchor

optional.  Will be the anchor to append to the URL, if there is one.

=item $title

optional. If provided will be the title displayed above the link. If
one is not provided, then $env{'form.title'} will be used, unless empty.

=item $linktext

The text to inlcude between the <a href="$url"> and </a> tags.

=back

Returns HTML needed to show a link which can be followed to display the
part of the original URL following the initial /adm/wrapper part 
in the original request, in the case where an iframe is not going to be
used to embed the content available at the URL in the existing page.

=item handler()

Content handler for requests for: /adm/wrapper/...
used for content to be displayed in an iframe, or launched in a separate tab
or window via a link.  The target URL is extracted from the requested URL, by
removing the /adm/wrapper prefix.

The target URL will typically be a PDF served from the current server, an
external resource URL served from a different server, or an external tool
(from an LTI Provider) launched from LON-CAPA (as LTI Consumer) and launched
via a link.

If the request included forceedit in the query string, and the requester has
rights to modify course content, then the editor will be displayed to allow
changes to be made to the resource (e.g., change the URL of the external resource,
or change the setting for the external tool instance).

If not in edit mode, then the wrapper() subroutine will be called to generate the
standard LON-CAPA inline menu, and then either a link to launch a separate tab or
window, or an iframe to display the content inline.

=back

=cut