#!/usr/bin/perl
# The LearningOnline Network 
# Pre-installation script for LON-CAPA
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# http://www.lon-capa.org/
#

use strict;
use File::Copy;
use Term::ReadKey;
use DBI;
use File::Spec;
use Cwd();
use File::Basename();
use lib File::Basename::dirname(Cwd::abs_path($0));
use LCLocalization::localize;

# ========================================================= The language handle

my %languages = (
                  ar => 'Arabic', 
                  de => 'German',
                  en => 'English',
                  es => 'Spanish (Castellan)',
                  fa => 'Persian',
                  fr => 'French', 
                  he => 'Hebrew', 
                  ja => 'Japanese',
                  pt => 'Portuguese',
                  ru => 'Russian',
                  tr => 'Turkish',
                  zh => 'Chinese Simplified'
               ); 

use vars qw($lh $lang);
$lang = 'en';
if (@ARGV > 0) {
    foreach my $poss (keys(%languages)) {
        if ($ARGV[0] eq $poss) {
            $lang = $ARGV[0]; 
        }
    }
}

&get_language_handle($lang);

# Check user has root privs
if (0 != $<) {
    print &mt('This script must be run as root.')."\n".
          &mt('Stopping execution.')."\n";
    exit;
}


# Globals: filehandle LOG is global.
if (!open(LOG,">>loncapa_install.log")) {
    print &mt('Unable to open log file.')."\n".
          &mt('Stopping execution.')."\n";
    exit;
} else {
    print LOG '$Id: install.pl,v 1.45.2.14 2021/03/28 22:00:27 raeburn Exp $'."\n";
}

#
# Helper routines and routines to establish recommended actions
#

sub get_language_handle {
    my @languages = @_;
    $lh=LCLocalization::localize->get_handle(@languages);
}

sub mt (@) {
    if ($lh) {
        if ($_[0] eq '') {
            if (wantarray) {
                return @_;
            } else {
                return $_[0];
            }
        } else {
            return $lh->maketext(@_);
        }
    } else {
        if (wantarray) {
            return @_;
        } else {
            return $_[0];
        }
    }
}

sub texthash {
    my (%hash) = @_;
    foreach (keys(%hash)) {
        $hash{$_}=&mt($hash{$_});
    }
    return %hash;
}


sub skip_if_nonempty {
    my ($string,$error)=@_;
    return if (! defined($error));
    chomp($string);chomp($error);
    if ($string ne '') {
        print_and_log("$error\n".&mt('Stopping execution.')."\n");
        return 1;
    }
    return;
}

sub writelog {
    while ($_ = shift) {
        chomp();
        print LOG "$_\n";
    }
}

sub print_and_log {
    while ($_=shift) {
        chomp();
        print "$_\n";
        print LOG "$_\n";
    }
}

sub get_user_selection {
    my ($defaultrun) = @_;
    my $do_action = 0;
    my $choice = <STDIN>;
    chomp($choice);
    $choice =~ s/(^\s+|\s+$)//g;
    my $yes = &mt('y');
    if ($defaultrun) {
        if (($choice eq '') || ($choice =~ /^\Q$yes\E/i)) {
            $do_action = 1;
        }
    } else {
        if ($choice =~ /^\Q$yes\E/i) {
            $do_action = 1;
        }
    }
    return $do_action;
}

sub get_distro {
    my ($distro,$gotprereqs,$updatecmd,$packagecmd,$installnow,$unknown);
    $packagecmd = '/bin/rpm -q LONCAPA-prerequisites ';
    if (-e '/etc/oracle-release') {
        open(IN,'</etc/oracle-release');
        my $versionstring=<IN>;
        chomp($versionstring);
        close(IN);
        if ($versionstring =~ /^Oracle Linux Server release (\d+)/) {
            my $version = $1;
            $distro = 'oracle'.$1;
            $updatecmd = 'yum install LONCAPA-prerequisites';
            $installnow = 'yum -y install LONCAPA-prerequisites';
        }
    } elsif (-e '/etc/redhat-release') {
        open(IN,'</etc/redhat-release');
        my $versionstring=<IN>;
        chomp($versionstring);
        close(IN);
        if ($versionstring =~ /^Red Hat Linux release ([\d\.]+) /) {
            my $version = $1;
            if ($version=~/^7\./) {
                $distro='redhat7';
            } elsif ($version=~/^8\./) {
                $distro='redhat8';
            } elsif ($version=~/^9/) {
                $distro='redhat9';
            }
        } elsif ($versionstring =~ /Fedora( Core)? release ([\d\.]+) /) {
            my $version=$2;
            if ($version - int($version) > .9) {
                $distro = 'fedora'.(int($version)+1);
            } else {
                $distro = 'fedora'.int($version);
            }
            $updatecmd = 'yum install LONCAPA-prerequisites';
            $installnow = 'yum -y install LONCAPA-prerequisites';
        } elsif ($versionstring =~ /Red Hat Enterprise Linux [AE]S release ([\d\.]+) /) {
            $distro = 'rhes'.$1;
            $updatecmd = 'up2date -i LONCAPA-prerequisites';
        } elsif ($versionstring =~ /Red Hat Enterprise Linux Server release (\d+)/) {
            $distro = 'rhes'.$1;
            $updatecmd = 'yum install LONCAPA-prerequisites';
            $installnow = 'yum -y install LONCAPA-prerequisites';
        } elsif ($versionstring =~ /Red Hat Enterprise Linux release (\d+)/) {
            $distro = 'rhes'.$1;
            $updatecmd = 'dnf install LONCAPA-prerequisites';
            $installnow = 'dnf -y install LONCAPA-prerequisites';
        } elsif ($versionstring =~ /CentOS(?:| Linux| Stream) release (\d+)/) {
            $distro = 'centos'.$1;
            $updatecmd = 'yum install LONCAPA-prerequisites';
            $installnow = 'yum -y install LONCAPA-prerequisites';
        } elsif ($versionstring =~ /Scientific Linux (?:SL )?release ([\d.]+) /) {
            my $ver = $1;
            $ver =~ s/\.\d+$//;
            $distro = 'scientific'.$ver;
            $updatecmd = 'yum install LONCAPA-prerequisites';
            $installnow = 'yum -y install LONCAPA-prerequisites';
        } else {
            print &mt('Unable to interpret [_1] to determine system type.',
                      '/etc/redhat-release')."\n";
            $unknown = 1;
        }
    } elsif (-e '/etc/SuSE-release') {
        open(IN,'</etc/SuSE-release');
        my $versionstring=<IN>;
        chomp($versionstring);
        close(IN);
        if ($versionstring =~ /^SUSE LINUX Enterprise Server ([\d\.]+) /i) {
            $distro='sles'.$1;
            if ($1 >= 10) {
                $updatecmd = 'zypper install LONCAPA-prerequisites';
            } else {
                $updatecmd = 'yast -i LONCAPA-prerequisites';
            }
        } elsif ($versionstring =~ /^SuSE Linux ([\d\.]+) /i) {
            $distro = 'suse'.$1;
            $updatecmd = 'yast -i LONCAPA-prerequisites';
        } elsif ($versionstring =~ /^openSUSE ([\d\.]+) /i) {
            $distro = 'suse'.$1;
            if ($1 >= 10.3 ) {
                $updatecmd = 'zypper install LONCAPA-prerequisites';
            } else {
                $updatecmd = 'yast -i LONCAPA-prerequisites';
            }
        } else {
            print &mt('Unable to interpret [_1] to determine system type.',
                      '/etc/SuSE-release')."\n";
            $unknown = 1;
        }
    } elsif (-e '/etc/issue') {
        open(IN,'</etc/issue');
        my $versionstring=<IN>;
        chomp($versionstring);
        close(IN);
        if ($versionstring =~ /^Ubuntu (\d+)\.\d+/i) {
            $distro = 'ubuntu'.$1;
            $updatecmd = 'sudo apt-get install loncapa-prerequisites';
        } elsif ($versionstring =~ /^Debian\s+GNU\/Linux\s+(\d+)\.\d+/i) {
            $distro = 'debian'.$1;
            $updatecmd = 'apt-get install loncapa-prerequisites';
        } elsif (-e '/etc/debian_version') {
            open(IN,'</etc/debian_version');
            my $version=<IN>;
            chomp($version);
            close(IN);
            if ($version =~ /^(\d+)\.\d+\.?\d*/) {
                $distro='debian'.$1;
                $updatecmd = 'apt-get install loncapa-prerequisites';
            } else {
                print &mt('Unable to interpret [_1] to determine system type.',
                          '/etc/debian_version')."\n";
                $unknown = 1;
            }
        }
        if ($distro ne '') {
            $packagecmd = '/usr/bin/dpkg -l loncapa-prerequisites ';
        }
    } elsif (-e '/etc/debian_version') {
        open(IN,'</etc/debian_version');
        my $version=<IN>;
        chomp($version);
        close(IN);
        if ($version =~  /^(\d+)\.\d+\.?\d*/) {
            $distro='debian'.$1;
            $packagecmd = '/usr/bin/dpkg -l loncapa-prerequisites ';
            $updatecmd = 'apt-get install loncapa-prerequisites';
        } else {
            print &mt('Unable to interpret [_1] to determine system type.',
                      '/etc/debian_version')."\n";
            $unknown = 1;
        }
    }
    if (($distro eq '') && (!$unknown)) {
        if (-e '/etc/os-release') {
            if (open(IN,'<','/etc/os-release')) {
                my ($id,$version);
                while(<IN>) {
                    chomp();
                    if (/^ID="(\w+)"/) {
                        $id=$1;
                    } elsif (/^VERSION_ID="([\d\.]+)"/) {
                        $version=$1;
                    }
                }
                close(IN);
                if ($id eq 'sles') {
                    my ($major,$minor) = split(/\./,$version);
                    if ($major =~ /^\d+$/) {
                        $distro = $id.$major;
                        $updatecmd = 'zypper install LONCAPA-prerequisites';
                    }
                }
            }
            if ($distro eq '') {
                print &mt('Unable to interpret [_1] to determine system type.',
                          '/etc/os-release')."\n";
                $unknown = 1;
            }
        } else {
            print &mt('Unknown installation: expecting a debian, ubuntu, suse, sles, redhat, fedora, scientific linux, or oracle linux system.')."\n";
        }
    }
    return ($distro,$packagecmd,$updatecmd,$installnow);
}

sub check_prerequisites {
    my ($packagecmd,$distro) = @_;
    my $gotprereqs;
    if ($packagecmd ne '') {
        if (open(PIPE,"$packagecmd|")) {
            if ($distro =~ /^(debian|ubuntu)/) {
                my @lines = <PIPE>;
                chomp(@lines);
                foreach my $line (@lines) {
                    if ($line =~ /^ii\s+loncapa-prerequisites\s+([\w\.]+)/) {
                        $gotprereqs = $1;
                    }
                }
            } else {
                my $line = <PIPE>;
                chomp($line);
                if ($line =~ /^LONCAPA\-prerequisites\-([\d\-]+)\.(?:[.\w]+)$/) {
                    $gotprereqs = $1;
                }
            }
            close(PIPE);
        } else {
            print &mt('Error: could not determine if LONCAPA-prerequisites package is installed')."\n";
        }
    }
    return $gotprereqs;
}

sub check_locale {
    my ($distro) = @_;
    my ($fh,$langvar,$command,$earlyout);
    $langvar = 'LANG';
    if ($distro =~ /^(ubuntu|debian)/) {
        if (!open($fh,"</etc/default/locale")) {
            print &mt('Failed to open: [_1], default locale not checked.',
                      '/etc/default/locale');
            $earlyout = 1;
        }
    } elsif ($distro =~ /^(suse|sles)(\d+)/) {
        if (($1 eq 'sles') && ($2 >= 15)) {
            if (!open($fh,"</etc/locale.conf")) {
                print &mt('Failed to open: [_1], default locale not checked.',
                          '/etc/locale.conf');
                $earlyout = 1;
            }
        } else {
            if (!open($fh,"</etc/sysconfig/language")) {
                print &mt('Failed to open: [_1], default locale not checked.',
                          '/etc/sysconfig/language');
                $earlyout = 1;
            }
            $langvar = 'RC_LANG';
        }
    } elsif ($distro =~ /^fedora(\d+)/) {
        if ($1 >= 18) {
            if (!open($fh,"</etc/locale.conf")) {
                print &mt('Failed to open: [_1], default locale not checked.',
                          '/etc/locale.conf');
                $earlyout = 1;
            }
        } elsif (!open($fh,"</etc/sysconfig/i18n")) {
            print &mt('Failed to open: [_1], default locale not checked.',
                      '/etc/sysconfig/i18n');
            $earlyout = 1;
        }
    } elsif ($distro =~ /^(?:rhes|centos|scientific|oracle)(\d+)/) {
        if ($1 >= 7) {
            if (!open($fh,"</etc/locale.conf")) {
                print &mt('Failed to open: [_1], default locale not checked.',
                          '/etc/locale.conf');
                $earlyout = 1;
            }
        } elsif (!open($fh,"</etc/sysconfig/i18n")) {
            print &mt('Failed to open: [_1], default locale not checked.',
                      '/etc/sysconfig/i18n');
            $earlyout = 1;
        }
    } else {
        if (!open($fh,"</etc/sysconfig/i18n")) {
            print &mt('Failed to open: [_1], default locale not checked.',
                      '/etc/sysconfig/i18n');
            $earlyout = 1;
        }
    }
    return if ($earlyout);
    my @data = <$fh>;
    chomp(@data);
    foreach my $item (@data) {
        if ($item =~ /^\Q$langvar\E=\"?([^\"]*)\"?/) {
            my $default = $1;
            if ($default ne 'en_US.UTF-8') {
                if ($distro =~ /^debian/) {
                    $command = 'locale-gen en_US.UTF-8'."\n".
                               'update-locale LANG=en_US.UTF-8';
                } elsif ($distro =~ /^ubuntu/) {
                    $command = 'sudo locale-gen en_US.UTF-8'."\n".
                               'sudo update-locale LANG=en_US.UTF-8';
                } elsif ($distro =~ /^(suse|sles)/) {
                    $command = 'yast language';
                } elsif (-e '/usr/bin/system-config-language') {
                    $command = 'system-config-language';
                } elsif (-e '/usr/bin/localectl') {
                    $command = '/usr/bin/localectl set-locale LANG=en_US.UTF-8';
                } else {
                    $command = 'No standard command found';
                }
            }
            last;
        }
    }
    close($fh);
    return $command;
}

sub check_required {
    my ($instdir,$dsn) = @_;
    my ($distro,$packagecmd,$updatecmd,$installnow) = &get_distro();
    if ($distro eq '') {
        return;
    }
    my $gotprereqs = &check_prerequisites($packagecmd,$distro); 
    if ($gotprereqs eq '') {
        return ($distro,$gotprereqs,'',$packagecmd,$updatecmd);
    }
    my $localecmd = &check_locale($distro);
    unless ($localecmd eq '') {
        return ($distro,$gotprereqs,$localecmd);
    }
    my ($mysqlon,$mysqlsetup,$mysqlrestart,$dbh,$has_pass,$mysql_unix_socket,$has_lcdb,
        %recommended,$downloadstatus,$filetouse,$production,$testing,$apachefw,
        $tostop,$uses_systemctl,$mysql_has_wwwuser);
    my $wwwuid = &uid_of_www();
    my $wwwgid = getgrnam('www');
    if (($wwwuid eq '') || ($wwwgid eq '')) {
        $recommended{'wwwuser'} = 1;
    }
    unless( -e "/usr/local/sbin/pwauth") {
        $recommended{'pwauth'} = 1;
    }
    $mysqlon = &check_mysql_running($distro);
    if ($mysqlon) {
        ($mysqlsetup,$has_pass,$dbh,$mysql_has_wwwuser,$mysql_unix_socket) =
            &check_mysql_setup($instdir,$dsn,$distro);
        if ($mysqlsetup eq 'needsrestart') {
            $mysqlrestart = '';
            if ($distro eq 'ubuntu') {
                $mysqlrestart = 'sudo '; 
            }
            $mysqlrestart .= 'service mysql restart';
            return ($distro,$gotprereqs,$localecmd,$packagecmd,$updatecmd,$installnow,$mysqlrestart);
        } else {
            if ($mysqlsetup eq 'noroot') {
                $recommended{'mysqlperms'} = 1;
            } else {
                unless ($mysql_has_wwwuser) {
                    $recommended{'mysqlperms'} = 1;
                }
            }
            if ($dbh) {
                $has_lcdb = &check_loncapa_mysqldb($dbh);
            }
            unless ($has_lcdb) {
                $recommended{'mysql'} = 1;
            }
        }
    }
    ($recommended{'firewall'},$apachefw) = &chkfirewall($distro);
    ($recommended{'runlevels'},$tostop,$uses_systemctl) = &chkconfig($distro,$instdir);
    $recommended{'apache'} = &chkapache($distro,$instdir);
    $recommended{'stopsrvcs'} = &chksrvcs($distro,$tostop);
    ($recommended{'download'},$downloadstatus,$filetouse,$production,$testing) 
        = &need_download();
    return ($distro,$gotprereqs,$localecmd,$packagecmd,$updatecmd,$installnow,
            $mysqlrestart,\%recommended,$dbh,$has_pass,$mysql_unix_socket,
            $has_lcdb,$downloadstatus,$filetouse,$production,$testing,$apachefw,
            $uses_systemctl);
}

sub check_mysql_running {
    my ($distro) = @_;
    my $use_systemctl;
    my $mysqldaemon ='mysqld';
    if ($distro =~ /^(suse|sles|debian|ubuntu)/) {
        $mysqldaemon = 'mysql';
    }
    my $process = 'mysqld_safe';
    my $proc_owner = 'root';
    if ($distro =~ /^ubuntu(\w+)/) {
        if ($1 >= 10) {
            $process = 'mysqld';
            $proc_owner = 'mysql';
        }
    } elsif ($distro =~ /^fedora(\d+)/) {
        if ($1 >= 16) {
            $process = 'mysqld';
            $proc_owner = 'mysql';
            $use_systemctl = 1;
        }
        if ($1 >= 19) {
            $mysqldaemon ='mariadb';
        }
    } elsif ($distro =~ /^(?:centos|rhes|scientific|oracle)(\d+)/) {
        if ($1 >= 7) {
            $mysqldaemon ='mariadb';
            $process = 'mysqld';
            $proc_owner = 'mysql';
            $use_systemctl = 1;
        }
    } elsif ($distro =~ /^sles(\d+)/) {
        if ($1 >= 12) {
            $use_systemctl = 1;
            $proc_owner = 'mysql';
            $process = 'mysqld';
        }
        if ($1 >= 15) {
            $mysqldaemon ='mariadb';
        }
    } elsif ($distro =~ /^suse(\d+)/) {
        if ($1 >= 13) {
            $use_systemctl = 1;
        }
    }
    if (open(PIPE,"ps -ef |grep $process |grep ^$proc_owner |grep -v grep 2>&1 |")) {
        my $status = <PIPE>;
        close(PIPE);
        chomp($status);
        if ($status =~ /^\Q$proc_owner\E\s+\d+\s+/) {
            print_and_log(&mt('MySQL is running.')."\n");
            return 1;
        } else {
            if ($use_systemctl) {
                system("/bin/systemctl start $mysqldaemon.service >/dev/null 2>&1 ");
            } else {
                system("/etc/init.d/$mysqldaemon start >/dev/null 2>&1 ");
            }
            print_and_log(&mt('Waiting for MySQL to start.')."\n");
            sleep 5;
            if (open(PIPE,"ps -ef |grep $process |grep -v grep 2>&1 |")) {
                $status = <PIPE>;
                close(PIPE);
                chomp($status);
                if ($status =~ /^\Q$proc_owner\E\s+\d+\s+/) {
                    print_and_log(&mt('MySQL is running.')."\n");
                    return 1;
                } else {
                    print_and_log(&mt('Still waiting for MySQL to start.')."\n");
                    sleep 5;
                    if (open(PIPE,"ps -ef |grep $process |grep -v grep 2>&1 |")) {
                        $status = <PIPE>;
                        close(PIPE);
                        chomp($status);
                        if ($status =~ /^\Q$proc_owner\E\s+\d+\s+/) {
                            print_and_log(&mt('MySQL is running.')."\n");
                            return 1;
                        } else {
                            print_and_log(&mt('Given up waiting for MySQL to start.')."\n"); 
                        }
                    }
                }
            }
        }
    } else {
        print &mt('Could not determine if MySQL is running.')."\n";
    }
    return;
}

sub chkconfig {
    my ($distro,$instdir) = @_;
    my (%needfix,%tostop,%uses_systemctl);
    my $checker_bin = '/sbin/chkconfig';
    my $sysctl_bin = '/bin/systemctl';
    my %daemon = (
                  mysql     => 'mysqld',
                  apache    => 'httpd',
                  cups      => 'cups',
                  ntp       => 'ntpd',
                  memcached => 'memcached',
    );
    my @runlevels = qw/3 4 5/;
    my @norunlevels = qw/0 1 6/;
    if ($distro =~ /^(suse|sles)/) {
        @runlevels = qw/3 5/;
        @norunlevels = qw/0 2 1 6/;
        $daemon{'mysql'} = 'mysql';
        $daemon{'apache'} = 'apache2';
        $daemon{'ntp'}    = 'ntp';
        if ($distro =~ /^(suse|sles)9/) {
            $daemon{'apache'} = 'apache';
        }
        if ($distro =~ /^(suse|sles)([\d\.]+)/) {
            my $name = $1;
            my $num = $2;
            if ($num > 11) {
                $uses_systemctl{'apache'} = 1;
                if (($name eq 'sles') || ($name eq 'suse' && $num >= 13.2)) {
                    $uses_systemctl{'mysql'} = 1;
                    $uses_systemctl{'ntp'} = 1;
                    $uses_systemctl{'cups'} = 1;
                    $uses_systemctl{'memcached'} = 1;
                    if (($name eq 'sles') && ($num >= 15)) {
                        $daemon{'ntp'} = 'chronyd';
                        $daemon{'mysql'} = 'mariadb';
                    } else {
                        $daemon{'ntp'} = 'ntpd';
                    }
                }
            }
        }
    } elsif ($distro =~ /^(?:debian|ubuntu)(\d+)/) {
        my $version = $1;
        @runlevels = qw/2 3 4 5/;
        @norunlevels = qw/0 1 6/;
        if (($distro =~ /^ubuntu/) && ($version <= 16)) {
            $checker_bin = '/usr/sbin/sysv-rc-conf';
        } else {
            $uses_systemctl{'ntp'} = 1;
            $uses_systemctl{'mysql'} = 1;
            $uses_systemctl{'apache'} = 1;
            $uses_systemctl{'memcached'} = 1;
            $uses_systemctl{'cups'} = 1;
        }
        $daemon{'mysql'}  = 'mysql';
        $daemon{'apache'} = 'apache2';
        $daemon{'ntp'}    = 'ntp';
        if (($distro =~ /^ubuntu/) && ($version <= 8)) {
            $daemon{'cups'} = 'cupsys';
        }
        if (($distro =~ /^ubuntu/) && ($version >= 18)) {
            $daemon{'ntp'}    = 'chrony';
        }
    } elsif ($distro =~ /^fedora(\d+)/) {
        my $version = $1;
        if ($version >= 15) {
            $uses_systemctl{'ntp'} = 1;
        }
        if ($version >= 16) {
            $uses_systemctl{'mysql'} = 1;
            $uses_systemctl{'apache'} = 1;
            $uses_systemctl{'memcached'} = 1;
            $uses_systemctl{'cups'} = 1;
        }
        if ($version >= 19) {
            $daemon{'mysql'} = 'mariadb';
        }
        if ($version >= 26) {
            $daemon{'ntp'} = 'chronyd';
        }
    } elsif ($distro =~ /^(?:centos|rhes|scientific|oracle)(\d+)/) {
        my $version = $1;
        if ($version >= 7) {
            $uses_systemctl{'ntp'} = 1;
            $uses_systemctl{'mysql'} = 1;
            $uses_systemctl{'apache'} = 1;
            $uses_systemctl{'memcached'} = 1;
            $uses_systemctl{'cups'} = 1;
            $daemon{'mysql'} = 'mariadb';
        }
        if (($version >= 8) || ($distro eq 'oracle7')) {
            $daemon{'ntp'} = 'chronyd';
        }
    }
    my $nocheck;
    if (! -x $checker_bin) {
        if ($uses_systemctl{'mysql'} && $uses_systemctl{'apache'}) {
            if (! -x $sysctl_bin) {
                $nocheck = 1;       
            }
        } else {
            $nocheck = 1;
        }
    }
    if ($nocheck) {
        print &mt('Could not check runlevel status for MySQL or Apache')."\n";
        return;
    }
    my $rlstr = join('',@runlevels);
    my $nrlstr = join('',@norunlevels);

    foreach my $type ('apache','mysql','ntp','cups','memcached') {
        my $service = $daemon{$type};
        if ($uses_systemctl{$type}) {
            if (($type eq 'memcached') || ($type eq 'cups')) {
                if (-l "/etc/systemd/system/multi-user.target.wants/$service.service") {
                    $tostop{$type} = 1;
                }
            } else {
                if (!-l "/etc/systemd/system/multi-user.target.wants/$service.service") {
                    $needfix{$type} = "systemctl enable $service.service";
                }
            }
        } else {
            my $command = $checker_bin.' --list '.$service.' 2>/dev/null';
            if ($type eq 'cups') {
                if ($distro =~ /^(?:debian|ubuntu)(\d+)/) {
                    my $version = $1;
                    if (($distro =~ /^ubuntu/) && ($version <= 8)) {
                        $command = $checker_bin.' --list cupsys 2>/dev/null';
                    }
                }
            }
            my $results = `$command`;
            my $tofix;
            if ($results eq '') {
                if (($type eq 'apache') || ($type eq 'mysql') || ($type eq 'ntp')) {
                    if ($distro  =~ /^(debian|ubuntu)/) {
                        $tofix = "update-rc.d $type defaults";
                    } else {
                        $tofix = "$checker_bin --add $service\n";
                    }
                }
            } else {
                my %curr_runlevels;
                for (my $rl=0; $rl<=6; $rl++) {
                    if ($results =~ /$rl:on/) { $curr_runlevels{$rl}++; }
                }
                if (($type eq 'apache') || ($type eq 'mysql') || ($type eq 'ntp')) {
                    my $warning;
                    foreach my $rl (@runlevels) {
                        if (!exists($curr_runlevels{$rl})) {
                            $warning = 1;
                        }
                    }
                    if ($warning) {
                        $tofix = "$checker_bin --level $rlstr $service on\n";
                    }
                } elsif (keys(%curr_runlevels) > 0) {
                    $tostop{$type} = 1;
                }
            }
            if ($tofix) {
                $needfix{$type} = $tofix;
            }
        }
    }
    if ($distro =~ /^(suse|sles)([\d\.]+)$/) {
        my $name = $1;
        my $version = $2;
        my ($major,$minor);
        if ($name eq 'suse') {
            ($major,$minor) = split(/\./,$version);
        } else {
            $major = $version;
        }
        if (($major > 10) && ($major <= 13)) {
            if (&check_SuSEfirewall2_setup($instdir)) {
                $needfix{'insserv'} = 1;
            }
        }
    }
    return (\%needfix,\%tostop,\%uses_systemctl);
}

sub uses_firewalld {
    my ($distro) = @_;
    my ($inuse,$checkfirewalld,$zone);
    if ($distro =~ /^(suse|sles)([\d\.]+)$/) {
        if (($1 eq 'sles') && ($2 >= 15)) {
            $checkfirewalld = 1;
        }
    } elsif ($distro =~ /^fedora(\d+)$/) {
        if ($1 >= 18) {
            $checkfirewalld = 1;
        }
    } elsif ($distro =~ /^(?:centos|rhes|scientific|oracle)(\d+)/) {
        if ($1 >= 7) {
            $checkfirewalld = 1;
        }
    }
    if ($checkfirewalld) {
        my ($loaded,$active);
        if (open(PIPE,"systemctl status firewalld |")) {
            while (<PIPE>) {
                chomp();
                if (/^\s*Loaded:\s+(\w+)/) {
                    $loaded = $1;
                }
                if (/^\s*Active\s+(\w+)/) {
                    $active = $1;
                }
            }
            close(PIPE);
        }
        if (($loaded eq 'loaded') || ($active eq 'active')) {
            $inuse = 1;
            my $cmd = 'firewall-cmd --get-default-zone';
            if (open(PIPE,"$cmd |")) {
                my $result = <PIPE>;
                chomp($result);
                close(PIPE);
                if ($result =~ /^\w+$/) {
                    $zone = $result;
                }
            }
        }
    }
    return ($inuse,$zone);
}

sub chkfirewall {
    my ($distro) = @_;
    my $configfirewall = 1;
    my %ports = (
                    http  =>  80,
                    https => 443,
                );
    my %activefw;
    my ($firewalld,$zone) = &uses_firewalld($distro);
    if ($firewalld) {
        my %current;
        if (open(PIPE,'firewall-cmd --permanent --zone='.$zone.' --list-services |')) {
            my $svc = <PIPE>;
            close(PIPE);
            chomp($svc);
            map { $current{$_} = 1; } (split(/\s+/,$svc));
        }
        if ($current{'http'} && $current{'https'}) {
            $configfirewall = 0;
        }
    } else {
        if (&firewall_is_active()) {
            my $iptables = &get_pathto_iptables();
            if ($iptables eq '') {
                print &mt('Firewall not checked as path to iptables not determined.')."\n";
            } else {
                my @fwchains = &get_fw_chains($iptables,$distro);
                if (@fwchains) {
                    foreach my $service ('http','https') {
                        foreach my $fwchain (@fwchains) {
                            if (&firewall_is_port_open($iptables,$fwchain,$ports{$service})) {
                                $activefw{$service} = 1;
                                last;
                            }
                        }
                    }
                    if ($activefw{'http'}) {
                        $configfirewall = 0;
                    }
                } else {
                    print &mt('Firewall not checked as iptables Chains not identified.')."\n";
                }
            }
        } else {
            print &mt('Firewall not enabled.')."\n";
        }
    }
    return ($configfirewall,\%activefw);
}

sub chkapache {
    my ($distro,$instdir) = @_;
    my $fixapache = 1;
    if ($distro =~ /^(debian|ubuntu)(\d+)$/) {
        my $distname = $1;
        my $version = $2;
        my ($stdconf,$stdsite);
        if (($distname eq 'ubuntu') && ($version > 12)) {
            $stdconf = "$instdir/debian-ubuntu/ubuntu14/loncapa_conf";
            $stdsite = "$instdir/debian-ubuntu/ubuntu14/loncapa_sites";
        } else {
            $stdconf = "$instdir/debian-ubuntu/loncapa"; 
        }
        if (!-e $stdconf) {
            $fixapache = 0;
            print &mt('Warning: No LON-CAPA Apache configuration file found for installation check.')."\n"; 
        } else {
            my ($configfile,$sitefile);
            if (($distname eq 'ubuntu') && ($version > 12)) {
                $sitefile = '/etc/apache2/sites-available/loncapa.conf';
                $configfile = '/etc/apache2/conf-available/loncapa.conf';
            } else {
                $configfile = '/etc/apache2/sites-available/loncapa';
            }
            if (($configfile ne '') && (-e $configfile) && (-e $stdconf))  {
                if (open(PIPE, "diff --brief $stdconf $configfile |")) {
                    my $diffres = <PIPE>;
                    close(PIPE);
                    chomp($diffres);
                    unless ($diffres) {
                        $fixapache = 0;
                    }
                }
            }
            if ((!$fixapache) && ($distname eq 'ubuntu') && ($version > 12)) {
                if (($sitefile ne '') && (-e $sitefile) && (-e $stdsite)) {
                    if (open(PIPE, "diff --brief $stdsite $sitefile |")) {
                        my $diffres = <PIPE>;
                        close(PIPE);
                        chomp($diffres);
                        unless ($diffres) {
                            $fixapache = 0;
                        }
                    }
                }
            }
        }
        if (!$fixapache) {
            foreach my $module ('headers.load','expires.load') {
                unless (-l "/etc/apache2/mods-enabled/$module") {
                    $fixapache = 1;
                }
            }
        }
        if ((!$fixapache) && ($distname eq 'ubuntu')) {
            my $sitestatus = "/etc/apache2/mods-available/status.conf";
            my $stdstatus = "$instdir/debian-ubuntu/status.conf";
            if ((-e $stdstatus) && (-e $sitestatus)) {
                if (open(PIPE, "diff --brief $stdstatus $sitestatus |")) {
                    my $diffres = <PIPE>;
                    close(PIPE);
                    chomp($diffres);
                    if ($diffres) {
                        $fixapache = 1;
                    }
                }
            }
        }
    } elsif ($distro =~ /^(suse|sles)([\d\.]+)$/) {
        my ($name,$version) = ($1,$2);
        my $apache = 'apache';
        my $conf_file = "$instdir/sles-suse/default-server.conf";
        if ($version >= 10) {
            $apache = 'apache2';
        }
        if (($name eq 'sles') && ($version >= 12)) {
            $conf_file = "$instdir/sles-suse/apache2.4/default-server.conf";
        }
        if (!-e $conf_file) {
            $fixapache = 0;
            print &mt('Warning: No LON-CAPA Apache configuration file found for installation check.')."\n";
        } elsif (-e "/etc/$apache/default-server.conf") {
            if (open(PIPE, "diff --brief $conf_file /etc/$apache/default-server.conf |")) {
                my $diffres = <PIPE>;
                close(PIPE);
                chomp($diffres);
                unless ($diffres) {
                    $fixapache = 0;
                }
            }
        }
    } elsif ($distro eq 'rhes4') {
        if (!-e "$instdir/rhes4/httpd.conf") {
            $fixapache = 0;
            print &mt('Warning: No LON-CAPA Apache configuration file found for installation check.')."\n";
        } elsif ((-e "/etc/httpd/conf/httpd.conf") && (-e "$instdir/rhes4/httpd.conf")) {
            if (open(PIPE, "diff --brief $instdir/rhes4/httpd.conf /etc/httpd/conf/httpd.conf |")) {
                my $diffres = <PIPE>;
                close(PIPE);
                chomp($diffres);
                unless ($diffres) {
                    $fixapache = 0;
                }
            }
        }
    } else {
        my $configfile = 'httpd.conf';
        my $mpmfile = 'mpm.conf';
        if ($distro =~ /^(?:centos|rhes|scientific|oracle)(\d+)$/) {
            if ($1 >= 7) {
                $configfile = 'apache2.4/httpd.conf';
            } elsif ($1 > 5) {
                $configfile = 'new/httpd.conf';
            }
        } elsif ($distro =~ /^fedora(\d+)$/) {
            if ($1 > 17) {
                $configfile = 'apache2.4/httpd.conf';
            } elsif ($1 > 10) {
                $configfile = 'new/httpd.conf';
            }
        }
        if (!-e "$instdir/centos-rhes-fedora-sl/$configfile") {
            $fixapache = 0;
            print &mt('Warning: No LON-CAPA Apache configuration file found for installation check.')."\n";
        } elsif ((-e "/etc/httpd/conf/httpd.conf") && (-e "$instdir/centos-rhes-fedora-sl/$configfile")) {
            if (open(PIPE, "diff --brief $instdir/centos-rhes-fedora-sl/$configfile /etc/httpd/conf/httpd.conf |")) {
                my $diffres = <PIPE>;
                close(PIPE);
                chomp($diffres);
                unless ($diffres) {
                    $fixapache = 0;
                }
            }
        }
        if (-e "/etc/httpd/conf.modules.d/00-mpm.conf") {
            if (!-e "$instdir/centos-rhes-fedora-sl/$mpmfile") {
                print &mt('Warning: No LON-CAPA Apache MPM configuration file found for installation check.')."\n";
            } elsif ((-e "/etc/httpd/conf.modules.d/00-mpm.conf") && (-e "$instdir/centos-rhes-fedora-sl/$mpmfile")) {
                if (open(PIPE, "diff --brief $instdir/centos-rhes-fedora-sl/$mpmfile /etc/httpd/conf.modules.d/00-mpm.conf |")) {
                    my $diffres = <PIPE>;
                    close(PIPE);
                    chomp($diffres);
                    if ($diffres) {
                        $fixapache = 1;
                    }
                }
            }
        }
    }
    return $fixapache;
}

sub chksrvcs {
    my ($distro,$tostop) = @_;
    my %stopsrvcs;
    if (ref($tostop) eq 'HASH') {
        %stopsrvcs = %{$tostop};
    }
    foreach my $service ('cups','memcached') {
        next if (exists($stopsrvcs{$service}));
        my $daemon = $service;
        if ($service eq 'cups') {
            $daemon = 'cupsd';
        }
        my $cmd = "ps -ef |grep '$daemon' |grep -v grep";
        if (open(PIPE,'-|',$cmd)) {
            my $daemonrunning = <PIPE>;
            chomp($daemonrunning);
            close(PIPE);
            if ($daemonrunning) {
                if ($service eq 'memcached') {
                    my $cmd = '/usr/bin/memcached';
                    if ($distro =~ /^(suse|sles)/) {
                        $cmd = '/usr/sbin/memcached';
                    }
                    unless ($daemonrunning =~ m{^www[^/]+\Q$cmd -m 400 -v\E$}) {
                        $stopsrvcs{$service} = 1;
                    }
                } else {
                    $stopsrvcs{$service} = 1;
                }
            }
        }
    }
    return \%stopsrvcs;
}

sub need_download {
    my $needs_download = 1;
    my ($production,$testing,$stdsizes) = &download_versionslist();
    my ($rootdir,$localcurrent,$localtesting,%tarball,%localsize,%bymodtime,
        %bysize,$filetouse,$downloadstatus);
    $rootdir = '/root';
    if (opendir(my $dir,"$rootdir")) {
        my (@lcdownloads,$version);
        foreach my $file (readdir($dir)) {
            if ($file =~ /^loncapa\-([\w\-.]+)\.tar\.gz$/) {
                $version = $1;
            } else {
                next;
            }
            if (ref($stdsizes) eq 'HASH') {
                if ($version eq 'current') {
                    my @stats = stat("$rootdir/$file");
                    $localcurrent = $stats[7];
                    if ($localcurrent == $stdsizes->{$production}) {
                        $needs_download = 0;
                        $filetouse = $file;
                    }
                } elsif ($version eq 'testing') {
                    my @stats = stat("$rootdir/$file");
                    $localtesting = $stats[7];
                    if ($localtesting == $stdsizes->{$testing}) {
                        $needs_download = 0;
                        $filetouse = $file;
                    }
                }
            }
            $tarball{$version} = $file;
            push(@lcdownloads,$version);
        }
        if ($needs_download) {
            if (@lcdownloads > 0) {
                foreach my $version (@lcdownloads) {
                    my @stats = stat("$rootdir/$tarball{$version}");
                    my $mtime = $stats[9];
                    $localsize{$version} = $stats[7];
                    if ($mtime) {
                        push(@{$bymodtime{$mtime}},$version);
                    }
                    if ($localsize{$version}) {
                        push(@{$bysize{$localsize{$version}}},$version);
                    }
                }
                if ($testing) {
                    if (exists($localsize{$testing})) {
                        if ($stdsizes->{$testing} == $localsize{$testing}) {
                            $needs_download = 0;
                            $filetouse = 'loncapa-'.$testing.'.tar.gz';
                        }
                    }
                }
                if ($needs_download) { 
                    if ($production) {
                        if (exists($localsize{$production})) {
                            if ($stdsizes->{$production} == $localsize{$production}) {
                                $needs_download = 0;
                                $filetouse = 'loncapa-'.$production.'.tar.gz';
                            }
                        }
                    }
                }
                if ($needs_download) {
                    my @sorted = sort { $b <=> $a } keys(%bymodtime);
                    my $newest = $sorted[0];
                    if (ref($bymodtime{$newest}) eq 'ARRAY') {
                        $downloadstatus = 
                              "Latest LON-CAPA source download in $rootdir is: ".
                              join(',',@{$bymodtime{$newest}})." (downloaded ".
                              localtime($newest).")\n";
                    }
                } else {
                    $downloadstatus = 
                        "The $rootdir directory already contains the latest LON-CAPA version:".
                        "\n".$filetouse."\n"."which can be used for installation.\n";
                }
            } else {
                $downloadstatus = "The $rootdir directory does not appear to contain any downloaded LON-CAPA source code files which can be used for installation.\n";
            }
        }
    } else {
        $downloadstatus = "Could not open $rootdir directory to look for existing downloads of LON-CAPA source code.\n";
    }
    return ($needs_download,$downloadstatus,$filetouse,$production,$testing);
}

sub check_mysql_setup {
    my ($instdir,$dsn,$distro) = @_;
    my ($mysqlsetup,$has_pass,$mysql_unix_socket,$mysql_has_wwwuser);
    my $dbh = DBI->connect($dsn,'root','',{'PrintError'=>0});
    my ($mysqlversion,$mysqlsubver,$mysqlname) = &get_mysql_version();
    if (($mysqlname =~ /^MariaDB/i) && ($mysqlversion >= 10.4)) {
        if ($dbh) {
            my $sth = $dbh->prepare("SELECT Priv FROM mysql.global_priv WHERE (User = 'root' AND Host ='localhost')");
            $sth->execute();
            while (my $priv = $sth->fetchrow_array) {
                if ($priv =~ /unix_socket/) {
                    $mysql_unix_socket = 1;
                    last;
                }
            }
            $sth->finish();
            if ($mysql_unix_socket) {
                print_and_log(&mt('MariaDB using unix_socket for root access from localhost.')."\n");
                $mysqlsetup = 'rootok';
                $mysql_has_wwwuser = &check_mysql_wwwuser($dbh);
                return ($mysqlsetup,$has_pass,$dbh,$mysql_has_wwwuser,$mysql_unix_socket);
            }
        }
    }
    if ($dbh) {
        $mysqlsetup = 'noroot';
        if (($mysqlname !~ /^MariaDB/i) && ($mysqlversion >= 5.7)) {
            my $sth = $dbh->prepare("SELECT plugin from mysql.user where User='root'");
            $sth->execute();
            while (my $priv = $sth->fetchrow_array) {
                if ($priv =~ /auth_socket/) {
                    $mysql_unix_socket = 1;
                    last;
                }
            }
            $sth->finish();
            if ($mysql_unix_socket) {
                print_and_log(&mt('MySQL using unix_socket for root access from localhost.')."\n");
                $mysqlsetup = 'rootok';
                $mysql_has_wwwuser = &check_mysql_wwwuser($dbh);
                return ($mysqlsetup,$has_pass,$dbh,$mysql_has_wwwuser,$mysql_unix_socket);
            }
        }
    } elsif ($DBI::err =~ /1045/) {
        $has_pass = 1;
    } elsif ($distro =~ /^ubuntu(\d+)$/) {
        my $version = $1;
        if ($1 > 12) {
            print_and_log(&mt('Restarting mysql, please be patient')."\n");
            if (open (PIPE, "service mysql restart 2>&1 |")) {
                while (<PIPE>) {
                    print $_;
                }
                close(PIPE);
            }
            $dbh = DBI->connect($dsn,'root','',{'PrintError'=>0});
            if ($dbh) {
                $mysqlsetup = 'noroot';
                $mysql_has_wwwuser = &check_mysql_wwwuser($dbh);
            } elsif ($DBI::err =~ /1045/) {
                $has_pass = 1;
            } else {
                $mysqlsetup = 'needsrestart';
                $mysql_has_wwwuser = &check_mysql_wwwuser(); 
                return ($mysqlsetup,$has_pass,$dbh,$mysql_has_wwwuser);
            }
        }
    }
    if ($has_pass) {
        print &mt('You have already set a root password for the MySQL database.')."\n";
        my $currpass = &get_mysql_password(&mt('Please enter the password now'));
        $dbh = DBI->connect($dsn,'root',$currpass,{'PrintError'=>0});
        if ($dbh) {
            $mysqlsetup = 'rootok';
            print_and_log(&mt('Password accepted.')."\n");
            $mysql_has_wwwuser = &check_mysql_wwwuser($dbh);
        } else {
            $mysqlsetup = 'rootfail';
            print_and_log(&mt('Problem accessing MySQL.')."\n");
            if ($DBI::err =~ /1045/) {
                print_and_log(&mt('Perhaps the password was incorrect?')."\n");
                print &mt('Try again?').' ';
                $currpass = &get_mysql_password(&mt('Re-enter password now')); 
                $dbh = DBI->connect($dsn,'root',$currpass,{'PrintError'=>0});
                if ($dbh) {
                    $mysqlsetup = 'rootok';
                    print_and_log(&mt('Password accepted.')."\n");
                    $mysql_has_wwwuser = &check_mysql_wwwuser($dbh);
                } else {
                    if ($DBI::err =~ /1045/) {
                        print_and_log(&mt('Incorrect password.')."\n");
                    }
                    $mysql_has_wwwuser = &check_mysql_wwwuser(); 
                }
            }
        }
    } elsif ($mysqlsetup ne 'noroot') {
        print_and_log(&mt('Problem accessing MySQL.')."\n");
        $mysqlsetup = 'rootfail';
        $mysql_has_wwwuser = &check_mysql_wwwuser(); 
    }
    return ($mysqlsetup,$has_pass,$dbh,$mysql_has_wwwuser);
}

sub check_mysql_wwwuser {
    my ($dbh) = @_;
    my $mysql_wwwuser;
    if ($dbh) {
        $mysql_wwwuser = $dbh->selectrow_array("SELECT COUNT(User) FROM mysql.user WHERE (User = 'www' AND Host ='localhost')");
    } else {
        my $dbhn = DBI->connect("DBI:mysql:database=information_schema",'www','localhostkey',
                                {PrintError => +0}) || return;
        if ($dbhn) {
            $mysql_wwwuser = 1;
            $dbhn->disconnect;
        }
    }
    return $mysql_wwwuser;
}

sub check_loncapa_mysqldb {
    my ($dbh) = @_;
    my $has_lcdb;
    if (ref($dbh)) {
        my $sth = $dbh->prepare("SHOW DATABASES");
        $sth->execute();
        while (my $dbname = $sth->fetchrow_array) {
            if ($dbname eq 'loncapa') {
                $has_lcdb = 1;
                last;
            }
        }
        $sth->finish();
    }
    return $has_lcdb;
}

sub get_pathto_iptables {
    my $iptables;
    if (-e '/sbin/iptables') {
        $iptables = '/sbin/iptables';
    } elsif (-e '/usr/sbin/iptables') {
        $iptables = '/usr/sbin/iptables';
    } else {
        print &mt('Unable to find iptables command.')."\n";
    }
    return $iptables;
}

sub firewall_is_active {
    if (-e '/proc/net/ip_tables_names') {
        if (open(PIPE,'cat /proc/net/ip_tables_names |grep filter |')) {
            my $status = <PIPE>;
            close(PIPE);
            chomp($status);
            if ($status eq 'filter') {
                return 1;
            }
        }
    }
    return 0;
}

sub get_fw_chains {
    my ($iptables,$distro) = @_;
    my @fw_chains;
    my $suse_config = "/etc/sysconfig/SuSEfirewall2";
    my $ubuntu_config = "/etc/ufw/ufw.conf";
    if (-e $suse_config) {
        push(@fw_chains,'input_ext');
    } else {
        my @posschains;
        if (-e $ubuntu_config) {
            @posschains = ('ufw-user-input','INPUT');
        } elsif ($distro =~ /^debian5/) {
            @posschains = ('INPUT');
        } elsif ($distro =~ /^(suse|sles)(\d+)/) {
            @posschains = ('IN_public');
        } else {
            @posschains = ('RH-Firewall-1-INPUT','INPUT');
            if (!-e '/etc/sysconfig/iptables') {
                if (!-e '/var/lib/iptables') {
                    print &mt('Unable to find iptables file containing static definitions.')."\n";
                }
                push(@fw_chains,'RH-Firewall-1-INPUT');
            }
        }
        if ($iptables eq '') {
            $iptables = &get_pathto_iptables();
        }
        my %counts;
        if (open(PIPE,"$iptables -L -n |")) {
            while(<PIPE>) {
                foreach my $chain (@posschains) {
                    if (/(\Q$chain\E)/) {
                        $counts{$1} ++;
                    }
                }
            }
            close(PIPE);
        }
        foreach my $fw_chain (@posschains) {
            if ($counts{$fw_chain}) {
                unless(grep(/^\Q$fw_chain\E$/,@fw_chains)) {
                    push(@fw_chains,$fw_chain);
                }
            }
        }
    }
    return @fw_chains;
}

sub firewall_is_port_open {
    my ($iptables,$fw_chain,$port) = @_;
    # returns 1 if the firewall port is open, 0 if not.
    #
    # check if firewall is active or installed
    return if (! &firewall_is_active());
    my $count = 0;
    if (open(PIPE,"$iptables -L $fw_chain -n |")) {
        while(<PIPE>) {
            if (/tcp dpt\:\Q$port\E/) {
                $count ++;
                last;
            }
        }
        close(PIPE);
    } else {
        print &mt('Firewall status not checked: unable to run [_1].','iptables -L')."\n";
    }
    return $count;
}

sub get_mysql_password {
    my ($prompt) = @_;
    local $| = 1;
    print $prompt.': ';
    my $newpasswd = '';
    ReadMode 'raw';
    my $key;
    while(ord($key = ReadKey(0)) != 10) {
        if(ord($key) == 127 || ord($key) == 8) {
            chop($newpasswd);
            print "\b \b";
        } elsif(!ord($key) < 32) {
            $newpasswd .= $key;
            print '*';
        }
    }
    ReadMode 'normal';
    print "\n";
    return $newpasswd;
}

sub check_SuSEfirewall2_setup {
    my ($instdir) = @_;
    my $need_override = 1;
    if ((-e "/etc/insserv/overrides/SuSEfirewall2_setup") && (-e "$instdir/sles-suse/SuSEfirewall2_setup")) {
        if (open(PIPE, "diff --brief $instdir/sles-suse/SuSEfirewall2_setup /etc/insserv/overrides/SuSEfirewall2_setup  |")) {
            my $diffres = <PIPE>;
            close(PIPE);
            chomp($diffres);
            unless ($diffres) {
                $need_override = 0;
            }
        }
    }
    return $need_override;
}

sub download_versionslist {
    my ($production,$testing,%sizes);
    if (-e "latest.txt") {
         unlink("latest.txt");
    }
    my $rtncode = system("wget http://install.loncapa.org/versions/latest.txt ".
                         "> /dev/null 2>&1");
    if (!$rtncode) {
        if (open(my $fh,"<latest.txt")) {
            my @info = <$fh>;
            close($fh);
            foreach my $line (@info) {
                chomp();
                if ($line =~ /^\QLATEST-IS: \E([\w\-.]+):(\d+)$/) {
                     $production = $1;
                     $sizes{$1} = $2;
                } elsif ($line =~ /^LATEST-TESTING-IS: \E([\w\-.]+):(\d+)$/) {
                     $testing = $1;
                     $sizes{$1} = $2;
                }
            }
        }
    }
    return ($production,$testing,\%sizes);
}

#
# End helper routines.
# Main script starts here
#

print "
********************************************************************

                    ".&mt('Welcome to LON-CAPA')."

".&mt('This script will configure your system for installation of LON-CAPA.')."

********************************************************************

".&mt('The following actions are available:')."

".&mt('1.')." ".&mt('Create the www user/group.')."
   ".&mt('This is the user/group ownership under which Apache child processes run.')."
   ".&mt('It also owns most directories within the /home/httpd directory.')." 
   ".&mt('This directory is where most LON-CAPA files and directories are stored.')."
".&mt('2.')." ".&mt('Install the package LON-CAPA uses to authenticate users.')."
".&mt('3.')." ".&mt('Set-up the MySQL database.')."
".&mt('4.')." ".&mt('Set-up MySQL permissions.')."
".&mt('5.')." ".&mt('Configure Apache web server.')."
".&mt('6.')." ".&mt('Configure start-up of services.')."
".&mt('7.')." ".&mt('Check firewall settings.')."
".&mt('8.')." ".&mt('Stop services not used by LON-CAPA,')."
   ".&mt('i.e., services for a print server: [_1] daemon.',"'cups'")."
".&mt('9.')." ".&mt('Download LON-CAPA source code in readiness for installation.')."

".&mt('Typically, you will run this script only once, when you first install LON-CAPA.')." 

".&mt('The script will analyze your system to determine which actions are recommended.')."
".&mt('The script will then prompt you to choose the actions you would like taken.')."

".&mt('For each the recommended action will be selected if you hit Enter/Return.')."
".&mt('To override the default, type the lower case option from the two options listed.')."
".&mt('So, if the default is "yes", ~[Y/n~] will be shown -- type n to override.')."
".&mt('Whereas if the default is "no", ~[y/N~] will be shown -- type y to override.')." 

".&mt('To accept the default, simply hit Enter/Return on your keyboard.')."
".&mt('Otherwise type: y or n then hit the Enter/Return key.')."

".&mt('Once a choice has been entered for all nine actions, required changes will be made.')."
".&mt('Feedback will be displayed on screen, and also stored in: [_1].','loncapa_install.log')."

".&mt('Continue? ~[Y/n~] ');

my $go_on = &get_user_selection(1);
if (!$go_on) {
    exit;
}

my $instdir = `pwd`;
chomp($instdir);

my %callsub;
my @actions = ('wwwuser','pwauth','mysql','mysqlperms','apache',
               'runlevels','firewall','stopsrvcs','download');
my %prompts = &texthash( 
    wwwuser    => "Create the 'www' user?",
    pwauth     => 'Install the package LON-CAPA uses to authenticate users?',
    mysql      => 'Set-up the MySQL database?',
    mysqlperms => 'Set-up MySQL permissions?',
    apache     => 'Configure Apache web server?',
    runlevels  => 'Set overrides for start-up order of services?',
    firewall   => 'Configure firewall settings for Apache',
    stopsrvcs  => 'Stop extra services not required on a LON-CAPA server?',
    download   => 'Download LON-CAPA source code in readiness for installation?',
);

print "\n".&mt('Checking system status ...')."\n";

my $dsn = "DBI:mysql:database=mysql";
my ($distro,$gotprereqs,$localecmd,$packagecmd,$updatecmd,$installnow,$mysqlrestart,
    $recommended,$dbh,$has_pass,$mysql_unix_socket,$has_lcdb,$downloadstatus,
    $filetouse,$production,$testing,$apachefw,$uses_systemctl) = &check_required($instdir,$dsn);
if ($distro eq '') {
    print "\n".&mt('Linux distribution could not be verified as a supported distribution.')."\n".
          &mt('The following are supported: [_1].',
              'CentOS, RedHat Enterprise, Fedora, Scientific Linux, '.
              'Oracle Linux, openSuSE, SLES, Ubuntu LTS, Debian')."\n\n".
          &mt('Stopping execution.')."\n";
    exit;
}
if ($mysqlrestart) {
    print "\n".&mt('The mysql daemon needs to be restarted using the following command:')."\n".
          $mysqlrestart."\n\n".
          &mt('Stopping execution of install.pl script.')."\n".
          &mt('Please run the install.pl script again, once you have restarted mysql.')."\n";
    exit;
}
if ($localecmd ne '') {
    print "\n".&mt('Although the LON-CAPA application itself is localized for a number of different languages, the default locale language for the Linux OS on which it runs should be US English.')."\n";
    print "\n".&mt('Run the following command from the command line to set the default language for your OS, and then run this LON-CAPA installation set-up script again.')."\n\n".
    $localecmd."\n\n".
    &mt('Stopping execution.')."\n";
    exit;
}
if (!$gotprereqs) {
    print "\n".&mt('The LONCAPA-prerequisites package is not installed.')."\n".
          &mt('The following command can be used to install the package (and dependencies):')."\n\n".
          $updatecmd."\n\n";
    if ($installnow eq '') {
        print &mt('Stopping execution.')."\n";
        exit;
    } else {
        print &mt('Run command? ~[Y/n~]');
        my $install_prereq = &get_user_selection(1);
        if ($install_prereq) {
            if (open(PIPE,'|-',$installnow)) {
                close(PIPE);
                $gotprereqs = &check_prerequisites($packagecmd,$distro);
                if (!$gotprereqs) {
                    print &mt('The LONCAPA-prerequisites package is not installed.')."\n".
                          &mt('Stopping execution.')."\n";
                    exit;
                } else {
                    ($distro,$gotprereqs,$localecmd,$packagecmd,$updatecmd,$installnow,
                     $mysqlrestart,$recommended,$dbh,$has_pass,$mysql_unix_socket,
                     $has_lcdb,$downloadstatus,$filetouse,$production,$testing,$apachefw,
                     $uses_systemctl) = &check_required($instdir,$dsn);
                }
            } else {
                print &mt('Failed to run command to install LONCAPA-prerequisites')."\n";
                exit;
            }
        } else {
            print &mt('Stopping execution.')."\n";
            exit;
        }
    }
}
unless (ref($recommended) eq 'HASH') {
    print "\n".&mt('An error occurred determining which actions are recommended.')."\n\n".
          &mt('Stopping execution.')."\n";
    exit;
}

print "\n";
my $num = 0;
foreach my $action (@actions) {
    $num ++;
    my ($yesno,$defaultrun);
    if (ref($recommended) eq 'HASH') {
        if (($action eq 'runlevels') || ($action eq 'stopsrvcs')) {
            $yesno = '[y/N]';
            if (ref($recommended->{$action}) eq 'HASH') {
                if (keys(%{$recommended->{$action}}) > 0) {
                    $yesno = &mt('~[Y/n~]');
                    $defaultrun = 1;
                }
            }
        } else {
            if ($action eq 'download') {
                if ($downloadstatus) {
                    print "\n$downloadstatus\n";
                }
            }
            if ($recommended->{$action}) {
                $yesno = mt('~[Y/n~]');
                $defaultrun = 1;
            } else {
                $yesno = &mt('~[y/N~]');
            }
        }
        print $num.'. '.$prompts{$action}." $yesno ";
        $callsub{$action} = &get_user_selection($defaultrun);
    }
}

my $lctarball = 'loncapa-current.tar.gz';
my $sourcetarball = $lctarball;
if ($callsub{'download'}) {
    my ($production,$testing,$sizes) = &download_versionslist();
    if ($production && $testing) {
        if ($production ne $testing) {
            print &mt('Two recent LON-CAPA releases are available: ')."\n".
                  &mt('1.').' '.&mt('A production release - version: [_1].',$production)."\n".
                  &mt('2.').' '.&mt('A testing release - version: [_1].',$testing)."\n\n".
                  &mt('Download the production release? ~[Y/n~]');
            if (&get_user_selection(1)) {
                $sourcetarball = 'loncapa-'.$production.'.tar.gz';
            } else {
                print "\n".&mt('Download the testing release? ~[Y/n~]');
                if (&get_user_selection(1)) {
                    $sourcetarball = 'loncapa-'.$testing.'.tar.gz';
                }
            }
        }
    } elsif ($production) {
        print &mt('The most recent LON-CAPA release is version: [_1].',$production)."\n".
              &mt('Download the production release? ~[Y/n~]');
        if (&get_user_selection(1)) {
            $sourcetarball = 'loncapa-'.$production.'.tar.gz';
        }
    }
} elsif ($filetouse ne '') {
    $sourcetarball = $filetouse;
}

print_and_log("\n");

# Each action: report if skipping, or perform action and provide feedback. 
if ($callsub{'wwwuser'}) {
    &setup_www();
} else {
    &print_and_log(&mt('Skipping creation of user [_1].',"'www'")."\n");
}

if ($callsub{'pwauth'}) {
    &build_and_install_mod_auth_external($instdir);
} else {
    &print_and_log(&mt('Skipping [_1] installation.',"'pwauth'")."\n");
}

if ($callsub{'mysql'}) {
    if ($dbh) {
        &setup_mysql($callsub{'mysqlperms'},$dbh,$has_pass,
                     $mysql_unix_socket,$has_lcdb);
    } else {
        print &mt('Unable to configure MySQL because access is denied.')."\n";
    }
} else {
    &print_and_log(&mt('Skipping configuration of MySQL.')."\n");
    if ($callsub{'mysqlperms'}) {
        if ($dbh) {
            &setup_mysql_permissions($dbh,$has_pass,$mysql_unix_socket);
        } else {
            print &mt('Unable to configure MySQL because access is denied.')."\n";  
        }
    } else {
        &print_and_log(&mt('Skipping MySQL permissions setup.')."\n");
    }
}

if ($dbh) {
    if (!$dbh->disconnect) {
        &print_and_log(&mt('Failed to disconnect from MySQL:')."\n".
                       $dbh->errstr);
    }
}

if ($callsub{'apache'}) {
    if ($distro =~ /^(suse|sles)/) {
        &copy_apache2_suseconf($instdir,$distro);
    } elsif ($distro =~ /^(debian|ubuntu)/) {
        &copy_apache2_debconf($instdir,$distro);
    } else {
        &copy_httpd_conf($instdir,$distro);
        &copy_mpm_conf($instdir,$distro);
    }
} else {
    print_and_log(&mt('Skipping configuration of Apache web server.')."\n");
}

if ($callsub{'runlevels'}) {
    my $count = 0;
    if (ref($recommended) eq 'HASH') {
        if (ref($recommended->{'runlevels'}) eq 'HASH') {
            foreach my $type (keys(%{$recommended->{'runlevels'}})) {
                next if ($type eq 'insserv');
                $count ++;
                my $command = $recommended->{'runlevels'}{$type};
                if ($command ne '') {
                    print_and_log(&mt('Runlevel update command run: [_1].',$command)."\n");
                    system($command);
                }
            }
            if (!$count) {
                print_and_log(&mt('No runlevel updates required.')."\n");
            }  
        }
    }
    if ($distro =~ /^(suse|sles)(\d+)/) {
        unless(($1 eq 'sles') && ($2 >= 15)) {
            &update_SuSEfirewall2_setup($instdir);
        }
    }
} else {
    &print_and_log(&mt('Skipping setting override for start-up order of services.')."\n");
}

if ($callsub{'firewall'}) {
    my ($firewalld,$zone) = &uses_firewalld($distro);
    if ($firewalld) {
        my (%current,%added);
        if (open(PIPE,"firewall-cmd --permanent --zone=$zone --list-services |")) {
            my $svc = <PIPE>;
            close(PIPE);
            chomp($svc);
            map { $current{$_} = 1; } (split(/\s+/,$svc));
        }
        foreach my $service ('http','https') {
            unless ($current{$service}) {
                if (open(PIPE,"firewall-cmd --permanent --zone=$zone --add-service=$service |")) {
                    my $result = <PIPE>;
                    if ($result =~ /^success/) {
                        $added{$service} = 1;
                    }
                }
            }
        }
        if (keys(%added) > 0) {
            print &mt('Firewall configured to allow access for: [_1].',
                      join(', ',sort(keys(%added))))."\n";
            system('firewall-cmd --reload');
        }
        if ($current{'http'} || $current{'https'}) {
            print &mt('Firewall already configured to allow access for:[_1].',
                      (($current{'http'})? ' http':'').(($current{'https'})? ' https':''))."\n";
        }
        unless ($current{'ssh'}) {
            print &mt('If you would like to allow access to ssh from outside, use the commands:')."\n".
                  "firewall-cmd --permanent --zone=$zone --add-service=ssh\n".
                  "firewall-cmd --reload\n";
        }
    } elsif ($distro =~ /^(suse|sles)/) {
        print &mt('Use [_1] to configure the firewall to allow access for [_2].',
                  'yast -- Security and Users -> Firewall -> Interfaces',
                  'ssh, http, https')."\n";
    } elsif ($distro =~ /^(debian|ubuntu)(\d+)/) {
        if (($1 eq 'ubuntu') || ($2 > 5)) {
            print &mt('Use [_1] to configure the firewall to allow access for [_2].',
                      'ufw','ssh, http, https')."\n";
        } else {
            my $fwadded = &get_iptables_rules($distro,$instdir,$apachefw);
            if ($fwadded) {
                print &mt('Enable firewall? ~[Y/n~]');
                my $enable_iptables = &get_user_selection(1);
                if ($enable_iptables) {
                    system('/etc/network/if-pre-up.d/iptables');
                    print &mt('Firewall enabled using rules defined in [_1].',
                              '/etc/iptables.loncapa.rules'); 
                }
            }
        }
    } elsif ($distro =~ /^(scientific|oracle)/) {
        print &mt('Use [_1] to configure the firewall to allow access for [_2].',
                  'system-config-firewall-tui -- Customize',
                  'ssh, http')."\n";
    } else {
        my $version;
        if ($distro =~ /^(redhat|centos)(\d+)$/) {
            $version = $1;
        }
        if ($version > 5) {
            print &mt('Use [_1] to configure the firewall to allow access for [_2].',
                  'system-config-firewall-tui -- Customize',
                  'ssh, http')."\n";
        } else {
            print &mt('Use [_1] to configure the firewall to allow access for [_2].',
                      'setup -- Firewall configuration -> Customize',
                      'ssh, http, https')."\n";
        }
    }
} else {
    &print_and_log(&mt('Skipping Firewall configuration.')."\n");
}

if ($callsub{'stopsrvcs'}) {
    &kill_extra_services($distro,$recommended->{'stopsrvcs'},$uses_systemctl);
} else {
    &print_and_log(&mt('Skipping stopping unnecessary service ([_1] daemons).',"'cups','memcached'")."\n");
}

my ($have_tarball,$updateshown);
if ($callsub{'download'}) {
    ($have_tarball,$updateshown) = &download_loncapa($instdir,$sourcetarball);
} else {
    print_and_log(&mt('Skipping download of LON-CAPA tar file.')."\n\n");
    print &mt('LON-CAPA is available for download from: [_1]',
              'http://install.loncapa.org/')."\n";
    if (!-e '/etc/loncapa-release') {
        &print_and_log(&mt('LON-CAPA is not yet installed on your system.'). 
                       "\n\n". 
                       &mt('You may retrieve the source for LON-CAPA by executing:')."\n".
                       "wget http://install.loncapa.org/versions/$lctarball\n");
    } else {
        my $currentversion;
        if (open(my $fh,"</etc/loncapa-release")) {
            my $version = <$fh>;
            chomp($version);
            if ($version =~ /^\QLON-CAPA release \E([\w\-.]+)$/) {
                $currentversion = $1;
            }
        }
        if ($currentversion ne '') {
            print &mt('Version of LON-CAPA currently installed on this server is: [_1].',
                      $currentversion),"\n";
            if ($production) {
                print &mt('The latest production release of LON-CAPA is [_1].',$production)."\n";
            }
            if ($testing) {
                print &mt('The latest testing release of LON-CAPA is [_1].',$testing)."\n";
            }
        }
    }
    if ($filetouse ne '') {
        $have_tarball = 1;
    }
}

print "\n".&mt('Requested configuration complete.')."\n\n";
if ($have_tarball && !$updateshown) {
    my ($lcdir) = ($sourcetarball =~ /^([\w.\-]+)\.tar.gz$/);
    my ($apachename,$lc_uses_systemctl,$uses_sudo);
    if ($distro =~ /^(suse|sles|debian|ubuntu)([\d.]+)/) {
        if (($1 eq 'suse') && ($2 < 10)) {
            $apachename = 'apache';
        } else {
            $apachename = 'apache2';
        }
    } else {
        $apachename = 'httpd';
    }
    if ($distro =~ /^oracle(\d+)$/) {
        if ($1 > 6) {
            $lc_uses_systemctl = 1;
        }
    } elsif ($distro =~ /^(?:rhes|centos)(\d+)$/) {
        if ($1 > 7) {
            $lc_uses_systemctl = 1;
        }
    } elsif ($distro =~ /^ubuntu(\d+)$/) {
        if ($1 > 16) {
            $lc_uses_systemctl = 1;
        }
        $uses_sudo = 1;
    } elsif ($distro =~ /^sles(\d+)$/) {
        if ($1 > 12) {
            $lc_uses_systemctl = 1;
        }
    }
    if (!-e '/etc/loncapa-release') {
        print &mt('If you are now ready to install LON-CAPA, enter the following commands:')."\n\n";
    } else {
        my $lcstop = '/etc/init.d/loncontrol stop';
        if ($lc_uses_systemctl) {
            $lcstop = 'systemctl stop loncontrol';
        }
        my $apachestop = "/etc/init.d/$apachename stop";
        if ($uses_systemctl) {
            $apachestop = "systemctl stop $apachename";
        }
        if ($uses_sudo) {
            $lcstop = 'sudo '.$lcstop;	 
            $apachestop = 'sudo '.$apachestop;
        }
        print &mt('If you are now ready to update LON-CAPA, enter the following commands:').
              "\n\n$lcstop\n$apachestop\n";
    }
    print "cd /root\n".
          "tar zxf $sourcetarball\n".
          "cd $lcdir\n".
          "./UPDATE\n";
    if (-e '/etc/loncapa-release') {
        my $lcstart = '/etc/init.d/loncontrol start';     
        if ($lc_uses_systemctl) {
            $lcstart = '/home/httpd/perl/loncontrol start';
        }
        my $apachestart = "/etc/init.d/$apachename start";
        if ($uses_systemctl) {
            $apachestart = "systemctl start $apachename";
        }
        if ($uses_sudo) {
            $lcstart = 'sudo '.$lcstart;
            $apachestart = 'sudo '.$apachestart;
        }
        print "$lcstart\n";
        print "$apachestart\n";
    }
}
exit;

#
# End main script
#

#
# Routines for the actions
#
 
sub setup_www {
    ##
    ## Set up www
    ##
    print_and_log(&mt('Creating user [_1]',"'www'")."\n");
    # -- Add group

    my $status = `/usr/sbin/groupadd www`;
    if ($status =~ /\QGroup `www' already exists.\E/) {
        print &mt('Group [_1] already exists.',"'www'")."\n";
    } elsif ($status ne '') {
        print &mt('Unable to add group [_1].',"'www'")."\n";
    }
   
    my $gid = getgrnam('www');

    if (open (PIPE, "/usr/sbin/useradd -c LONCAPA -g $gid www 2>&1 |")) {
        $status = <PIPE>;
        close(PIPE);
        chomp($status);
        if ($status =~ /\QAccount `www' already exists.\E/) {
            print &mt('Account [_1] already exists.',"'www'")."\n";
        } elsif ($status ne '') {
            print &mt('Unable to add user [_1].',"'www'")."\n";
        }
    }  else {
        print &mt('Unable to run command to add user [_1].',"'www'")."\n";
    }

    my $uid = &uid_of_www();
    if (($gid ne '') && ($uid ne '')) {
        if (!-e '/home/www') {
            mkdir('/home/www',0755);
            system('chown www:www /home/www');
        }
    }
    writelog ($status);
}

sub uid_of_www {
    my ($num) = (getpwnam('www'))[2];
    return $num;
}

sub build_and_install_mod_auth_external {
    my ($instdir) = @_;
    my $num = &uid_of_www();
    # Patch pwauth
    print_and_log(&mt('Building authentication system for LON-CAPA users.')."\n");
    my $patch = <<"ENDPATCH";
148c148
< #define SERVER_UIDS 99		/* user "nobody" */
---
> #define SERVER_UIDS $num		/* user "www" */
ENDPATCH

    if (! -e "/usr/bin/patch") {
	print_and_log(&mt('You must install the software development tools package: [_1], when installing Linux.',"'patch'")."\n");
        print_and_log(&mt('Authentication installation not completed.')."\n");
        return;
    }
    if (&skip_if_nonempty(`cd /tmp; tar zxf $instdir/pwauth-2.2.8.tar.gz`,
		     &mt('Unable to extract pwauth')."\n")) {
        return;
    }
    my $dir = "/tmp/pwauth-2.2.8";
    if (open(PATCH,"| patch $dir/config.h")) {
        print PATCH $patch;
        close(PATCH);
        print_and_log("\n");
        ##
        ## Compile patched pwauth
        ##
        print_and_log(&mt('Compiling pwauth')."\n");
        my $result = `cd $dir/; make 2>/dev/null `;
        my $expected = <<"END";
gcc -g    -c -o pwauth.o pwauth.c
gcc -o pwauth -g  pwauth.o -lcrypt
END
        if ($result eq $expected) {
            print_and_log(&mt('Apparent success compiling pwauth:').
                          "\n".$result );
            # Install patched pwauth
            print_and_log(&mt('Copying pwauth to [_1]',' /usr/local/sbin')."\n");
            if (copy "$dir/pwauth","/usr/local/sbin/pwauth") {
                if (chmod(06755, "/usr/local/sbin/pwauth")) {
                    print_and_log(&mt('[_1] copied successfully',"'pwauth'").
                                  "\n");
                } else {
                    print &mt('Unable to set permissions on [_1].'.
                              "/usr/local/sbin/pwauth")."\n";
                }
            } else {
                print &mt('Unable to copy [_1] to [_2]',
                          "'$dir/pwauth'","/usr/local/sbin/pwauth")."\n$!\n";
            }
        } else {
            print &mt('Unable to compile patched [_1].'."'pwauth'")."\n";
        }
    } else {
        print &mt('Unable to start patch for [_1]',"'pwauth'")."\n";
    }
    print_and_log("\n");
}

sub kill_extra_services {
    my ($distro,$stopsrvcs,$uses_systemctl) = @_;
    if (ref($stopsrvcs) eq 'HASH') {
        my @stopping = sort(keys(%{$stopsrvcs}));
        if (@stopping) {
            my $kill_list = join("', '",@stopping);
            if ($kill_list) {
                $kill_list = "'".$kill_list."'";
                &print_and_log("\n".&mt('Killing unnecessary services ([_1] daemon(s)).',$kill_list)."\n");
                foreach my $service (@stopping) {
                    my $daemon = $service;
                    if ($service eq 'cups') {
                        $daemon = 'cupsd';
                        if ($distro =~ /^(?:debian|ubuntu)(\d+)/) {
                            my $version = $1;
                            if (($distro =~ /^ubuntu/) && ($version <= 8)) {
                                $daemon = 'cupsys';
                            }
                        } else {
                            $daemon = 'cups';
                        }
                    }
                    my $cmd = "ps -ef |grep '$daemon' |grep -v grep";
                    if (open(PIPE,'-|',$cmd)) {
                        my $daemonrunning = <PIPE>;
                        chomp($daemonrunning);
                        close(PIPE);
                        if ($daemonrunning) {
                            &print_and_log(`/etc/init.d/$daemon stop`);
                        }
                    }
	            &print_and_log(&mt('Removing [_1] from startup.',$service)."\n");
                    if ($distro =~ /^(?:debian|ubuntu)(\d+)/) {
                        my $version = $1;
                        if (($distro =~ /^ubuntu/) && ($version > 16)) {
                            if (ref($uses_systemctl) eq 'HASH') {
                                if ($uses_systemctl->{$service}) {
                                    if (`systemctl is-enabled $service`) {
                                        &print_and_log(`systemctl disable $service`);
                                    }
                                }
                            }
                        } else {
                            &print_and_log(`update-rc.d -f $daemon remove`);
                        }
                    } else {
                        if (ref($uses_systemctl) eq 'HASH') {
                            if ($uses_systemctl->{$service}) {
                                if (`systemctl is-enabled $service`) {                          
                                    &print_and_log(`systemctl disable $service`);
                                }
                            } else {
                                &print_and_log(`/sbin/chkconfig --del $service`);
                            }
                        } else {
	                    &print_and_log(`/sbin/chkconfig --del $service`);
                        } 
                    }
                }
            }
        }
    }
    return;
}

sub setup_mysql {
    my ($setup_mysql_permissions,$dbh,$has_pass,$mysql_unix_socket,$has_lcdb) = @_;
    my @mysql_lc_commands;
    unless ($has_lcdb) {
        push(@mysql_lc_commands,"CREATE DATABASE loncapa");
    }
    push(@mysql_lc_commands,"USE loncapa");
    push(@mysql_lc_commands,qq{
CREATE TABLE IF NOT EXISTS metadata (title TEXT, author TEXT, subject TEXT, url TEXT, keywords TEXT, version TEXT, notes TEXT, abstract TEXT, mime TEXT, language TEXT, creationdate DATETIME, lastrevisiondate DATETIME, owner TEXT, copyright TEXT, domain TEXT, dependencies TEXT, modifyinguser TEXT, authorspace TEXT, lowestgradelevel TEXT, highestgradelevel TEXT, standards TEXT, count INT, course INT, course_list TEXT, goto INT, goto_list TEXT, comefrom INT, comefrom_list TEXT, sequsage INT, sequsage_list TEXT, stdno INT, stdno_list TEXT, avetries FLOAT, avetries_list TEXT, difficulty FLOAT, difficulty_list TEXT, disc FLOAT, disc_list TEXT, clear FLOAT, technical FLOAT, correct FLOAT, helpful FLOAT, depth FLOAT, hostname TEXT, FULLTEXT idx_title (title), FULLTEXT idx_author (author), FULLTEXT idx_subject (subject), FULLTEXT idx_url (url), FULLTEXT idx_keywords (keywords), FULLTEXT idx_version (version), FULLTEXT idx_notes (notes), FULLTEXT idx_abstract (abstract), FULLTEXT idx_mime (mime), FULLTEXT idx_language (language), FULLTEXT idx_owner (owner), FULLTEXT idx_copyright (copyright)) ENGINE=MYISAM
});
    if ($setup_mysql_permissions) {
        &setup_mysql_permissions($dbh,$has_pass,$mysql_unix_socket,@mysql_lc_commands);
    } else {
        print_and_log(&mt('Skipping MySQL permissions setup.')."\n");
        if ($dbh) {
            if (@mysql_lc_commands) {
                foreach my $lccmd (@mysql_lc_commands) { 
                    $dbh->do($lccmd) || print $dbh->errstr."\n";
                }
            }
            print_and_log(&mt('MySQL database set up complete.')."\n");
        } else {
            print_and_log(&mt('Problem accessing MySQL.')."\n");
        }
    }
}

sub setup_mysql_permissions {
    my ($dbh,$has_pass,$mysql_unix_socket,@mysql_lc_commands) = @_;
    my ($mysqlversion,$mysqlsubver,$mysqlname) = &get_mysql_version();
    my ($usescreate,$usesauth,$is_mariadb,$hasauthcol,@mysql_commands);
    if ($mysqlname =~ /^MariaDB/i) {
        $is_mariadb = 1;
        if ($mysqlversion >= 10.4) {
            $usescreate = 1;
        } elsif ($mysqlversion >= 10.2) {
            $usesauth = 1;
        } elsif ($mysqlversion >= 5.5) {
            $hasauthcol = 1;
        }
    } else {
        if (($mysqlversion > 5.7) || (($mysqlversion == 5.7) && ($mysqlsubver > 5))) {
            $usesauth = 1;
        } elsif (($mysqlversion >= 5.6) || (($mysqlversion == 5.5) && ($mysqlsubver >= 7))) {
            $hasauthcol = 1;
        }
    }
    if ($usescreate) {
        @mysql_commands = ("CREATE USER 'www'\@'localhost' IDENTIFIED BY 'localhostkey'");
    } elsif ($usesauth) {
        @mysql_commands = ("INSERT user (Host, User, ssl_cipher, x509_issuer, x509_subject, authentication_string) VALUES('localhost','www','','','','')");
        if ($is_mariadb) {
            push(@mysql_commands,"ALTER USER 'www'\@'localhost' IDENTIFIED BY 'localhostkey'");
        } else {
            push(@mysql_commands,"ALTER USER 'www'\@'localhost' IDENTIFIED WITH mysql_native_password BY 'localhostkey'");
        }
    } elsif ($hasauthcol) {
        @mysql_commands = ("INSERT user (Host, User, Password, ssl_cipher, x509_issuer, x509_subject, authentication_string) VALUES('localhost','www',password('localhostkey'),'','','','');");
    } else {
        @mysql_commands = ("INSERT user (Host, User, Password, ssl_cipher, x509_issuer, x509_subject) VALUES('localhost','www',password('localhostkey'),'','','');");
    }
    if ($mysqlversion < 4) {
        push (@mysql_commands,"
INSERT db (Host,Db,User,Select_priv,Insert_priv,Update_priv,Delete_priv,Create_priv,Drop_priv,Grant_priv,References_priv,Index_priv,Alter_priv) VALUES('localhost','loncapa','www','Y','Y','Y','Y','Y','Y','N','Y','Y','Y')");
    } else {
        push (@mysql_commands,"
INSERT db (Host,Db,User,Select_priv,Insert_priv,Update_priv,Delete_priv,Create_priv,Drop_priv,Grant_priv,References_priv,Index_priv,Alter_priv,Create_tmp_table_priv,Lock_tables_priv) VALUES('localhost','loncapa','www','Y','Y','Y','Y','Y','Y','N','Y','Y','Y','Y','Y')");
    }
    push(@mysql_commands,"DELETE FROM user WHERE host<>'localhost'");
    if (($has_pass) || ($mysql_unix_socket)) {
        if ($dbh) {
            push(@mysql_commands,"FLUSH PRIVILEGES");
            if (@mysql_commands) {
                foreach my $cmd (@mysql_commands) {
                    $dbh->do($cmd) || print $dbh->errstr."\n";
                }
            }
            if (@mysql_lc_commands) {
                foreach my $lccmd (@mysql_lc_commands) {
                    $dbh->do($lccmd) || print $dbh->errstr."\n";
                }
            }
            print_and_log(&mt('Permissions set for LON-CAPA MySQL user: [_1]',"'www'")."\n");
        } else {
            print_and_log(&mt('Problem accessing MySQL.')."\n".
                          &mt('Permissions not set.')."\n");
        }
    } else {
        my ($firstpass,$secondpass,$got_passwd,$newmysqlpass);
        print &mt('Please enter a root password for the mysql database.')."\n".
              &mt('It does not have to match your root account password, but you will need to remember it.')."\n";
        my $maxtries = 10;
        my $trial = 0;
        while ((!$got_passwd) && ($trial < $maxtries)) {
            $firstpass = &get_mysql_password(&mt('Enter password'));
            if (length($firstpass) > 5) { 
                $secondpass = &get_mysql_password(&mt('Enter password a second time'));
                if ($firstpass eq $secondpass) {
                    $got_passwd = 1;
                    $newmysqlpass = $firstpass;
                } else {
                    print(&mt('Passwords did not match. Please try again.')."\n");
                }
                $trial ++;
            } else {
                print(&mt('Password too short.')."\n".
                      &mt('Please choose a password with at least six characters.')."\n");
            }
        }
        if ($got_passwd) {
            my (@newpass_cmds) = &new_mysql_rootpasswd($newmysqlpass,$usesauth,$is_mariadb);
            push(@mysql_commands,@newpass_cmds);
        } else {
            print_and_log(&mt('Failed to get MySQL root password from user input.')."\n");
        }
        if ($dbh) {
            if (@mysql_commands) {
                foreach my $cmd (@mysql_commands) {
                    $dbh->do($cmd) || print $dbh->errstr."\n";
                }
            }
            if (@mysql_lc_commands) {
                foreach my $lccmd (@mysql_lc_commands) {
                    $dbh->do($lccmd) || print $dbh->errstr."\n";
                }
            }
            if ($got_passwd) {
                print_and_log(&mt('MySQL root password stored.')."\n".
                              &mt('Permissions set for LON-CAPA MySQL user: [_1].',"'www'")."\n");
            } else {
                print_and_log(&mt('Permissions set for LON-CAPA MySQL user: [_1].',"'www'")."\n");
            }
        } else {
            print_and_log(&mt('Problem accessing MySQL.')."\n".
                          &mt('Permissions not set.')."\n");
        }
    }
}

sub new_mysql_rootpasswd {
    my ($currmysqlpass,$usesauth,$is_mariadb) = @_;
    if ($usesauth) {
        if ($is_mariadb) {
            return ("ALTER USER 'root'\@'localhost' IDENTIFIED BY '$currmysqlpass'",
                    "FLUSH PRIVILEGES;");
        } else {
            return ("ALTER USER 'root'\@'localhost' IDENTIFIED WITH mysql_native_password BY '$currmysqlpass'",
                    "FLUSH PRIVILEGES;");
        }
    } else {
        return ("SET PASSWORD FOR 'root'\@'localhost'=PASSWORD('$currmysqlpass')",
                "FLUSH PRIVILEGES;");
    }
}

sub get_mysql_version {
    my ($version,$subversion,$name);
    if (open(PIPE," mysql -V |")) {
        my $info = <PIPE>;
        chomp($info);
        close(PIPE);
        ($version,$subversion,$name) = ($info =~ /(\d+\.\d+)\.(\d+)(?:\-?(\w*),|)/);
    } else {
        print &mt('Could not determine which version of MySQL is installed.').
              "\n";
    }
    return ($version,$subversion,$name);
}

###########################################################
##
## RHEL/CentOS/Fedora/Scientific Linux
## Copy LON-CAPA httpd.conf to /etc/httpd/conf
##
###########################################################

sub copy_httpd_conf {
    my ($instdir,$distro) = @_;
    my $configfile = 'httpd.conf';
    if ($distro =~ /^(?:centos|rhes|scientific|oracle)(\d+)$/) {
        if ($1 >= 7) {
            $configfile = 'apache2.4/httpd.conf';
        } elsif ($1 > 5) {
            $configfile = 'new/httpd.conf';
        }
    } elsif ($distro =~ /^fedora(\d+)$/) {
        if ($1 > 17) {
            $configfile = 'apache2.4/httpd.conf';
        } elsif ($1 > 10) {
            $configfile = 'new/httpd.conf';
        }
    }
    print_and_log(&mt('Copying the LON-CAPA [_1] to [_2].',"'httpd.conf'",
                  "'/etc/httpd/conf/httpd.conf'")."\n");
    copy "/etc/httpd/conf/httpd.conf","/etc/httpd/conf/httpd.conf.original";
    copy "$instdir/centos-rhes-fedora-sl/$configfile","/etc/httpd/conf/httpd.conf";
    chmod(0444,"/etc/httpd/conf/httpd.conf");
    print_and_log("\n");
}

###########################################################
##
## RHEL/CentOS/Fedora/Scientific Linux
## Copy LON-CAPA mpm.conf to /etc/httpd/conf.modules.d/00-mpm.conf
##
## The LON-CAPA mpm.conf enables the prefork MPM module in
## Apache. This is also the default for RHEL/CentOS/Oracle
## Linux 7 and earlier, and Fedora 26 and earlier. For more
## recent versions of those distros, the event MPM is enabled
## by default. After &copy_mpm_conf() is run, the prefork MPM
## module will be enabled instead of the event MPM module.
##
###########################################################

sub copy_mpm_conf {
    my ($instdir,$distro) = @_;
    my $mpmfile = 'mpm.conf';
    if ((-e "/etc/httpd/conf.modules.d/00-mpm.conf") &&
        (-e "$instdir/centos-rhes-fedora-sl/$mpmfile")) {
        print_and_log(&mt('Copying the LON-CAPA [_1] to [_2].',"'mpm.conf'",
                      "'/etc/httpd/conf.modules.d/00-mpm.conf'")."\n");
        copy "$instdir/centos-rhes-fedora-sl/$mpmfile","/etc/httpd/conf.modules.d/00-mpm.conf";
        chmod(0644,"/etc/httpd/conf.modules.d/00-mpm.conf");
        print_and_log("\n");
    } else {
        my $logfail;
        if ($distro =~ /^(?:centos|rhes|scientific|oracle)(\d+)$/) {
            if ($1 > 7) {
                $logfail = 1;
            }
        } elsif ($distro =~ /^fedora(\d+)$/) {
            if ($1 > 26) {
                $logfail = 1;
            }
        }
        if ($logfail) {
            print_and_log(&mt('Warning: copying the LON-CAPA [_1] failed because [_2] and/or [_3] are missing.',
                              $mpmfile,"'$instdir/centos-rhes-fedora-sl/$mpmfile'",
                              "'/etc/httpd/conf.modules.d/00-mpm.conf'"));
            print_and_log("\n");
        }
    }
}

#########################################################
##
## Ubuntu/Debian -- copy our loncapa configuration file to
## sites-available and set the symlink from sites-enabled.
##
#########################################################

sub copy_apache2_debconf {
    my ($instdir,$distro) = @_;
    my $apache2_mods_enabled_dir = '/etc/apache2/mods-enabled';
    my $apache2_mods_available_dir = '/etc/apache2/mods-available';
    foreach my $module ('headers.load','expires.load') {
        unless (-l "$apache2_mods_enabled_dir/$module") {
            symlink("$apache2_mods_available_dir/$module","$apache2_mods_enabled_dir/$module");
            print_and_log(&mt('Enabling "[_1]" Apache module.',$module)."\n");
        }
    }
    my $apache2_sites_enabled_dir = '/etc/apache2/sites-enabled';
    my $apache2_sites_available_dir = '/etc/apache2/sites-available';
    my $defaultconfig = "$apache2_sites_enabled_dir/000-default";
    my $defaultsite = "$apache2_sites_enabled_dir/loncapa.conf";
    my ($distname,$version);
    if ($distro =~ /^(debian|ubuntu)(\d+)$/) {
        $distname = $1;
        $version = $2;
    }
    if (($distname eq 'ubuntu') && ($version > 12)) {
        $defaultconfig = "$apache2_sites_enabled_dir/000-default.conf";
    }
    my ($skipconf,$skipsite,$skipstatus);
    if (($distname eq 'ubuntu') && ($version > 12)) {
        my $apache2_conf_enabled_dir = '/etc/apache2/conf-enabled';
        my $apache2_conf_available_dir = '/etc/apache2/conf-available';
        my $defaultconf = $apache2_conf_enabled_dir.'/loncapa.conf';
        if ((-e "$apache2_conf_available_dir/loncapa") && (-e "$instdir/debian-ubuntu/ubuntu14/loncapa_conf")) {
            if (open(PIPE, "diff --brief $apache2_conf_available_dir/loncapa $instdir/debian-ubuntu/ubuntu14/loncapa_conf |")) {
                my $diffres = <PIPE>;
                close(PIPE);
                chomp($diffres);
                if ($diffres) {
                    copy("$apache2_conf_available_dir/loncapa","$apache2_conf_available_dir/loncapa.conf.original");
                } else {
                    copy("$apache2_conf_available_dir/loncapa","$apache2_conf_available_dir/loncapa.conf");
                    chdir($apache2_conf_enabled_dir);
                    symlink('../conf-available/loncapa.conf','loncapa.conf');
                    chdir($instdir);
                }
                if (-l $defaultconf) {
                    my $linkfname = readlink($defaultconf);
                    if ($linkfname ne '') {
                        $linkfname = Cwd::abs_path(File::Spec->rel2abs($linkfname,$apache2_conf_enabled_dir));
                    }
                    if ($linkfname eq "$apache2_conf_available_dir/loncapa") {
                        unlink($defaultconf);
                    }
                }
                unlink("$apache2_conf_available_dir/loncapa");
            }
        }
        if ((-e "$apache2_conf_available_dir/loncapa.conf") && (-e "$instdir/debian-ubuntu/ubuntu14/loncapa_conf")) {
            if (open(PIPE, "diff --brief $apache2_conf_available_dir/loncapa.conf $instdir/debian-ubuntu/ubuntu14/loncapa_conf |")) {
                my $diffres = <PIPE>;
                close(PIPE);
                chomp($diffres);
                if ($diffres) {
                    copy("$apache2_conf_available_dir/loncapa.conf","$apache2_conf_available_dir/loncapa.conf.original");
                }
                if (-l $defaultconf) {
                    my $linkfname = readlink($defaultconf);
                    if ($linkfname ne '') {
                        $linkfname = Cwd::abs_path(File::Spec->rel2abs($linkfname,$apache2_conf_enabled_dir));
                    }
                    if ($linkfname eq "$apache2_conf_available_dir/loncapa.conf") {
                        unless ($diffres) {
                            $skipconf = 1;
                        }
                    }
                }
            }
        }
        unless ($skipconf) {
            print_and_log(&mt('Copying loncapa [_1] config file to [_2] and pointing [_3] to it from conf-enabled.',"'apache2'","'/etc/apache2/conf-available'","'loncapa.conf symlink'")."\n");
            copy("$instdir/debian-ubuntu/ubuntu14/loncapa_conf","$apache2_conf_available_dir/loncapa.conf");
            chmod(0444,"$apache2_conf_available_dir/loncapa.conf");
            if (-l $defaultconf) {
                unlink($defaultconf);
            }
            chdir($apache2_conf_enabled_dir);
            symlink('../conf-available/loncapa.conf','loncapa.conf');
            chdir($instdir);
        }
        my $stdsite = "$instdir/debian-ubuntu/ubuntu14/loncapa_site";
        if ((-e $stdsite) && (-e "$apache2_sites_available_dir/loncapa")) {
            if (open(PIPE, "diff --brief $stdsite $apache2_sites_available_dir/loncapa |")) {
                my $diffres = <PIPE>;
                close(PIPE);
                chomp($diffres);
                if ($diffres) {
                    copy("$apache2_sites_available_dir/loncapa","$apache2_sites_available_dir/loncapa.conf.original");
                } else {
                    copy("$apache2_sites_available_dir/loncapa","$apache2_sites_available_dir/loncapa.conf");
                }
                if (-l $defaultconfig) {
                    my $linkfname = readlink($defaultconfig);
                    if ($linkfname ne '') {
                        $linkfname = Cwd::abs_path(File::Spec->rel2abs($linkfname,$apache2_sites_enabled_dir));
                    }
                    if ($linkfname eq "$apache2_sites_available_dir/loncapa") {
                        unlink($defaultconfig);
                    }
                }
                unlink("$apache2_sites_available_dir/loncapa");
            }
        }
        if ((-e $stdsite) && (-e "$apache2_sites_available_dir/loncapa.conf")) {
            if (open(PIPE, "diff --brief $stdsite $apache2_sites_available_dir/loncapa.conf |")) {
                my $diffres = <PIPE>;
                close(PIPE);
                chomp($diffres);
                if ($diffres) {
                    copy("$apache2_sites_available_dir/loncapa.conf","$apache2_sites_available_dir/loncapa.conf.original");
                }
                if (-l $defaultsite) {
                    my $linkfname = readlink($defaultsite);
                    if ($linkfname ne '') {
                        $linkfname = Cwd::abs_path(File::Spec->rel2abs($linkfname,$apache2_sites_enabled_dir));
                    }
                    if ($linkfname eq "$apache2_sites_available_dir/loncapa.conf") {
                        unless ($diffres) {
                            $skipsite = 1;
                        }
                    }
                }
            }
        }
        unless ($skipsite) {
            print_and_log(&mt('Copying loncapa [_1] site file to [_2] and pointing [_3] to it from sites-enabled.',"'apache2'","'/etc/apache2/sites-available'","'loncapa.conf symlink'")."\n");
            copy("$instdir/debian-ubuntu/ubuntu14/loncapa_site","$apache2_sites_available_dir/loncapa.conf");
            chmod(0444,"$apache2_sites_available_dir/loncapa.conf");
            chdir($apache2_sites_enabled_dir);
            symlink('../sites-available/loncapa.conf','loncapa.conf');
            chdir($instdir);
        }
        if (-l $defaultconfig) {
            my $linkfname = readlink($defaultconfig);
            if ($linkfname ne '') {
                $linkfname = Cwd::abs_path(File::Spec->rel2abs($linkfname,$apache2_sites_enabled_dir));
            }
            if ($linkfname eq "$apache2_sites_available_dir/000-default.conf") {
                unlink($defaultconfig);
            }
        }
    } else {
        if ((-e "$instdir/debian-ubuntu/loncapa") && (-e "$apache2_sites_available_dir/loncapa")) {
            if (open(PIPE, "diff --brief $instdir/debian-ubuntu/loncapa $apache2_sites_available_dir/loncapa |")) {
                my $diffres = <PIPE>;
                close(PIPE);
                chomp($diffres);
                if ($diffres) {
                    copy("$apache2_sites_available_dir/loncapa","$apache2_sites_available_dir/loncapa.original");
                }
                if (-l $defaultconfig) {
                    my $linkfname = readlink($defaultconfig);
                    if ($linkfname eq "$apache2_sites_available_dir/loncapa") {
                        unless ($diffres) {
                            $skipsite = 1;
                        }
                    }
                }
            }
        }
        unless ($skipsite) {
            if (-l $defaultconfig) {
                unlink($defaultconfig);
            }
            print_and_log(&mt('Copying loncapa [_1] config file to [_2] and pointing [_3] to it from sites-enabled.',"'apache2'","'/etc/apache2/sites-available'","'000-default symlink'")."\n");
            if (-e "$instdir/debian-ubuntu/loncapa") {
                copy("$instdir/debian-ubuntu/loncapa","$apache2_sites_available_dir/loncapa");
                chmod(0444,"$apache2_sites_available_dir/loncapa");
                symlink("$apache2_sites_available_dir/loncapa","$apache2_sites_enabled_dir/000-default");
            }
        }
    }
    if ($distname eq 'ubuntu') {
        my $sitestatus = "$apache2_mods_available_dir/status.conf";
        my $stdstatus = "$instdir/debian-ubuntu/status.conf";
        if ((-e $sitestatus) && (-e $stdstatus)) {
            if (open(PIPE, "diff --brief $stdstatus $sitestatus |")) {
                my $diffres = <PIPE>;
                close(PIPE);
                chomp($diffres);
                if ($diffres) {
                    copy("$apache2_mods_available_dir/status.conf","$apache2_mods_available_dir/status.conf.original");
                } else {
                    $skipstatus = 1;
                }
            }
        }
        unless ($skipstatus) {
            if (-e $stdstatus) {
                print_and_log(&mt('Copying loncapa [_1] file to [_2],',"'status.conf'","'/etc/apache2/mods-available/status.conf'")."\n");
                copy($stdstatus,$sitestatus);
                chmod(0644,$sitestatus);
            }
        }
    }
    print_and_log("\n");
}

###########################################################
##
## openSuSE/SLES Copy apache2 config files:
##   default-server.conf, uid.conf, /etc/sysconfig/apache2 
##   and create symlink from /srv/www/conf to /etc/apache2 
##
###########################################################

sub copy_apache2_suseconf {
    my ($instdir,$distro) = @_;
    my ($name,$version) = ($distro =~ /^(suse|sles)([\d\.]+)$/);
    my $conf_file = "$instdir/sles-suse/default-server.conf";
    if (($name eq 'sles') && ($version >= 12)) {
        $conf_file = "$instdir/sles-suse/apache2.4/default-server.conf";
    }
    print_and_log(&mt('Copying the LON-CAPA [_1] to [_2].',
                  "'default-server.conf'",
                  "'/etc/apache2/default-server.conf'")."\n");
    if (!-e "/etc/apache2/default-server.conf.original") {
        copy "/etc/apache2/default-server.conf","/etc/apache2/default-server.conf.original";
    }
    copy $conf_file,"/etc/apache2/default-server.conf";
    chmod(0444,"/etc/apache2/default-server.conf");
    # Make symlink for conf directory (included in loncapa_apache.conf)
    my $can_symlink = (eval { symlink('/etc/apache2','/srv/www/conf'); }, $@ eq '');
    if ($can_symlink) {
        &print_and_log(&mt('Symlink created for [_1] to [_2].',
                       "'/srv/www/conf'","'/etc/apache2'")."\n");
    } else {
        &print_and_log(&mt('Symlink creation failed for [_1] to [_2]. You will need to perform this action from the command line.',"'/srv/www/conf'","'/etc/apache2'")."\n");
    }
    &copy_apache2_conf_files($instdir);
    &copy_sysconfig_apache2_file($instdir,$name,$version); 
    print_and_log("\n");
}

###############################################
##
## Modify uid.conf
##
###############################################
sub copy_apache2_conf_files {
    my ($instdir) = @_;
    print_and_log(&mt('Copying the LON-CAPA [_1] to [_2].',
                  "'uid.conf'","'/etc/apache2/uid.conf'")."\n");
    if (!-e "/etc/apache2/uid.conf.original") {
        copy "/etc/apache2/uid.conf","/etc/apache2/uid.conf.original";
    }
    copy "$instdir/sles-suse/uid.conf","/etc/apache2/uid.conf";
    chmod(0444,"/etc/apache2/uid.conf");
}

###############################################
##
## Modify /etc/sysconfig/apache2  
##
###############################################
sub copy_sysconfig_apache2_file {
    my ($instdir,$name,$version) = @_;
    print_and_log(&mt('Copying the LON-CAPA [_1] to [_2].',"'sysconfig/apache2'","'/etc/sysconfig/apache2'")."\n");
    if (!-e "/etc/sysconfig/apache2.original") {
        copy "/etc/sysconfig/apache2","/etc/sysconfig/apache2.original";
    }
    my $sysconf_file = "$instdir/sles-suse/sysconfig_apache2";
    if (($name eq 'sles') && ($version >= 12)) {
       $sysconf_file = "$instdir/sles-suse/apache2.4/sysconfig_apache2";
    }
    copy $sysconf_file,"/etc/sysconfig/apache2";
    chmod(0444,"/etc/sysconfig/apache2");
}

###############################################
##
## Add/Modify /etc/insserv/overrides
##
###############################################

sub update_SuSEfirewall2_setup {
    my ($instdir) = @_;
    print_and_log(&mt('Copying the LON-CAPA [_1] to [_2].',"'SuSEfirewall2_setup'","'/etc/insserv/overrides/SuSEfirewall2_setup'")."\n");
    if (!-e "/etc/insserv/overrides/SuSEfirewall2_setup") {
        if (!-d "/etc/insserv") {
            mkdir("/etc/insserv",0755); 
        }
        if (!-d "/etc/insserv/overrides") {
            mkdir("/etc/insserv/overrides",0755);
        }
    } elsif (!-e  "/etc/insserv/overrides/SuSEfirewall2_setup.original") {
        copy "/etc/insserv/overrides/SuSEfirewall2_setup","/etc/insserv/overrides/SuSEfirewall2_setup.original"
    }
    copy "$instdir/sles-suse/SuSEfirewall2_setup","/etc/insserv/overrides/SuSEfirewall2_setup";
    chmod(0444,"/etc/insserv/overrides/SuSEfirewall2_setup");
}

sub get_iptables_rules {
    my ($distro,$instdir,$apachefw) = @_;
    my (@fwchains,@ports);
    if (&firewall_is_active()) {
        my $iptables = &get_pathto_iptables();
        if ($iptables ne '') {
            @fwchains = &get_fw_chains($iptables,$distro);
        }
    }
    if (ref($apachefw) eq 'HASH') {
        foreach my $service ('http','https') {
            unless ($apachefw->{$service}) {
                push (@ports,$service); 
            }
        }
    } else {
        @ports = ('http','https');
    }
    if (@ports == 0) {
        return;
    }
    my $ask_to_enable;
    if (-e "/etc/iptables.loncapa.rules") {
        if (open(PIPE, "diff --brief $instdir/debian-ubuntu/iptables.loncapa.rules /etc/iptables.loncapa.rules |")) {
            my $diffres = <PIPE>;
            close(PIPE);
            chomp($diffres);
            if ($diffres) {
                print &mt('Warning: [_1] exists but differs from LON-CAPA supplied file.','/etc/iptables.loncapa.rules')."\n";
            }
        } else {
            print &mt('Error: unable to open [_1] to compare contents with LON-CAPA supplied file.','/etc/iptables.loncapa.rules')."\n";
        }
    } else {
        if (-e "$instdir/debian-ubuntu/iptables.loncapa.rules") {
            copy "$instdir/debian-ubuntu/iptables.loncapa.rules","/etc/iptables.loncapa.rules";
            chmod(0600,"/etc/iptables.loncapa.rules");
        }
    }
    if (-e "/etc/iptables.loncapa.rules") {
        if (-e "/etc/network/if-pre-up.d/iptables") {
            if (open(PIPE, "diff --brief $instdir/debian-ubuntu/iptables /etc/network/if-pre-up/iptables |")) {
                my $diffres = <PIPE>;
                close(PIPE);
                chomp($diffres);
                if ($diffres) {
                    print &mt('Warning: [_1] exists but differs from LON-CAPA supplied file.','/etc/network/if-pre-up.d/iptables')."\n";
                }
            } else {
                print &mt('Error: unable to open [_1] to compare contents with LON-CAPA supplied file.','/etc/network/if-pre-up.d/iptables')."\n";
            }
        } else {
            copy "$instdir/debian-ubuntu/iptables","/etc/network/if-pre-up.d/iptables";
            chmod(0755,"/etc/network/if-pre-up.d/iptables");
            print_and_log(&mt('Installed script "[_1]" to add iptables rules to block all ports except 22, 80, and 443 when network is enabled during boot.','/etc/network/if-pre-up.d/iptables'));
            $ask_to_enable = 1;
        }
    }
    return $ask_to_enable;
}

sub download_loncapa {
    my ($instdir,$lctarball) = @_;
    my ($have_tarball,$updateshown);
    if (! -e "$instdir/$lctarball") {
	print_and_log(&mt('Retrieving LON-CAPA source files from: [_1]',
		      'http://install.loncapa.org')."\n");
	system("wget http://install.loncapa.org/versions/$lctarball ".
	       "2>/dev/null 1>/dev/null");
	if (! -e "./$lctarball") {
	    print &mt('Unable to retrieve LON-CAPA source files from: [_1].', 
		     "http://install.loncapa.org/versions/$lctarball")."\n";
	} else {
            $have_tarball = 1;
        }
	print_and_log("\n");
    } else {
        $have_tarball = 1;
	print_and_log("
------------------------------------------------------------------------

".&mt('You seem to have a version of loncapa-current.tar.gz in [_1]',$instdir)."\n".
&mt('This copy will be used and a new version will NOT be downloaded.')."\n".
&mt('If you wish, you may download a new version by executing:')."

wget http://install.loncapa.org/versions/loncapa-current.tar.gz

------------------------------------------------------------------------
");
    }

    ##
    ## untar loncapa.tar.gz
    ##
    if ($have_tarball) {
        print_and_log(&mt('Extracting LON-CAPA source files')."\n");
        writelog(`cd ~root; tar zxf $instdir/$lctarball`);
        print_and_log("\n");
        print &mt('LON-CAPA source files extracted.')."\n".
              &mt('It remains for you to execute the following commands:')."

cd /root/loncapa-X.Y.Z     (X.Y.Z should correspond to a version number like '2.11.3')
./UPDATE

".&mt('If you have any trouble, please see [_1] and [_2]',
      'http://install.loncapa.org/','http://help.loncapa.org/')."\n";
        $updateshown = 1;
    }
    return ($have_tarball,$updateshown);
}

close LOG;
